Maybe some media for a thin atmosphere.

-tgq


"Coridon Henshaw" <che### [at] sympaticoca> wrote in message
news:Xns### [at] 204213191226...
>
> Any comments?
>
>

Post a reply to this message

Coridon Henshaw schrieb:

> Any comments?
>
>  [Image]

Really cool... but obviously it is not Mars (Mars has only two tiny,
asteroid-like moons), but some other, extra-solar desert world - perhaps
Frank Herbert's Arrakis? However, the planet's moon is too featureless
for a rocky body with little or no atmosphere, it reminds me of Venus.

Is your planet intended to have an atmosphere? If yes, then perhaps a
narrow seam of media along the horizon could be appropriate!

See you in Khyberspace -
http://www.geocities.com/electricafghan/index-e.html
Afghanistan Chronicle: http://www.ndh.net/home/bleimann/

Yadgar

Post a reply to this message

Yadgar wrote:

> Is your planet intended to have an atmosphere? If yes, then perhaps a
> narrow seam of media along the horizon could be appropriate!

Funny how different people perceive things differently. I had thought that
we were looking over the surface of a moon at the planet beyond. BTW, I
absolutely love this image, as it is tremendously understated in a way that
one rarely sees in a CG image.

Post a reply to this message

Dave Dunn wrote:

> 
> Yadgar wrote:
> 
> 
>>Is your planet intended to have an atmosphere? If yes, then perhaps a
>>narrow seam of media along the horizon could be appropriate!
>>
> 
> Funny how different people perceive things differently. I had thought that
> we were looking over the surface of a moon at the planet beyond. BTW, I
> absolutely love this image, as it is tremendously understated in a way that
> one rarely sees in a CG image.


Or in RL images, for that matter.


BTW:  I found the Voyager 2 pic I mentioned in an earlier post:

http://antwrp.gsfc.nasa.gov/apod/ap010619.html



-- 
/*Francois Labreque*/#local a=x+y;#local b=x+a;#local c=a+b;#macro P(F//
/*    flabreque    */L)polygon{5,F,F+z,L+z,L,F pigment{rgb 9}}#end union
/*        @        */{P(0,a)P(a,b)P(b,c)P(2*a,2*b)P(2*b,b+c)P(b+c,<2,3>)
/*   videotron.ca  */}camera{location<6,1.25,-6>look_at a orthographic}

Post a reply to this message

Francois Labreque wrote:

> BTW:  I found the Voyager 2 pic I mentioned in an earlier post:

ALong the same lines:
http://www.jpl.nasa.gov/cgi-bin/gs2?path=/cassini/english/press/imageadv/images/imagead_010531.jpg&type=image

Post a reply to this message

Yadgar <j.b### [at] ndhnet> wrote in news:3BE17DEF.FC307C13@ndh.net:

> Is your planet intended to have an atmosphere? If yes, then perhaps a
> narrow seam of media along the horizon could be appropriate!

<cough> Look closely at the limb on the left hand side.  Also look for the 
whispy dust clouds in the lower right.  The entire planet is contained in a 
media.

Anyhow, here's revision 2 -- at 1024x768x24bpp.

Post a reply to this message

Attachments:
Download 'mop.jpg' (24 KB)

Preview of image 'mop.jpg'

Francois Labreque <fla### [at] videotronca> wrote in
news:3BE### [at] videotronca: 

> BTW:  I found the Voyager 2 pic I mentioned in an earlier post:
> 
> http://antwrp.gsfc.nasa.gov/apod/ap010619.html

Been there, done that.  Waited a few hours for the render.

Post a reply to this message

Attachments:
Download 'neptri2.jpg' (35 KB)

Preview of image 'neptri2.jpg'

could you post the source for this? i tried for a long time to get a
realistic scene like this, but i could not get the textures and lighting
right. i even checked my physics books for sizes and distances of the earth,
moon and sun just for completeness.

the texture on the moon never gave way to the cresent shape we all know and
love.

thanks,
ross

Post a reply to this message

"Ross Litscher" <lit### [at] osuedu> wrote in
news:3be1edad$1@news.povray.org: 

