I was playing with scattering media today. I happened to stick my light 
source inside the media container and was surprised to find POV-Ray 
suddenly running orders of magnitude faster - seconds instead of minutes.

On digging it looks to me when media is inside a container and the light 
  outside, media_attenuation is on no matter the light source setting in 
the SDL. If the light source is inside the container, media_attenuation 
is off.

If we move the media block to the top level of the scene the 
media_attenuation keyword in any light source behaves as I expect. In 
other words, I can turn media attenuation on and off.

Is this the expected behavior for media_attenuation?

It goes back to 3.7.0 at least. I've for years assumed media_attenuation 
was off unless I turned it on whether or not I had a media container - 
and assumed that media was always really slow.

In the attached image, the light sources for the left column explicitly 
set media_attenuation on. The right column explicitly sets it off. The 
bottom and top row use a media {} block at the top of the scene hierarchy.

The middle two rows use a sphere as a container for the same defined 
media. The first two rows have the light at a position which places it 
inside the sphere container in row 2. The last two rows have the light 
position such that it is outside the containing sphere in row 3.

When the light is inside the container in row 2, media attenuation is 
always off no matter the setting. When the light is outside the 
container (the common use case I think) media_attenuation looks to 
always be on.

Bill P.

//---------- LightMediaAttenuationTest.pov ---------
#version 3.7;
global_settings { assumed_gamma 1 }
#default { finish {ambient 0.0 diffuse 1.0} }
#declare Grey20 = srgb <0.2,0.2,0.2>;
background { color Grey20 }
#declare Camera00 = camera {
     perspective
     location <2.7,2.7,-2.701>
     sky y
     angle 35
     right x*(image_width/image_height)
     look_at <0,0,0>
}
#declare VarDist = 0.207;
#declare VarDistRes = 0.02;
#declare VarDistPos = VarDist+(VarDistRes/2);
#declare White = srgb <1,1,1>;
#declare LightInsideAttenOff = light_source {
     <0.5,0.95,-0.5>, White
     fade_distance VarDistPos
     fade_power 2
     media_attenuation off
}
#declare LightInsideAttenOn = light_source {
     <0.5,0.95,-0.5>, White
     fade_distance VarDistPos
     fade_power 2
     media_attenuation on
}
#declare LightOutsideAttenOff = light_source {
     <0.5,1.05,-0.5>, White
     fade_distance VarDistPos
     fade_power 2
     media_attenuation off
}
#declare LightOutsideAttenOn = light_source {
     <0.5,1.05,-0.5>, White
     fade_distance VarDistPos
     fade_power 2
     media_attenuation on
}
#declare Red = srgb <1,0,0>;
#declare CylinderX = cylinder { -2*x, 2*x, 0.01 pigment { Red } }
#declare Green = srgb <0,1,0>;
#declare CylinderY = cylinder { -2*y, 2*y, 0.01 pigment { Green } }
#declare Blue = srgb <0,0,1>;
#declare CylinderZ = cylinder { -2*z, 2*z, 0.01 pigment { Blue } }
#declare BrightBlue = srgb <0.05882,0.2549,1>;
#declare Box00 = box {
     <-1.001,-1.001,-1.001>,<1.001,0.499,1.001>
     pigment { color BrightBlue }
}
#declare DensitySph = density {
     spherical
     scale 0.4
     translate <0.5,0.5,-0.5>
     scale 3
     turbulence 0.35 octaves 6 omega 0.63 lambda 5
     scale 1/3
}
#declare Sphere00 = sphere { <0.5,0.5,-0.5>, 0.5 hollow }
#declare Media00 = media {
     method       3
     samples      100
     absorption   rgb <0,0,0>
     emission     rgb <0,0,0>
     scattering { 1, rgb <5,5,5> extinction 1 }
     density { DensitySph }
}
#declare Interior00 = interior { ior 1 media { Media00 } }
#declare Clear100 = srgbt <1,1,1,1>;
#declare PigmClear100 = pigment { color Clear100 }
#declare TxtrClear100 = texture { pigment { PigmClear100 } }
#declare MatrClear100 = material {
     texture { TxtrClear100 }
     interior { Interior00 }
}
#declare Obj00 = object { Sphere00 material { MatrClear100 } hollow }

