Just playing with 3.7 beta 2 and came up with this. Isosurface, media,
refraction, sky_sphere.

 - Slime
 [ http://www.slimeland.com/ ]

Post a reply to this message

Attachments:
Download 'blueblob.jpg' (111 KB)

Preview of image 'blueblob.jpg'

Love it!  I think I see my new desktop wallpaper.  Any chance you would 
share the source?  Does it require 3.7 beta 2?

Slime wrote:
> Just playing with 3.7 beta 2 and came up with this. Isosurface, media,
> refraction, sky_sphere.
> 
>  - Slime
>  [ http://www.slimeland.com/ ]
> 
> 
>

Post a reply to this message

Beautiful and unique!

Post a reply to this message

> Love it!  I think I see my new desktop wallpaper.  Any chance you would
> share the source?  Does it require 3.7 beta 2?

Thanks. =)

Shouldn't require 3.7; here's the source:

// +w1280 +h502 +AM2 +A0.1 +R3

global_settings {
 max_trace_level 100
}

light_source {
 <0,1,-1>*999
 rgb 1
}

camera {
 location -10*z
 right x * image_width/image_height // intended: 2.55
 up y
 look_at z
}

sky_sphere {
 pigment {
  gradient y
  color_map {
   [0 rgb <0.2, 0.3, .65>*.7]
   [1 rgb <0.7, 1.2, 1.3>*1.1]
  }
  scale 2
  translate -y
 }
}

#include "functions.inc"

#declare scurve = function(x) {x*x*(3-2*x)};

isosurface {
 function {
  (f_noise_generator(x*5,y*5,z*5+20,2)-.4) +
  .4 * curve(max((pow(x*x + y*y + z*z,.5)-.7)/.3, 0)) // (round off edges)
 }
 max_gradient 4
 accuracy .001

 contained_by {
  sphere{0,1}
  //box {<-1,-1,-.01>,1}
 }

 all_intersections

 texture {
  pigment {rgbt 1}
  finish {
   specular .45
   roughness .01
  }
 }
 interior {
  ior 1.1

  media {
   emission <.2,.65,.8>*.08
   absorption .05
  }
 }

 hollow

 rotate -40*y
 rotate -30*x
 scale 9

 translate <2.5,-3.5,0>
}

 - Slime
 [ http://www.slimeland.com/ ]

Post a reply to this message

"Slime" <fak### [at] emailaddress> wrote in message
news:426d9af6$1@news.povray.org...
> > Love it!  I think I see my new desktop wallpaper.  Any chance you would
> > share the source?  Does it require 3.7 beta 2?
>
> Thanks. =)
>
> Shouldn't require 3.7; here's the source:
>
<snip>
> isosurface {
>  function {
>   (f_noise_generator(x*5,y*5,z*5+20,2)-.4) +
>   .4 * curve(max((pow(x*x + y*y + z*z,.5)-.7)/.3, 0)) // (round off edges)
<------
>  }
<snip>

I saw your image and thought WOW, and had to take a look for myself :)

I've tried to run the code, but it errors on the line i have marked.  It
complains about the curve function.  I'm running beta 2 of version 3.7 but
with no luck...

Any ideas?

Cheers Dre

Post a reply to this message

> I've tried to run the code, but it errors on the line i have marked.  It
> complains about the curve function.

Serves me right for trying to edit it before posting. That should be
'scurve', the function defined a few lines earlier.

 - Slime
 [ http://www.slimeland.com/ ]

Post a reply to this message

"Slime" <fak### [at] emailaddress> wrote in message
news:426dab6b$1@news.povray.org...
> > I've tried to run the code, but it errors on the line i have marked.  It
> > complains about the curve function.
>
> Serves me right for trying to edit it before posting. That should be
> 'scurve', the function defined a few lines earlier.
>
>  - Slime
>  [ http://www.slimeland.com/ ]
>
>
Doh!  and serves me right for asking stupid questions before checking it out
fully :)

I *should* have picked that!

Thanks again!

Cheers Dre

Post a reply to this message

> Just playing with 3.7 beta 2 and came up with this. Isosurface, media,
> refraction, sky_sphere.
> 
>  - Slime
>  [ http://www.slimeland.com/ ]
> 
> 
> 
Hey, I love it! !!!

Could you render it in 1440x900, I want to put it as my new wallpaper 
without having to alter the picture quality !

-- 
Dark Skull Software
http://www.darkskull.net

A+

Post a reply to this message

Re-rendered at 1600x1200 and installed as my wallpaper.  Beautiful and 
likely to keep me occupied tweaking, modifying, and maybe even 
understanding for weeks.  Thank you!

Now where did I hide that dolphin model... ?


Slime wrote:
>>I've tried to run the code, but it errors on the line i have marked.  It
>>complains about the curve function.
> 
> 
> Serves me right for trying to edit it before posting. That should be
> 'scurve', the function defined a few lines earlier.
> 
>  - Slime
>  [ http://www.slimeland.com/ ]
> 
>

Post a reply to this message

> Could you render it in 1440x900, I want to put it as my new wallpaper
> without having to alter the picture quality !

You can render it in any resolution you want if you use the source code
provided in my other post. =)

 - Slime
 [ http://www.slimeland.com/ ]

Post a reply to this message