|
 |
Op 24-11-2022 om 17:13 schreef Cousin Ricky:
> On 2022-11-22 14:43 (-4), ingo wrote:
>>
>> It can probably be done with the meshmaker.inc that comes with POV-Ray.
>
> For those using POV-Ray 3.7, be aware that there is a bug in
> meshmaker.inc v3.7: It will set your scene to #version 3.5, no matter
> what you put at the top of your scene file.
>
> This bug is fixed in v3.8 and in unofficial patches based on v3.7.1, and
> the file should work if you copy it to your v3.7 include folder.
>
Thank you indeed for this reminder! Personally, I almost always version
3.8, but sometimes 3.7 also. I now copied the corrected version of
meshmaker.inc from 3.8 to 3.7.
--
Thomas
Post a reply to this message
|
|
|
|
Op 3-12-2022 om 22:48 schreef s.day:
> This is even better than the first image, not really anything to critique. I
> especially love the texture/worn paint on the boat, great work.
>
> Looking forwards to the next image.
>
> Sean
>
Thank you indeed Sean!
the (exterior) mesh2 boat texture is constructed as follows:
//source of the image maps:
//https://www.arroway-textures.ch/products/boards-004/?texture-tags=&texture-filter=
//Map definitions
#declare p_map1=pigment {image_map{jpeg
"OldRowingBoat_boards-004_d100.jpg" gamma srgb interpolate 2 transmit
all 0 } }
#declare p_map2=normal {bump_map{jpeg
"OldRowingBoat_boards-004_b030.jpg" gamma 1.0 interpolate 2 }}
#declare p_map3=pigment {image_map{jpeg
"OldRowingBoat_boards-004_s050-g050.jpg" gamma 1.0 interpolate 2 }}
//Poseray macro:
#macro pigment_multiply(p1,p2)
//multiplies two pigments p1xp2
#local PR1 = function {pigment{p1}}
#local PR2 = function {pigment{p2}}
#local PR_FRed=function (x,y,z) {PR1(x,y,z).red*PR2(x,y,z).red}
#local PR_FGrn=function (x,y,z) {PR1(x,y,z).green*PR2(x,y,z).green}
#local PR_FBlu=function (x,y,z) {PR1(x,y,z).blue*PR2(x,y,z).blue}
average pigment_map{
[function{PR_FRed(x,y,z)} color_map{[0 rgb 0][1 rgb <1,0,0>*3]}]
//add each color and then divide by 3
[function{PR_FGrn(x,y,z)} color_map{[0 rgb 0][1 rgb <0,1,0>*3]}]
[function{PR_FBlu(x,y,z)} color_map{[0 rgb 0][1 rgb <0,0,1>*3]}]
}
#end
//Material definition
#declare PR_DIFFUSE = pigment {p_map1}
#declare PR_DIFFUSE = pigment {pigment_multiply(PR_DIFFUSE, pigment
{color srgb ((<0.67,0.67,0.50>-<1,1,1>)*1.0+<1,1,1>) })}
#declare F1 =
finish {
specular 0.274
roughness 0.048
diffuse 0.8
reflection {0} conserve_energy
}
#declare F2 =
finish {
specular 0.0
roughness 0.002
diffuse 0.8
reflection {0} conserve_energy
}
#declare N1 =
normal {p_map2
bump_size 50
}
#declare T1 =
texture {
pigment {uv_mapping PR_DIFFUSE}
finish {F1}
normal {uv_mapping N1}
}
#declare T2 =
texture {
pigment {uv_mapping PR_DIFFUSE}
finish {F2}
normal {uv_mapping N1}
}
#declare T3 =
texture {
pigment {uv_mapping
granite
pigment_map {
[0.20 srgb <0.3, 1.0, 0.3>]
[0.35 srgb <1.0, 0.3, 0.3>]
[0.55 srgb <1.0, 0.3, 0.3>]
[0.70 srgb <1.0, 1.0, 0.3>]
}
scale 1
}
finish {F1}
normal {uv_mapping N1}
}
#declare BoatPaint =
material {
texture {
pigment_pattern {uv_mapping p_map3}
texture_map {
[0.20 T1]
[0.30 T3]
[0.55 T2]
[0.90 T3]
}
}
}
--
Thomas
Post a reply to this message
|
|
org> wrote:
