POV-Ray : Newsgroups : povray.binaries.images : Crackle chart Server Time
23 Feb 2024 05:18:48 EST (-0500)
  Crackle chart (Message 1 to 8 of 8)  
From: Samuel B 
Subject: Crackle chart
Date: 31 Aug 2023 18:35:00
Message: <web.64f114bdc8ec43c916bed5696e741498@news.povray.org>
Hi,

Here's a remake of an old crackle chart, but using isosurfaces. It shows various
results from different forms. The one with white text is the standard form.

The attached image only uses metric 2, but the code can be changed if you want a
different value.

It's not at all exhaustive, but potentially handy for finding a jumping-off
point. (Please ignore the -0.0; it's been a while since using str() and I forgot
how to easily get rid of the minus sign ;P)

/*

CrackleChart.pov
2023 Sam Benge

+fn +f +a0.03 +am2 +r3 +w7000 +h1000

*/


#version 3.7;

global_settings{assumed_gamma 1.0}

#default{ finish{ambient 0} }

camera{
 orthographic
 right x*7 up y
 location <0, 5, -5>
 look_at 0
 angle 104
}

light_source{
 <-1, .5, -.25>*1e5, rgb <1.7, 1.6, 1.4>
 shadowless
}

background{rgb <.03, .1, .3>}

union{
 #declare N = 3;
 #for(Z, -1, 1, 1/N)
  #for(Y, -1, 1, 1/N)
   #for(X, -1, 1, 1/N)

    #local Form = <X, Y, Z>;
    #local Metric = 2;
    #local Translate = <X + Z*7.7, Y*1.5, 0>;

    #local FCrackle =
     function{
      pattern{
       crackle
       form Form
       metric Metric
       scale .75
      }
     }

    isosurface{
     function{
      y - .5 * FCrackle(x, 0, z) + .5
     }
     accuracy .001
     evaluate 0, 10, .5
     scale .3/N
     rotate y*25
     translate Translate
    }

    #undef FCrackle

    text{
     ttf "arialbd"
     concat("<", str(Form.x, 1, 1), ", ", str(Form.y, 1, 1), ", ", str(Form.z,
1, 1), ">")
     .1, 0
     rotate x*45
     translate <-4, -7.5, 0>
     scale .12/N
     translate Translate
     // white text for default crackle form, yellow otherwise
     #if(Form.x=-1 & Form.y=1 & Form.z=0)
      pigment{rgb 1}
     #else
      pigment{rgb <1, .8, .4>}
     #end
     finish{emission 1 diffuse 0}
    }

   #end
  #end
 #end

 translate y*.1
 pigment{rgb .75}
}

Sam


Post a reply to this message


Attachments:
Download 'cracklechart.jpg' (1133 KB)

Preview of image 'cracklechart.jpg'
cracklechart.jpg


 

From: gibe
Subject: Re: Crackle chart
Date: 1 Sep 2023 03:45:00
Message: <web.64f1964eb5886c36bafc4c6b64a53f21@news.povray.org>
"Samuel B." <stb### [at] hotmailcom> wrote:
> Hi,
>
> Here's a remake of an old crackle chart, but using isosurfaces. It shows various
> results from different forms. The one with white text is the standard form.
>
> The attached image only uses metric 2, but the code can be changed if you want a
> different value.
>
> It's not at all exhaustive, but potentially handy for finding a jumping-off
> point. (Please ignore the -0.0; it's been a while since using str() and I forgot
> how to easily get rid of the minus sign ;P)
>

I really missed your posts, Sam!
This one could be very useful. Lately I have a very little time for pov-ing, but
when possible I want to try this kind of crackle on an old project.

Paolo


Post a reply to this message

From: Samuel B 
Subject: Re: Crackle chart
Date: 1 Sep 2023 18:20:00
Message: <web.64f26281b5886c3616bed5696e741498@news.povray.org>
"gibe" <p.g### [at] gmailcom> wrote:
> "Samuel B." <stb### [at] hotmailcom> wrote:
> > Here's a remake of an old crackle chart [...]
>
> I really missed your posts, Sam!
> This one could be very useful. Lately I have a very little time for pov-ing, but
> when possible I want to try this kind of crackle on an old project.
>
> Paolo

Oh, hi Paolo! I didn't realize it was you at first, due to the name change.

Yeah, this chart should help for certain things. There's another one online at
https://www.imagico.de/pov/cr_form_en.php But it's a bit hard to navigate and
imagine how it will look as a height or bump map.

I hope you get some time for doing what you want to do soon. In the meantime,
are you making notes and sketches?

Sam


Post a reply to this message

From: Samuel B 
Subject: Re: Crackle chart
Date: 1 Sep 2023 19:25:00
Message: <web.64f271a3b5886c3616bed5696e741498@news.povray.org>
"Samuel B." <stb### [at] hotmailcom> wrote:
> Hi,
>
> [...] a remake of an old crackle chart, but using isosurfaces. [...]

And here's an inverted version to see how they look when... inverted. (I had to
adjust the plane.)

If I post another chart, it will be only the most interesting forms that don't
saturate.

Sam


Post a reply to this message


Attachments:
Download 'cracklechart-inverted.jpg' (1123 KB)

Preview of image 'cracklechart-inverted.jpg'
cracklechart-inverted.jpg


 

From: Paolo Gibellini
Subject: Re: Crackle chart
Date: 3 Oct 2023 17:58:54
Message: <651c8e9e$1@news.povray.org>
On 02/09/2023 00:15, Samuel B. wrote:
> I hope you get some time for doing what you want to do soon. In the meantime,
> are you making notes and sketches?
> 
> Sam
> 
I'm in the middle of an internal move, and I haven't had access to my 
home PC for a couple of months... and yes, I'm taking notes because I 
left too many codes pending ;-)

Paolo


Post a reply to this message

From: Samuel B 
Subject: Re: Crackle chart
Date: 5 Oct 2023 16:25:00
Message: <web.651f1ac3b5886c3616bed5696e741498@news.povray.org>
Paolo Gibellini <p.g### [at] gmailcom> wrote:
> On 02/09/2023 00:15, Samuel B. wrote:
> > I hope you get some time for doing what you want to do soon. In the meantime,
> > are you making notes and sketches?
> >
> > Sam
> >
> I'm in the middle of an internal move, and I haven't had access to my
> home PC for a couple of months... and yes, I'm taking notes because I
> left too many codes pending ;-)
>
> Paolo

Hopefully the move doesn't take too long! Sometimes I think it would be nice to
have an Android version of POV-Ray. (I think somebody compiled a binary once,
but I don't think they ever posted it anywhere.)

Sam


Post a reply to this message

From: Paolo Gibellini
Subject: Re: Crackle chart
Date: 5 Oct 2023 17:34:05
Message: <651f2bcd$1@news.povray.org>
On 05/10/2023 22:21, Samuel B. wrote:
> Hopefully the move doesn't take too long! Sometimes I think it would be nice to
> have an Android version of POV-Ray. (I think somebody compiled a binary once,
> but I don't think they ever posted it anywhere.)
> 
> Sam
> 

Hopefully...

An Android version of POV-Ray is available on Google Play (but is not 
available for my device). It was build by Ralf Wappler.

Paolo


Post a reply to this message

From: Samuel B 
Subject: Re: Crackle chart
Date: 7 Oct 2023 16:55:00
Message: <web.6521c481b5886c3616bed5696e741498@news.povray.org>
Paolo Gibellini <p.g### [at] gmailcom> wrote:
> On 05/10/2023 22:21, Samuel B. wrote:
> > Hopefully the move doesn't take too long! Sometimes I think it would be nice to
> > have an Android version of POV-Ray. (I think somebody compiled a binary once,
> > but I don't think they ever posted it anywhere.)
>
> Hopefully...
>
> An Android version of POV-Ray is available on Google Play (but is not
> available for my device). It was build by Ralf Wappler.
>
> Paolo

Just checked it out. It looks interesting, but the lack of description makes me
think it's pretty bare-bones. I can imagine one having to edit text files in a
different app and then switch over to POV-Ray for rendering, which would
potentially make the entire process very tedious. Still, I might try installing
it. Thanks for the head-up~

Sam


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.