//--- scene ---
camera { Camera00 }
object { Box00 }
object { CylinderX }
object { CylinderY }
object { CylinderZ }

//--- Use one of these
//    Inside position just inside top of Sphere00
//    Outside position just outside top of Sphere00
    light_source { LightInsideAttenOn }
// light_source { LightInsideAttenOff }
// light_source { LightOutsideAttenOn }
// light_source { LightOutsideAttenOff }

//--- Use one of these
// media  { Media00 } // Inside vs Outside means nothing to top media
    object { Obj00 }

//------ End of scene -------

Post a reply to this message

Attachments:
Download 'mediaattensummary.jpg' (141 KB)

Preview of image 'mediaattensummary.jpg'

On 21-1-2018 21:56, William F Pokorny wrote:
> I was playing with scattering media today. I happened to stick my light 
> source inside the media container and was surprised to find POV-Ray 
> suddenly running orders of magnitude faster - seconds instead of minutes.
> 

This is an interesting/important find indeed! My image 'Cat Alley' 
above, takes about 6 hours to render as you can expect. Like you, I 
always assumed media to severely slow down a render no matter what. I 
need to play with this a bit now. Thanks!

-- 
Thomas

Post a reply to this message

Something seems not right to me. The light source is /always/ outside 
the container:

light position: <0.5,0.95,-0.5> or: <0.5,1.05,-0.5>
container size: <0.5,0.5,-0.5>, 0.5

With a radius of 0.5 the container is always smaller.

-- 
Thomas

Post a reply to this message

Am 21.01.2018 um 21:56 schrieb William F Pokorny:

> Is this the expected behavior for media_attenuation?

The documentation for the feature specifically mentions "fog or
atmospheric media" (as opposed to object-contained media), so I'd say,
yes, that's the intended behaviour. Other portions of that same docs
section refer to "the fog or media", but I'd take that to be just a lazy
reference to the more precise term used earlier.

Post a reply to this message

Thomas de Groot <tho### [at] degrootorg> wrote:

>
> This is an interesting/important find indeed! My image 'Cat Alley'
> above, takes about 6 hours to render as you can expect. Like you, I
> always assumed media to severely slow down a render no matter what. I
> need to play with this a bit now. Thanks!
>

Same here; I never noticed this behavior before. I need to play with Bill's
example code.

Post a reply to this message

Question: The Docs are silent about this, but do fade_distance and 
fade_power have to be added to the light source or not, in order for the 
media attenuation to work?

http://wiki.povray.org/content/Reference:Light_Source#Atmospheric_Attenuation

-- 
Thomas

Post a reply to this message

On 01/22/2018 05:21 AM, clipka wrote:
> Am 21.01.2018 um 21:56 schrieb William F Pokorny:
> 
>> Is this the expected behavior for media_attenuation?
> 
> The documentation for the feature specifically mentions "fog or
> atmospheric media" (as opposed to object-contained media), so I'd say,
> yes, that's the intended behaviour. Other portions of that same docs
> section refer to "the fog or media", but I'd take that to be just a lazy
> reference to the more precise term used earlier.
> 

Thanks.

Does our documentation then push the use of the media container too much 
if using scattering media?

It looks to me like it's probably not the right thing to do if a user 
doesn't need/want media attenuation. Global media in my testing is quite 
a bit faster than any container with scattering media - except those 
where the light is inside the container.

--- media_attenuation on
1541.79user 0.67system 12:56.48elapsed (global media. outside postion)
                                        (Media Samples: 4,295,692,846)

--- media_attenuation off
403.22user 0.04system 3:22.24elapsed  (container. outside postion)
404.69user 0.05system 3:22.99elapsed  (Media Samples: 1,064,722,061)

32.04user 0.01system 0:16.67elapsed  (global media. outside postion)
32.10user 0.01system 0:16.67elapsed  (Media Samples: 58,877,772)

