|
 |
"EagleSun" <nomail@nomail> wrote:
> "o.bb.spammed" <o.b### [at] gmail com> wrote:
> > Last one in my stockpile for now :o)
> >
> > This one evolved quite a bit. The series is here:
> > http://members.cox.net/tulivu/ball/index.html
> >
> >
> > Hmmm. Code is at home. I'll post it later, if anyone wants it.
> >
> > Thanks
>
> Very nice uh.... isosurface? Is that clouds being reflected? Yea, I'm
> interested in the code.
Thanks. They're just blobs. The scene is surrounded by a big textured
sphere. Here's some of the older code I found. I'll dig around and see if
I can find something more recent.
#version 3.6;
#include "colors.inc"
global_settings {
assumed_gamma 1.0
}
// ----------------------------------------
camera {
location <-2.0, 5.0, 5.0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 1.0, 0.0>
}
/*
camera {
location <-2.0, 0.0, 5.0>
direction 1.5*z
right x*image_width/image_height
look_at <-2.0, 1.0, 5.0>
}
*/
light_source {
<-1, 1, -3.5>
color rgb <0.02, 0.01, 0.01>
fade_distance 40
fade_power 2
area_light <1, 0, 0>, <0, 0, 1>, 10, 10
adaptive 1
jitter
}
light_source {
<-1, 0, -3.5>
color rgb <0.8, 0.8, 0.8>
fade_distance 3
fade_power 1
area_light <1, 0, 0>, <0, 0, 1>, 10, 10
adaptive 1
jitter
}
// ----------------------------------------
plane {
y, -1
pigment {
color rgb <1,1,1>
}
finish
{
ambient 0
diffuse 1
}
normal
{
bozo
turbulence 0.65
octaves 6
omega 0.7
lambda 2
scale <.25, 2, .25>
}
}
height_field {
"ball_ground.bmp"
scale <25, -0.25, 25>
translate< -13.5, -0.75, -15.5>
pigment {
color rgb <1,1,1>
}
finish
{
ambient 0
diffuse 1
}
}
sphere {
0.0, 100
hollow
texture {
pigment {
bozo
turbulence 0.65
octaves 6
omega 0.7
lambda 2
color_map {
[0.0 0.4 color rgb <2.00, 2.00, 2.00> color rgb <2.00, 2.00, 2.00>]
[0.4 0.8 color rgb <2.00, 2.00, 2.00> color rgb <0.50, 0.50, 0.50>]
[0.8 1.0 color rgb <0.50, 0.50, 0.50> color rgb <0.50, 0.50, 0.50>]
}
scale 50
}
finish {
ambient 1
diffuse 0
}
}
}
/*
#declare ball =
sphere {
0.0, 1
texture {
pigment {
color rgb <0, 0, 0.1>
}
finish{
metallic
brilliance 10
reflection {
1
metallic
exponent 1.0
}
ambient 0.1
diffuse 0.9
}
}
}
#declare R1 = seed(0);
#declare i=99;
#while (i>0)
#declare s = 0.1+0.9*(rand(R1)*rand(R1));
object
{
ball
scale s
translate <10*rand(R1)-5, -1.0+s, 10*rand(R1)-8>
}
#declare i=i-1;
#end
*/
blob
{
threshold 0.89
#declare R1 = seed(0);
#declare i=199;
#while (i>0)
#declare s = 0.5+0.9*(rand(R1)*rand(R1));
sphere {
<0, 0, 0>, s, 1
translate <10*rand(R1)-5, -1.5+s, 10*rand(R1)-8>
}
#declare i=i-1;
#end
texture {
pigment {
color rgb <0, 0, 0.1>
}
finish{
metallic
brilliance 10
reflection {
1
metallic
exponent 1.0
}
ambient 0.1
diffuse 0.9
}
}
}
Post a reply to this message
|
|
