|
![](/i/fill.gif) |
Hi all!
See message with same subject in p.b-t for explanations... Here's the
result, on the left with beta 5, on the right with official 3.6.1a. Source
also attached... in case i did something obviously stupid in there and both
versions just don't handle stupidity the same way ;)
JYR
// Begin source...
// A Dice
global_settings {
assumed_gamma 2.2
max_trace_level 8
}
#declare Span = 82*y;
camera {
location -7.2*z
look_at -1.6*y
rotate Span
}
light_source {<3, 4, -5> rgb 1 rotate Span}
// A dice with no black dots yet
#declare Scale = 1.375;
#declare Blank_Dice =
intersection {
box {-1, 1}
sphere {0, 1.6}
cylinder {-x, x, 1 scale Scale}
cylinder {-y, y, 1 scale Scale}
cylinder {-z, z, 1 scale Scale}
pigment {rgb 1 transmit .4}
finish {diffuse .82 ambient .15}
}
// A single black dot
#declare Black_Dot =
sphere {
-z, .15
pigment {rgb .1}
finish {diffuse .9 ambient .1 phong .35 phong_size 10}
}
// Create the dot patterns on each side of the dice
#declare Face_1 = object {Black_Dot}
#declare Face_2 =
union {
object {Black_Dot translate < .5, .5, 0>}
object {Black_Dot translate <-.5, -.5, 0>}
}
#declare Face_3 =
union {
object {Face_1}
object {Face_2}
}
#declare Face_4 =
union {
object {Face_2}
object {Face_2 rotate 90*z}
}
#declare Face_5 =
union {
object {Face_2}
object {Face_3 rotate 90*z}
}
#declare Face_6 =
union {
object {Face_4}
object {Black_Dot translate .5*x}
object {Black_Dot translate -.5*x}
}
// Create the completed dice
#declare Dice =
difference {
object {Blank_Dice}
object {Face_1}
object {Face_2 rotate -90*y}
object {Face_3 rotate 90*x}
object {Face_4 rotate -90*x}
object {Face_5 rotate 90*y}
object {Face_6 rotate 180*x}
}
// Set the dice on display
object {Dice rotate 45*y rotate 52*x}
// On a Reflective Plane
plane {
y, -1.6
pigment {rgb 1}
finish {reflection .95 diffuse .08 ambient .01}
}
// end source code
Post a reply to this message
Attachments:
Download 'dices.jpg' (30 KB)
Preview of image 'dices.jpg'
![dices.jpg](/povray.binaries.images/attachment/%3Cweb.428f95e84516a8fe6a3607400%40news.povray.org%3E/dices.jpg?ttop=441697&toff=5250&preview=1)
|
![](/i/fill.gif) |