8.71user 0.01system 0:05.00elapsed  (container. inside postion)
8.63user 0.01system 0:04.94elapsed  (Media Samples: 11,828,518)


While I'm happy to know I can contort my media containers to contain the 
light for really fast scattering media renders, I do wonder a little why 
media attenuation is always off in that case.

Instead of contorting the container shape, would a media {} block 
'media_attenuation off' capability could be useful for those wanting to 
use scattering media and attenuation for final renders, but wanting fast 
working renders?

While you can sort of fake a media initially at much better performance 
using emitting media over scattering, you don't get a very good feel for 
the final scattering look of any given media-density that way.

Bill P.

Post a reply to this message

On 01/23/2018 03:32 AM, Thomas de Groot wrote:
> Question: The Docs are silent about this, but do fade_distance and 
> fade_power have to be added to the light source or not, in order for the 
> media attenuation to work?
> 
> http://wiki.povray.org/content/Reference:Light_Source#Atmospheric_Attenuation 
> 
> 
By experimentation just now it looks like no. If you have a fade power / 
fade_distance it will of course affect media results apart from or in 
addition to any media_attenuation.

Aside: In running these recent tests I wanted the media on black so I 
could better see any attenuation in addition to noting the run time 
changes when media_attenuation is on. I forgot global media needs a 
terminating shape on which the ray stops & my media disappeared causing 
me a spot of confusion until I thought to put the background box back 
into the scene but colored black.

Bill P.

Post a reply to this message

Am 23.01.2018 um 16:57 schrieb William F Pokorny:

> Instead of contorting the container shape, would a media {} block
> 'media_attenuation off' capability could be useful for those wanting to
> use scattering media and attenuation for final renders, but wanting fast
> working renders?

I'd say yes, that would be quite useful indeed.

(And maybe also `media_attenuation on` for light sources inside the
media container.)

Post a reply to this message

On 01/23/2018 03:28 PM, clipka wrote:
> Am 23.01.2018 um 16:57 schrieb William F Pokorny:
> 
>> Instead of contorting the container shape, would a media {} block
>> 'media_attenuation off' capability could be useful for those wanting to
>> use scattering media and attenuation for final renders, but wanting fast
>> working renders?
> 
> I'd say yes, that would be quite useful indeed.
> 
> (And maybe also `media_attenuation on` for light sources inside the
> media container.)
> 
Ah yes! A good idea to be able to turn attenuation on inside too if 
possible. Thanks. I've no experience with the media code, but will take 
a look to see if I can figure something out as a start.

Bill P.

Post a reply to this message

On 01/23/2018 03:28 PM, clipka wrote:
> Am 23.01.2018 um 16:57 schrieb William F Pokorny:
> 
...
> I'd say yes, that would be quite useful indeed.
> 
> (And maybe also `media_attenuation on` for light sources inside the
> media container.)
> 

I have been weeks now on and off digging into media and media code. It 
turns out there are scenes - abyss.pov for example - where the 
light_source IS inside the media container. We get no attenuation no 
matter other settings in those cases and often a washed out visual 
result. I'm starting to wonder if this lack of attenuation is behind the 
struggles with contrast in some media scenes.

Anyway, I want to immediately let folks know there is a way to get 
media_attenuation on in cases where your light source(s) are inside your 
media container. If you set up a difference creating either a small void 
or small divot around your light source(s) - presto media_attenuation is 
on.

It's an obvious idea since for lights outside the media container in my 
original posting the attenuation is always on. Of course, the small void 
idea didn't work when I first tried it...

Turns out in the global - the post transforms - scene coordinate space, 
the distance from the light outside to surface of the media container 
must be >= 0.001. This value appears to come from '#define 
SHADOW_TOLERANCE 1.0e-3' value being used in trace.cpp, but I've not 
spent time hacking at that code to be 100% sure.

Getting the lights outside the container >= 0.001 for attenuation works 
all the way back to 3.6.1 in my testing.

Bill P.

Post a reply to this message

Le 18-02-11 à 09:47, William F Pokorny a écrit :
> On 01/23/2018 03:28 PM, clipka wrote:
>> Am 23.01.2018 um 16:57 schrieb William F Pokorny:
>>
> ...
>> I'd say yes, that would be quite useful indeed.
>>
>> (And maybe also `media_attenuation on` for light sources inside the
>> media container.)
>>
> 
> I have been weeks now on and off digging into media and media code. It 
> turns out there are scenes - abyss.pov for example - where the 
> light_source IS inside the media container. We get no attenuation no 
> matter other settings in those cases and often a washed out visual 
> result. I'm starting to wonder if this lack of attenuation is behind the 
> struggles with contrast in some media scenes.
> 
> Anyway, I want to immediately let folks know there is a way to get 
> media_attenuation on in cases where your light source(s) are inside your 
> media container. If you set up a difference creating either a small void 
> or small divot around your light source(s) - presto media_attenuation is 
> on.
> 
> It's an obvious idea since for lights outside the media container in my 
> original posting the attenuation is always on. Of course, the small void 
> idea didn't work when I first tried it...
> 
> Turns out in the global - the post transforms - scene coordinate space, 
> the distance from the light outside to surface of the media container 
> must be >= 0.001. This value appears to come from '#define 
> SHADOW_TOLERANCE 1.0e-3' value being used in trace.cpp, but I've not 
> spent time hacking at that code to be 100% sure.
> 
> Getting the lights outside the container >= 0.001 for attenuation works 
> all the way back to 3.6.1 in my testing.
> 
> Bill P.
> 

So, we should add :
looks_like{sphere{0, 0.001 pigment{rgbt 1}}}
to the lights that are inside some media container.

Post a reply to this message

Alain <kua### [at] videotronca> wrote:

>
> So, we should add :
> looks_like{sphere{0, 0.001 pigment{rgbt 1}}}
> to the lights that are inside some media container.

I just tried that, and it doesn't work, unfortunately. (And the placement of the
looks_like(..) entry in the light code doesn't fix it either, relative to the
light's translation statement; I thought it might, but no luck.)

Apparently, Bill's successful trick needs an actual CGS difference of a tiny
object from the media container; then media_attenuation comes back on (as if the
light was again outside the media.) Very nice! By the way, here's an interesting
little detail about that small void. My media object code looks like this:

difference{
sphere{0,1}
sphere{0, .005 translate <-.2, 0, .9>} // translation same as light's position
hollow on
.....

The hollow keyword applies to BOTH objects AFAIK-- meaning both objects will
'contain' media. Yet the CSG-difference trick works anyway-- even though the
light is again 'inside a media container' rather than outside it. I don't know
what to make of that, re: a required media-free(?) void , but it's interesting.

My tests so far have been with object media, and with the camera outside the
object. I haven't yet tested atmospheric media. Or a situation where the camera
is *inside* the media object.

Post a reply to this message

On 02/12/2018 01:16 PM, Alain wrote:
> Le 18-02-11 à 09:47, William F Pokorny a écrit :
> 
> So, we should add :
> looks_like{sphere{0, 0.001 pigment{rgbt 1}}}
> to the lights that are inside some media container.
> 

Ah, good thought. I see Kenneth already tried it last night without 
success. Thanks Kenneth - saved me the time.

Longer term the aim is to be able to control whether media attenuation 
is on or off when using media containers by some explicit SDL mechanism. 
We've also got the problem we cannot turn it off when the light is 
outside, but to the quality of the end result it matters less I think.

Still trying to get my brain to digest as much as possible of the whole 
of the media code, how it interacts with itself and how it interacts 
with the rest of POV-Ray...

"The circles rapidly grow small—we are plunging madly within the grasp 
of the whirlpool—and amid a roaring, and bellowing, and thundering of 
ocean and of tempest, the ship is quivering—oh God! and ——going down!"

:-) I'm making progress, but it's slow.

Bill P.

Post a reply to this message

William F Pokorny <ano### [at] anonymousorg> wrote:
>
> Still trying to get my brain to digest as much as possible of the whole
> of the media code, how it interacts with itself and how it interacts
> with the rest of POV-Ray...
>

I'm in the throes of doing some further tests (although still with a media
container-object and the camera outside it)-- and I'm seeing some rather odd
things (so far) having to do with scattering's 'extinction' value. The fact that
media_attenuation is currently ALWAYS on (for lights outside the media, and when
your 'void' difference trick is used for a light *inside* the media), it's
really difficult to tell the difference between the media_attenuation effect,
and the separate shadowing (and 'self-shadowing') effects that
scattering/extinction produces. Those effects can't currently be separated out.
I've had to resort to some animation tests of the media with a moving light
source, to try and understand what's going on. It's a  s-l-o-w  process... but
worth the effort ;-)

Post a reply to this message

William F Pokorny <ano### [at] anonymousorg> wrote:

> "The circles rapidly grow small—we are plunging madly within the grasp
> of the whirlpool—and amid a roaring, and bellowing, and thundering of
> ocean and of tempest, the ship is quivering—oh God! and ——going down!"

https://www.youtube.com/watch?v=AX0XDHF3M60

Post a reply to this message

On 13/02/2018 15:03, Bald Eagle wrote:
> William F Pokorny <ano### [at] anonymousorg> wrote:
> 
>> "The circles rapidly grow small—we are plunging madly within the grasp
>> of the whirlpool—and amid a roaring, and bellowing, and thundering of
>> ocean and of tempest, the ship is quivering—oh God! and ——going down!"
> 
> https://www.youtube.com/watch?v=AX0XDHF3M60
> 

A bit of a Whoosh!, there. But I enjoyed the clip. :-)


-- 

Regards
     Stephen

Post a reply to this message

Stephen <mca### [at] aolcom> wrote:
> On 13/02/2018 15:03, Bald Eagle wrote:
> > William F Pokorny <ano### [at] anonymousorg> wrote:
> >
> >> "The circles rapidly grow small—we are plunging madly within the grasp
> >> of the whirlpool—and amid a roaring, and bellowing, and thundering of
> >> ocean and of tempest, the ship is quivering—oh God! and ——going down!"
> >
> > https://www.youtube.com/watch?v=AX0XDHF3M60
> >
>
> A bit of a Whoosh!, there. But I enjoyed the clip. :-)

The Quote is from "The House of Usher" by Poe.
The character's name is _Roderick_ Usher.

Or Wodewick Usheww....  :D

Post a reply to this message

On 13-2-2018 16:55, Bald Eagle wrote:
> Stephen <mca### [at] aolcom> wrote:
>> On 13/02/2018 15:03, Bald Eagle wrote:
>>> William F Pokorny <ano### [at] anonymousorg> wrote:
>>>
>>>> "The circles rapidly grow small—we are plunging madly within the grasp
>>>> of the whirlpool—and amid a roaring, and bellowing, and thundering of
>>>> ocean and of tempest, the ship is quivering—oh God! and ——going down!"
>>>
>>> https://www.youtube.com/watch?v=AX0XDHF3M60
>>>
>>
>> A bit of a Whoosh!, there. But I enjoyed the clip. :-)
> 
> The Quote is from "The House of Usher" by Poe.
> The character's name is _Roderick_ Usher.
> 
> Or Wodewick Usheww....  :D
> 
> 

Are you sure? I thought it was "A Descent into the Maelström" by same. :-0

-- 
Thomas

Post a reply to this message

On 13/02/2018 15:55, Bald Eagle wrote:
> Stephen <mca### [at] aolcom> wrote:
>> On 13/02/2018 15:03, Bald Eagle wrote:
>>> William F Pokorny <ano### [at] anonymousorg> wrote:
>>>
>>>> "The circles rapidly grow small—we are plunging madly within the grasp
>>>> of the whirlpool—and amid a roaring, and bellowing, and thundering of
>>>> ocean and of tempest, the ship is quivering—oh God! and ——going down!"
>>>
>>> https://www.youtube.com/watch?v=AX0XDHF3M60
>>>
>>
>> A bit of a Whoosh!, there. But I enjoyed the clip. :-)
> 
> The Quote is from "The House of Usher" by Poe.
> The character's name is _Roderick_ Usher.
> 

