|
![](/i/fill.gif) |
I was trying to create a stand-alone normal for blurred reflections. The sphere
on the left uses an averaged texture, as illustrated in the Knowledgebase. The
sphere on the right uses an averaged normal applied to a base texture.
_____________________________________________________________
#version 3.7;
global_settings
{ assumed_gamma 1
max_trace_level 10
}
camera
{ location <-8, 1.5, -8>
look_at y
angle 30
}
sky_sphere
{ pigment
{ gradient y color_map
{ [0 rgb <0.7, 0.8, 0.9>]
[1 rgb <0.2, 0.3, 0.6>]
}
}
}
light_source
{ <-1, 2, 0> * 1000 rgb 1
parallel point_at 0
}
plane { y, 0 pigment { checker rgb 0.05 rgb 1 } }
#declare t_Brass = texture
{ pigment { rgb <0.80, 0.57, 0.23> }
finish
{ reflection { 0.5 metallic }
diffuse 0.4 ambient 0.05
specular 1 metallic 0.95 roughness 0.015
brilliance 6.75
}
}
#declare S = seed (0);
sphere
{ y, 1
texture
{ average texture_map
{ #declare I = 0;
#while (I < 10)
[1 t_Brass
normal
{ bumps
translate <rand(S), rand(S), rand(S)> * 100
scale 1000
}
]
#declare I = I + 1;
#end
}
}
translate <-1, 0, 1>
}
#declare S = seed (0);
sphere
{ y, 1
texture
{ t_Brass
normal
{ average normal_map
{ #declare I = 0;
#while (I < 10)
[1 bumps
translate <rand(S), rand(S), rand(S)> * 100
scale 1000
]
#declare I = I + 1;
#end
}
}
}
translate <1, 0, -1>
}
_____________________________________________________________
By my understanding of SDL, the two spheres should be identical. Obviously, my
understanding is wrong, but I cannot figure out where the difference is. Why
are the two spheres different?
I am using version 3.7RC3.
Post a reply to this message
Attachments:
Download 'averagendemo.jpg' (51 KB)
Preview of image 'averagendemo.jpg'
![averagendemo.jpg](/povray.binaries.images/attachment/%3Cweb.4e4175bb14a73acc85de7b680%40news.povray.org%3E/averagendemo.jpg?ttop=443866&toff=1950&preview=1)
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
On 08/09/2011 09:00 PM, Cousin Ricky wrote:
> I was trying to create a stand-alone normal for blurred reflections. The sphere
> on the left uses an averaged texture, as illustrated in the Knowledgebase. The
> sphere on the right uses an averaged normal applied to a base texture.
When you average textures, POV-Ray will calculate each texture
independently and then average the results. If you average normals, the
resulting normals are average of the given normals, and used only once.
It's just how it has been implemented.
Post a reply to this message
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
> I was trying to create a stand-alone normal for blurred reflections. The sphere
> on the left uses an averaged texture, as illustrated in the Knowledgebase. The
> sphere on the right uses an averaged normal applied to a base texture.
> _____________________________________________________________
> _____________________________________________________________
>
> By my understanding of SDL, the two spheres should be identical. Obviously, my
> understanding is wrong, but I cannot figure out where the difference is. Why
> are the two spheres different?
>
> I am using version 3.7RC3.
I had the same assumption as you. I also did notice that with both
version 3.6 and 3.7.
I don't know why, but as the result did not change between 3.6 and 3.7,
I must assume that's by design.
Alain
Post a reply to this message
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
Warp <war### [at] tag povray org> wrote:
> When you average textures, POV-Ray will calculate each texture
> independently and then average the results. If you average normals, the
> resulting normals are average of the given normals, and used only once.
> It's just how it has been implemented.
I see. Thanks.
Post a reply to this message
|
![](/i/fill.gif) |