> could you post the source for this? i tried for a long time to get a
> realistic scene like this, but i could not get the textures and
> lighting right.

Here's the source for everything except the ship.  I've included addresses 
for where you can download the image maps.

sphere
{
    <-7500,20000,2e6>, 4000
/* get this map from http://www.mmedia.is/~bjj/data/venus/venus.jpg */

    pigment {image_map {jpeg "venus.jpg" map_type 1 interpolate 2} rotate 
x*-45}
    normal {bump_map {jpeg "venus.jpg" map_type 1 interpolate 2 bump_size 
2} rotate x*-45}
    finish {diffuse 1}
}

union
{
#local R=5500*0.90;
sphere {<0,0,0>, R

/* Get this map from http://maps.jpl.nasa.gov/textures/mar0kuu2.jpg */

    	pigment {image_map {jpeg "mar0kuu2.jpg" map_type 1 interpolate 2} 
rotate x*22.5}
        normal
        {
            average
            normal_map
            {
                [0 bump_map {jpeg "mar0kuu2.jpg" map_type 1 interpolate 2 
bump_size -1.25} rotate x*22.5]
                [1 wrinkles 1/75 scale 100]
            }
        }        
        finish {specular 0.075 diffuse 2}
}

#local R1=R*(5504/5500);

/* Atmosphere.  Renders s l o w l y */
    sphere {0,1
    hollow
    pigment {rgbf 1}
    
    interior
    {

#local D0 = density
{
    granite
    turbulence 1
    density_map
    {
        [0.0 rgb 1]
        [0.5 rgb 0.25]
        [1.0 rgb 0]
    }
    scale <4,2,4>/4
}

#local D1 = density
{
    granite
    turbulence 1
    density_map
    {
        [0.0 rgb 1]
        [0.6 rgb 0.1]
        [1.0 rgb 0]
    }
    scale 1/2
}

#local D2a = density
{
    spiral1 4
    turbulence 1
    density_map
    {
        [0.0 rgb 0]
        [0.5 rgb 1]
        [1.0 rgb 0]
    }
    rotate x*90
}

#local D2 = density
{
    gradient y
    density_map
    {
        [0.00 rgb 0]
        [1.00 D2a]
    }
    scale 1/2
}

        media
        {
            method 3
            scattering {4, ((<190,131,63>/255)*48)/R1}
            density
            {
                gradient y
                triangle_wave
                density_map
                {
                    [0.00 D0]
                    [0.25 D1]
                    [1.0 D2]
                }
                scale 2
            }
        }
    }
    rotate x*22.5
    scale R1
}
    
    translate y*(5500-R)
}

camera {location <1000,5500,-100000> look_at <1000,5500,0> angle 2}
light_source {<15,2,17>*1e6 color rgb 2 area_light <1,1,0>*2e6 <-1,-1,0>*
2e6 5,5 jitter circular orient adaptive 1}

Post a reply to this message

The ship has a triforce on it!?!?

I don't like the ship so far, personally... it's too hard to make out, and
not very detailed... it looks like it's made of large triangles. I'd like to
see a whole *fleet* of ships or something. I dunno.

- Slime
[ http://www.slimeland.com/ ]
[ http://www.slimeland.com/images/ ]

"Yadgar" <j.b### [at] ndhnet> wrote in message
news:3BE17DEF.FC307C13@ndh.net...
> Coridon Henshaw schrieb:
>
> > Any comments?
> >
> >  [Image]
>
> Really cool... but obviously it is not Mars (Mars has only two tiny,
> asteroid-like moons), but some other, extra-solar desert world - perhaps
> Frank Herbert's Arrakis? However, the planet's moon is too featureless
> for a rocky body with little or no atmosphere, it reminds me of Venus.
>
> Is your planet intended to have an atmosphere? If yes, then perhaps a
> narrow seam of media along the horizon could be appropriate!
>
> See you in Khyberspace -
> http://www.geocities.com/electricafghan/index-e.html
> Afghanistan Chronicle: http://www.ndh.net/home/bleimann/
>
> Yadgar
>
>
>

Post a reply to this message