Ah! literature. No wonder I didn't recognise it.


> Or Wodewick Usheww....  :D
> 
> 
> 

Wight! ;)


-- 

Regards
     Stephen

Post a reply to this message

Thomas de Groot <tho### [at] degrootorg> wrote:

> Are you sure? I thought it was "A Descent into the Maelström" by same. :-0

I was not at all sure.
It is not that either.

Upon having more than a few uninterrupted seconds to look into it further, it's
apparently from "Ms [manuscript] found in a bottle".   :/

This is what happens when you voraciously read many things in rapid succession,
and your vast personal library is no longer at your fingertips.
This is often an even worse problem for me with Sci Fi, or some bit of film I
only remember snippets of.

Elton John had a tiny dancer in his head - I need a tiny librarian, or a
secretary to manage the filing.

Sounds like TdG needs an AI to index all of his code - I know the feeling.
"Now WHERE is that little snippet that does....?"

"The circles rapidly grow small we are plunging madly within the grasp of the
whirlpool..."
To mix a thread or two, circles of confusion indeed.

Post a reply to this message

On 14-2-2018 12:27, Bald Eagle wrote:
> Thomas de Groot <tho### [at] degrootorg> wrote:
> 
>> Are you sure? I thought it was "A Descent into the Maelström" by same. :-0
> 
> I was not at all sure.
> It is not that either.
> 
> Upon having more than a few uninterrupted seconds to look into it further, it's
> apparently from "Ms [manuscript] found in a bottle".   :/

Ah! Of course! At least we had the author right. ;-)

[interesting alternative universe title: "Ms (miss) found in a bottle"]

> 
> This is what happens when you voraciously read many things in rapid succession,
> and your vast personal library is no longer at your fingertips.
> This is often an even worse problem for me with Sci Fi, or some bit of film I
> only remember snippets of.

I know what you mean. I am permanently struggling with remembering where 
I read snippets of text that come up in daily conversation. :-/

> 
> Elton John had a tiny dancer in his head - I need a tiny librarian, or a
> secretary to manage the filing.
> 
> Sounds like TdG needs an AI to index all of his code - I know the feeling.
> "Now WHERE is that little snippet that does....?"

I thought I had it all well and logically filed away but no. I /know/ I 
have it somewhere but it escapes my eager little fingers. When 
associated with an image I have less problems remembering and finding.

> 
> "The circles rapidly grow small we are plunging madly within the grasp of the
> whirlpool..."
> To mix a thread or two, circles of confusion indeed.
> 

So it is indeed, so it is.

-- 
Thomas

Post a reply to this message

On 2/11/18 9:47 AM, William F Pokorny wrote:
> On 01/23/2018 03:28 PM, clipka wrote:
>> Am 23.01.2018 um 16:57 schrieb William F Pokorny:
>>
> ...
>> I'd say yes, that would be quite useful indeed.
>>
>> (And maybe also `media_attenuation on` for light sources inside the
>> media container.)
>>
> 
> I have been weeks now on and off digging into media and media code. It 
...
> 

I was reminded today I'd left this branch of this thread hanging regard 
adding explicit media attenuation control for lights inside and outside 
a media container.

I looked at adding an SDL keyword/arrangement for explicit control early 
in the year. However, I could never get more than 80-90% of test scenes 
(or parts thereof) to work/match for any given coding attempt.

We today support scenes with both fog and media(1). This support 
constrains the games that can be played with rays and media intervals in 
the code. Heck, might be why the code works as it does. In any case 
fog+media support was the primary impediment I hit given the general 
approach I tried.

(1) - With some limits/issues.

Someday, perhaps, when my C++ skills have improved, I'll get back to 
this effort. I currently think a somewhat major ray-interval/media/fog 
code re-factoring is needed.

Bill P.

Post a reply to this message