 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
This rendering was actually made a bit over a month ago, as a supplement
to my primary project of making a topographic map of Skyrim. That,
while based on a render of the game terrain data with a gradient slapped
on it to indicate elevations, is needing to be redone by hand to get
consistent-width contour lines (if I were clever, I'd probably be able
to figure out something much simpler and faster as an automated process,
but what can I say, glutton for punishment or something), so doesn't
really qualify for posting here.
This one's just a straightforward shaded relief map. It could really
use some smoothing, but the combined size of the meshes just doesn't
make that feasible (as far as I can tell).
Post a reply to this message
Attachments:
Download 'skyrim shaded relief low.jpg' (872 KB)
Preview of image 'skyrim shaded relief low.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 15-10-2012 13:49, Tim Cook wrote:
> This one's just a straightforward shaded relief map. It could really
> use some smoothing, but the combined size of the meshes just doesn't
> make that feasible (as far as I can tell).
It is looking very good, except for the low polygon zone on the southern
border ;-)
Should make an interesting landscape.
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmail com> wrote:
> This one's just a straightforward shaded relief map. It could really
> use some smoothing, but the combined size of the meshes just doesn't
> make that feasible (as far as I can tell).
Solitude's pretty prominent, isn't it? Other than that, only the hill of
Whiterun stands out as a city location... I'd like to say I can see the college
at Winterhold too, but I think that might just be my imagination.
Is this data from the map page, or the actual game world?
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
I do believe I just clicked on the 'reply' button instead of 'followup'...
...again.
Really dislike that 'feature' of Thunderbird.
I think the data I pulled is the level-of-detail terrain data from
in-game, one or another of which is used as the world-map as well...?
I'm of half a mind to take and scale the meshes so they match what I've
been able to discern of 'real' distances for things; they're squished
about 10x laterally and stretched 10x vertically, so when you correct
for that, Skyrim's a lot flatter. (It's about 250 lore-canon miles from
Dawnstar to Windhelm, or something like that...? Whereas in-game, if
you use their 128 units = 6 feet, it's only about 25 miles. And the
Throat of the World is iirc 52 miles high--again with the 128 units to 6
feet measure.)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> This rendering was actually made a bit over a month ago, as a supplement
> to my primary project of making a topographic map of Skyrim. That,
> while based on a render of the game terrain data with a gradient slapped
> on it to indicate elevations, is needing to be redone by hand to get
> consistent-width contour lines (if I were clever, I'd probably be able
> to figure out something much simpler and faster as an automated process,
> but what can I say, glutton for punishment or something), so doesn't
> really qualify for posting here.
Try out the following if/when you have a chance:
#declare NLines = 10; // number of elevation lines
#declare LineSize = 2; // line size in pixels (1.0-2.0)
#declare LineOffs = 0; // line offset (phase)(0.0-1.0)
// your input pigment
#declare PgInput =
pigment{
bumps
turbulence .5
lambda 2.5
}
#declare FInput =
function{
pattern{
pigment_pattern{
PgInput
phase LineOffs/NLines
color_map{
#for(V, 0, NLines)
[V/NLines rgb (mod(V,2)=0)]
[V/NLines+1/NLines rgb (mod(V,2)=0)]
#end
}
}
}
}
#declare FSpherical = function{pattern{spherical}}
#declare PgElevationLines =
pigment{
#declare LineSizeX = LineSize/image_width;
#declare LineSizeY = LineSize/image_height;
function{
FSpherical(
FInput(x+LineSizeX, y, 0)-FInput(x-LineSizeX, y, 0),
FInput(x, y+LineSizeY, 0)-FInput(x, y-LineSizeY, 0),
0
)
}
}
plane{z,0
pigment{PgElevationLines}
}
It's really only good for line thicknesses between 1-2 pixels, but at least the
lines are of an even width. Antialiasing is recommended. Hope it helps!
Sam
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Samuel Benge" <stb### [at] hotmailcom> wrote:
> It's really only good for line thicknesses between 1-2 pixels, but at least the
> lines are of an even width. Antialiasing is recommended. Hope it helps!
Here's a version using an improved method. Elevation lines of any thickness will
be drawn properly, at the expense of PPS:
#declare NLines = 10; // number of "elevation" lines
#declare LineSize = 3; // line size in pixels (1.0-?)
#declare LineOffs = 0; // line offset (phase)(0.0-1.0)
#declare LineRes = LineSize*16; // number of line samples (1=?)
// input pigment
#declare PgInput =
pigment{
bumps
turbulence .5
lambda 2.5
}
#declare FInput =
function{
pattern{
pigment_pattern{
PgInput
phase LineOffs/NLines
color_map{
#for(V, 0, NLines)
[V/NLines rgb (mod(V,2)=0)]
[V/NLines+1/NLines rgb (mod(V,2)=0)]
#end
}
}
}
}
#macro SampleLoop()
#for(N, 1, LineRes)
#local C = 1/LineRes*N;
#local R = pow(C*sqrt(N)/pow(LineRes,.5),1/3);
#local Angle = N*137.508;
#local Pt = vrotate(y*R, z*Angle);
#local PtX = Pt.x*LineSizeX;
#local PtY = Pt.y*LineSizeY;
, FInput(x+PtX, y+PtY, 0)
#end
#end
#declare PgElevationLines =
pigment{
#declare LineSizeX = LineSize/image_width;
#declare LineSizeY = LineSize/image_height;
function{
min(1 SampleLoop())*(FInput(x, y, 0)=1)
+
(1-max(0 SampleLoop()))*(FInput(x, y, 0)=0)
}
}
plane{z, 0
pigment{PgElevationLines}
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
I believe the code has reached its final state. Elevation lines are now mapped
correctly starting at elevation=0.0. Included is an option for using smoothed
lines or not, and it's all wrapped up nicely into a macro that produces a
pigment_pattern.
Use it or don't; I always script for fun :)
http://news.povray.org/povray.text.scene-files/thread/%3Cweb.507c9bbc53181abf2165ae730%40news.povray.org%3E/
Sam
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Samuel Benge" <stb### [at] hotmailcom> wrote:
> I believe the code has reached its final state.
Attached is an image rendered from the example scene, using eight elevation
lines. An acceptable result, IIDSSMS, although calculating the number of lines
needed for real-world data might prove to be somewhat of a challenge!
Post a reply to this message
Attachments:
Download 'elevationlines.png' (119 KB)
Preview of image 'elevationlines.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Needs a bit of fiddling (go right-hand rule!) and POV 3.7 to work, but...
...need to figure out proper scaling and offset, but I think that just
might let me bypass another month of hand-drawing contour lines.
Thanks!
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 16-10-2012 1:36, Samuel Benge wrote:
> I believe the code has reached its final state. Elevation lines are now mapped
> correctly starting at elevation=0.0. Included is an option for using smoothed
> lines or not, and it's all wrapped up nicely into a macro that produces a
> pigment_pattern.
>
> Use it or don't; I always script for fun :)
>
>
http://news.povray.org/povray.text.scene-files/thread/%3Cweb.507c9bbc53181abf2165ae730%40news.povray.org%3E/
>
Incredible, Sam. This can be a very useful feature. I shall certainly
use it. Thanks indeed.
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
A'ight, I think I'm doing something wrong here, because I'm not getting
the fixed-width contour lines.
Here's relevant bit of SDL:
#declare East_Land4 = union {
object { Land4_P00P00_to_P12P28 }
object { Land4_P20P00_to_P28P28 }
object { Land4_P00M04_to_P12M32 }
object { Land4_P16M04_to_P32M32 }
object { Land4_P32P00_to_P44_28 }
object { Land4_P48P00_to_P60P28 }
object { Land4_P32M04_to_P44M32 }
object { Land4_P48M04_to_P60M32 }
object { tamriel_4_12_60_ }
object { tamriel_4_28_60_ }
object { tamriel_4_44_60_ }
object { tamriel_4_60_60_ }
#declare InputPigment = pigment{
gradient z
rotate x*90
}
pigment{
Pg_Elevation_Lines(
InputPigment,
8,
3,
8,
0,
on
)
pigment_map{ [ 0 InputPigment][ 1 rgb x] }
rotate -90 * x
scale 16384.0 * 3.2
translate <0.0, 0.0, -13800.0>
}
finish{ ambient 1 diffuse 0 }
}
Halp?
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
Attachments:
Download 'tamrieleast.png' (217 KB)
Preview of image 'tamrieleast.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> I do believe I just clicked on the 'reply' button instead of 'followup'...
>
> ...again.
Oh yes. I've not yet been to Dawnstar, Riften or Morthal so I couldn't comment!
Trying to keep the quest list down to a manageable size :)
> I'm of half a mind to take and scale the meshes so they match what I've
> been able to discern of 'real' distances for things; they're squished
> about 10x laterally and stretched 10x vertically, so when you correct
> for that, Skyrim's a lot flatter. (It's about 250 lore-canon miles from
> Dawnstar to Windhelm, or something like that...? Whereas in-game, if
> you use their 128 units = 6 feet, it's only about 25 miles. And the
> Throat of the World is iirc 52 miles high--again with the 128 units to 6
> feet measure.)
I thought so, or it would take weeks to cross wilderness! It's quite a clever
effect though, the landscape hides the locations' proximities so on the ground
it feels like a real, large world.
If you get Sam's contours working, it'd be fun to see a tourist hiking map :)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> A'ight, I think I'm doing something wrong here, because I'm not getting
> the fixed-width contour lines.
>
> Here's relevant bit of SDL:
>
> #declare East_Land4 = union {
> object { Land4_P00P00_to_P12P28 }
> object { Land4_P20P00_to_P28P28 }
> object { Land4_P00M04_to_P12M32 }
> object { Land4_P16M04_to_P32M32 }
> object { Land4_P32P00_to_P44_28 }
> object { Land4_P48P00_to_P60P28 }
> object { Land4_P32M04_to_P44M32 }
> object { Land4_P48M04_to_P60M32 }
> object { tamriel_4_12_60_ }
> object { tamriel_4_28_60_ }
> object { tamriel_4_44_60_ }
> object { tamriel_4_60_60_ }
> #declare InputPigment = pigment{
> gradient z
> rotate x*90
> }
> pigment{
> Pg_Elevation_Lines(
> InputPigment,
> 8,
> 3,
> 8,
> 0,
> on
> )
> pigment_map{ [ 0 InputPigment][ 1 rgb x] }
> rotate -90 * x
> scale 16384.0 * 3.2
> translate <0.0, 0.0, -13800.0>
> }
> finish{ ambient 1 diffuse 0 }
> }
>
> Halp?
A simple "gradient z" will not work because it doesn't contain any topographical
information describing your landscape. The macro requires a height map, so
you'll need to produce one from East_Land4 and then pass it to the macro. (You
might even be able to use it for a height_field object instead of that union of
objects you have now, but I'm not sure, since I don't know how your scene is set
up.)
Once you have your height_map, you'll be going forward again. If not, just give
me a holler :)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-16 14:19, Samuel Benge wrote:
> A simple "gradient z" will not work because it doesn't contain any topographical
> information describing your landscape. The macro requires a height map, so
> you'll need to produce one from East_Land4 and then pass it to the macro. (You
> might even be able to use it for a height_field object instead of that union of
> objects you have now, but I'm not sure, since I don't know how your scene is set
> up.)
>
> Once you have your height_map, you'll be going forward again. If not, just give
> me a holler :)
Well, a little bit of progress, but something's obviously not right...
Here's what I've got now, with tamrielheightsmall.png being a straight
height-gradient render.
box{
<-7200,-4800,-0.1>,< 7200, 4800, 0.1>
#declare InputPigment = pigment{
image_pattern{ png "c:\downloads\tamrielheightsmall.png" }
rotate z*180
translate <-0.5, -0.5, 0.0>
scale <1,0.8,1>
}
pigment{
Pg_Elevation_Lines( InputPigment, 8, 2, 32, 0, off )
pigment_map{ [ 0 InputPigment][ 1 rgb x] }
}
finish{ ambient 1 diffuse 0 }
}
...and this is what it comes out as. (there's some weird noise at the
top and bottom that's there even with just using InputPigment as the
pigment, and the contour lines are all noisy)
Post a reply to this message
Attachments:
Download 'tamriel flat.png' (485 KB)
Preview of image 'tamriel flat.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> Well, a little bit of progress, but something's obviously not right...
>
> Here's what I've got now, with tamrielheightsmall.png being a straight
> height-gradient render.
>
<snip>
> ...and this is what it comes out as. (there's some weird noise at the
> top and bottom that's there even with just using InputPigment as the
> pigment, and the contour lines are all noisy)
Alright, after scratching my head for a while I've determined that the problem
is with your height data. I zoomed up on an unlined portion of your image and
saw a lot of noise; rendered it with Pg_Elevation_Lines, and got similar results
as yours.
So to get rid of the noise, try one of these options:
1) Open the height map in Gimp, and apply the Despeckle filter using its default
settings. Unfortunately, Gimp does not (yet!) support 16-bit grayscale.
-or-
2) Render your height map in POV-Ray using these command line options: +fng +f
+a0.01 +am2 +r3 This seems to be more accurate than Gimp's Depseckle filter,
although POV-Ray still cannot match the gamma of the original image, so
calculating the proper line spacing and offset with Pg_Elevation_Lines might
prove difficult.
Other program options include PhotoShop, Terragen, Wilbur, or any other program
that can manipulate 16-bit height maps.
Since I was unable to render your entire height map, I cannot say for certain if
the noise reduction techniques I tried would completely get rid of all the
artifacts, so you may need to tweak some settings here and there (interpolating
the image in POV-Ray comes to mind).
Sam
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-17 16:06, Samuel Benge wrote:
> Alright, after scratching my head for a while I've determined that the problem
> is with your height data. I zoomed up on an unlined portion of your image and
> saw a lot of noise; rendered it with Pg_Elevation_Lines, and got similar results
> as yours.
Hmm...I ran the height image through despeckle and a few blurs just now,
and it's not changing the amount of noise artifacts with the contour
lines...? Hmm.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-17 17:13, Tim Cook wrote:
> Hmm...I ran the height image through despeckle and a few blurs just now,
> and it's not changing the amount of noise artifacts with the contour
> lines...? Hmm.
Ah wait. If I run the original height map through POV using your
suggested settings it cleans up a lot...bit of an interesting result,
though.
Still noisy in places, hmm. Ok, using a lower number for +a increases
the noise...
Here's the render with +a0.05 +am2 +r4 and the function called with 20
lines, 1.05 width, 32 quality.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
Attachments:
Download 'tamriel flat.png' (476 KB)
Preview of image 'tamriel flat.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> On 2012-10-17 16:06, Samuel Benge wrote:
> > Alright, after scratching my head for a while I've determined that the problem
> > is with your height data. I zoomed up on an unlined portion of your image and
> > saw a lot of noise; rendered it with Pg_Elevation_Lines, and got similar results
> > as yours.
>
> Hmm...I ran the height image through despeckle and a few blurs just now,
> and it's not changing the amount of noise artifacts with the contour
> lines...? Hmm.
Hmm, it should have at least helped.
I was wrong about POV-Ray not mapping the gamma correctly: it does. Also, when
trying to re-render the height map in POV, you need to use "interpolate 2" in
addition to high AA settings.
Try the attached. It's just a simple blur filter, but it works for the tiny
portion I cropped from your image.
Failing that, try the blur/resample file a posted a while back:
http://news.povray.org/povray.text.scene-files/thread/%3C4d34c72d@news.povray.org%3E/?ttop=372491
You might want to render your map at 2x resolution with a decent amount of blur
(2-6), and scale it back down to its original size.
If none of that works, would you mind posting your entire height map so I can
figure out what's going wrong?
Post a reply to this message
Attachments:
Download 'blendpixelsb.pov.txt' (1 KB)
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ah! A problem your macro doesn't take into account (not sure how it
would, either, but who knows?) is that of depressions, where a given
contour line loop isn't an ascending hill, but a shallower area. On the
other image I'd rendered, they're easy to spot because the fade is on
the outside rather than the inside, so can be marked appropriately when
redrawing everything by hand.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-17 17:33, Samuel Benge wrote:
> If none of that works, would you mind posting your entire height map so I can
> figure out what's going wrong?
The original height map I rendered at 7200x4800, so it's a 2.4 MB png,
here's the reduced-size version. (Ehm, re-rendered...oh hey, I had
jitter 'on' in the antialiasing options there, that might've been
contributing to the noise level, let's see what it turns out with that
off.) *waits*
Here we go.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
Attachments:
Download 'tamrielheightsmall.png' (302 KB)
Preview of image 'tamrielheightsmall.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
And I get slightly different results when I pipe the original east or
west rendering into the macro.
I think Paint Shop Pro is not doing a very good job at maintaining PNG
fidelity when I combine the two halves. Blarg.
Maybe paint.net will be better.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> On 2012-10-17 17:33, Samuel Benge wrote:
> > If none of that works, would you mind posting your entire height map so I can
> > figure out what's going wrong?
>
> The original height map I rendered at 7200x4800, so it's a 2.4 MB png,
> here's the reduced-size version. (Ehm, re-rendered...oh hey, I had
> jitter 'on' in the antialiasing options there, that might've been
> contributing to the noise level, let's see what it turns out with that
> off.) *waits*
>
> Here we go.
Thanks, I'll see how it works out over here.
I noticed that your map uses elements of varying resolutions. Some parts are
sharp, while others are quite pixelated. That could be a big source of your
problems. AFAICT, noise reduction schemes assume that the noise is at or near
the pixel level (ie. sudden changes occur from one pixel to the next). If abrupt
changes occur over several pixels, you're going to have problems trying to
smooth things out.
There must be a magnification filter somewhere that can smooth the transitions,
like some sort of HQNx filter for height maps.
> Ah! A problem your macro doesn't take into account (not sure how it
> would, either, but who knows?) is that of depressions, where a given
> contour line loop isn't an ascending hill, but a shallower area.
It should. The attached render uses a converted and eroded digital elevation
model of Morongo Valley, CA (elevation lines were arbitrarily chosen). Near the
far upper right you can just make out an irregular depression ringed by a blue
line. Depressions in the desert aren't easy to come by--all the water flows down
hills and ravines--and consequently that is the only one I have found on this
particular map so far.
My macro takes everything literally, so a line is just as likely to loop around
a depression as it is a hill, it's just that depressions are less common and
might be missed if the spacing is too wide.
Post a reply to this message
Attachments:
Download 'mv-topo.jpg' (272 KB)
Preview of image 'mv-topo.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Samuel Benge" <stb### [at] hotmailcom> wrote:
> Tim Cook <z99### [at] gmailcom> wrote:
> > The original height map I rendered at 7200x4800, so it's a 2.4 MB png,
> > here's the reduced-size version.
>
> Thanks, I'll see how it works out over here.
Attached is an image combining contour lines from "tamrielheightsmall.png"
superimposed onto your relief map. The lines seem to behaving themselves. Is
this anywhere near what you wanted? I sure hope I haven't sent you on a wild
goose chase!
Here's the POV scene used to trace it:
// +fn +f +a0.1 +am2 +r3 +w1600 +h1067
#version 3.7;
global_settings{assumed_gamma 1.0}
#default{ finish{ ambient 1 } }
camera{
orthographic
right x*2 up y*2
location -z
look_at 0
}
#macro Pg_Elevation_Lines(PgInput, NLines, LineSize, Quality, LineOffs,
LineSmoothing)
#local Quality = max(1, int(Quality*LineSize));
#macro SampleLoop(Param)
max(
0
#for(N, 1, Quality)
#local C = 1/Quality*N;
#local R = pow(C*sqrt(N)/pow(Quality,.5),1/3);
#local Angle = N*137.508;
#local Pt = vrotate(y*R, z*Angle);
#local PtX = Pt.x*LineSizeX;
#local PtY = Pt.y*LineSizeY;
#if(Param)
, (1-R*LineSmoothing)*(1-FInput(x+PtX, y+PtY, 0))
#else
, (1-R*LineSmoothing)*FInput(x+PtX, y+PtY, 0)
#end
#end
)
#end
#local FInput =
function{
pattern{
pigment_pattern{
PgInput
phase 1-LineOffs/2
frequency NLines/2
color_map{
[.5 rgb 0]
[.5 rgb 1]
}
}
}
}
pigment_pattern{
#local LineSizeX = LineSize/image_width;
#local LineSizeY = LineSize/image_height;
function{
SampleLoop(1)*(FInput(x, y, 0)=1)
+
SampleLoop(0)*(FInput(x, y, 0)=0)
}
cubic_wave
warp{planar}
}
#end // Pg_Elevation_Lines
// map relief
plane{
z, 1
pigment{
average
pigment_map{
[.5 rgb 1]
[1
image_map{
"skyrim shaded relief low.jpg"
interpolate 2
}
scale 2
translate -1
]
}
}
}
// contour lines overlay
plane{z, 0
#declare InputPigment =
pigment{
image_pattern{
"tamrielheightsmall.png"
interpolate 2
}
scale 2
translate -1
}
pigment{
#declare NLines = 11;
Pg_Elevation_Lines( InputPigment, NLines, 3, 8, 0, off )
pigment_map{
[0
Pg_Elevation_Lines( InputPigment, NLines*5, 1.5, 8, 0, off)
pigment_map{
[0 rgb 0 transmit 1]
[1 rgb 0 transmit .5]
}
]
[1 rgb 0 transmit .5]
}
}
}
Post a reply to this message
Attachments:
Download 'tamriel-contours.jpg' (344 KB)
Preview of image 'tamriel-contours.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Samuel Benge" <stb### [at] hotmailcom> wrote:
> Attached is an image combining contour lines from "tamrielheightsmall.png"
> superimposed onto your relief map.
Tim, I must mention that I thickened every fifth line, just in case you were
wondering why their widths vary :)
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-17 20:20, Samuel Benge wrote:
> I noticed that your map uses elements of varying resolutions. Some parts are
> sharp, while others are quite pixelated.
I know...the underwater areas at the upper-left in particular are much
lower resolution than other places, and that's purely game-data issue.
I guess they thought nobody'd notice.
> My macro takes everything literally, so a line is just as likely to loop around
> a depression as it is a hill, it's just that depressions are less common and
> might be missed if the spacing is too wide.
That's what I meant; if you have a donut-shaped hill, so that it has two
concentric rings that are actually the same altitude, with the centre
being a divot, it will look identical to a hill that's taller and
crosses the next elevation line up.
Any way of checking the slope direction/comparing the height
before/after the contour line, then generating perpendicular
inward-pointing ticks for depressions?
XD
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-17 21:19, Samuel Benge wrote:
> Attached is an image combining contour lines from "tamrielheightsmall.png"
> superimposed onto your relief map. The lines seem to behaving themselves. Is
> this anywhere near what you wanted? I sure hope I haven't sent you on a wild
> goose chase!
>
> Here's the POV scene used to trace it:
Oh...my. That's smexy. Think you did some modification to your macro
to do the index contours plus regulars from the version I snagged, v. nice.
Now to get to the minor tweaking. Running this at a stoopid-high
resolution, adding the shorelines/waterways, labelling...
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> It should. The attached render uses a converted and eroded digital elevation
> model of Morongo Valley, CA (elevation lines were arbitrarily chosen).
This is an interesting render.
Paolo
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
So, with the gracious assistance of Mr. Benge, I have been able to
progress by leaps and bounds, adding the initial pass of roads
(transcribed from the mod that adds those to the world map). I have
made some minor adjustments to make the roads better fit the terrain,
but not many; somewhat surprisingly (to me, at least), the roads in
Skyrim follow the contours of the land in a way that makes sense. Usually.
I had rendered the contour lines a bit light, I need to either rerender
or adjust in another layer. The landmark icons are the in-game ones,
and I need to verify/correct their locations, and replace them with
appropriate 'real' map symbols (or things that look as such). Think I
need to check on some of the roads, too, but...it's a great deal further
along than I had hoped to be.
When this is complete, the next logical stage will be to render the rest
of the terrain data and make a mod for Skyrim to display the topography
in its world map.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
Attachments:
Download '2456219 skyrim topo.jpg' (946 KB)
Preview of image '2456219 skyrim topo.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Awesome.
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
>Tim Cook on date 18/10/2012 19.28 wrote:
> So, with the gracious assistance of Mr. Benge, I have been able to
> progress by leaps and bounds, adding the initial pass of roads
> (transcribed from the mod that adds those to the world map). I have
> made some minor adjustments to make the roads better fit the terrain,
> but not many; somewhat surprisingly (to me, at least), the roads in
> Skyrim follow the contours of the land in a way that makes sense. Usually.
>
> I had rendered the contour lines a bit light, I need to either rerender
> or adjust in another layer. The landmark icons are the in-game ones,
> and I need to verify/correct their locations, and replace them with
> appropriate 'real' map symbols (or things that look as such). Think I
> need to check on some of the roads, too, but...it's a great deal further
> along than I had hoped to be.
>
> When this is complete, the next logical stage will be to render the rest
> of the terrain data and make a mod for Skyrim to display the topography
> in its world map.
>
> --
> Tim Cook
> http://empyrean.sjcook.com
This is an intriguing map!
Paolo
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Paolo Gibellini <p.g### [at] gmailcom> wrote:
> > It should. The attached render uses a converted and eroded digital elevation
> > model of Morongo Valley, CA (elevation lines were arbitrarily chosen).
> This is an interesting render.
> Paolo
That about describes it, because it's certainly not accurate. Besides
arbitrarily placing the contours, I'd managed to accidently get the map both
flipped horizontally and rotated 180 degrees. You'd think after all these years,
I'd know better! :P
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> So, with the gracious assistance of Mr. Benge, I have been able to
> progress by leaps and bounds, adding the initial pass of roads
> (transcribed from the mod that adds those to the world map). I have
> made some minor adjustments to make the roads better fit the terrain,
> but not many; somewhat surprisingly (to me, at least), the roads in
> Skyrim follow the contours of the land in a way that makes sense. Usually.
>
> I had rendered the contour lines a bit light, I need to either rerender
> or adjust in another layer. The landmark icons are the in-game ones,
> and I need to verify/correct their locations, and replace them with
> appropriate 'real' map symbols (or things that look as such). Think I
> need to check on some of the roads, too, but...it's a great deal further
> along than I had hoped to be.
>
> When this is complete, the next logical stage will be to render the rest
> of the terrain data and make a mod for Skyrim to display the topography
> in its world map.
It's looking good, Tim. Seems like it would be a fun place to explore. Are the
elevation lines in sync with Skyrim's sense of altitude?
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-19 15:34, Samuel Benge wrote:
> It's looking good, Tim. Seems like it would be a fun place to explore. Are the
> elevation lines in sync with Skyrim's sense of altitude?
The in-game scale is 128 units = 6 feet, and the Throat of the World
being at 21600 units above sea level. That comes to 1012.5 feet...a bit
short (Mt. Everest (er, Qomolongma) is 4.7 miles).
HOWEVER, if you look at the scale of things /along the ground/, the
horizontal distance between Dawnstar and Winterhold is about 61350
units. That'd be 2867 feet (bit over half a mile). Per canon (near as
I can tell, if this other map is accurate), it should be about 75 miles.
So horizontally it's off by let's say a factor of 40 (I'd previously
calculated it to 10, so need to fix my scale), and if you scale up the
verticals by the same amount, that puts the Throat of the World at 7.67
miles. So...let's say vertical exaggeration of 25x, puts the highest
peak on Nirn at 4.79 miles, and the lowest depth (on the map I have) at
25290 units below sea level, or 5.61 miles adjusting for the 25x factor
(Challenger Deep on Earth is 6.85 miles).
So I need to rerender after figuring... Total altitude range is 46890
units, which ends up being 54949 feet...let's say 55,000 feet. Calling
the macro with 11 would give 5000-foot indexes. (Had used 13 and change
on my current version).
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
And here's a sized-down version of the current version of the map.
Turns out an 8192x8192 image isn't something my computer is particularly
happy about being asked to work with, with multiple layers (even vector)
in an image editor.
I yet need to go in and do the shoreline and water features, swap out
the placeholder dots with map symbols, add the secondary and tertiary
roads, the borders, expand into Cyrodiil, High Rock, Hammerfell, and
Morrowind, add the canon cities from Skyrim that were left out of Skyrim
the game, maybe mark the forested areas...oh yeah and add labels to
everything.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
Attachments:
Download 'tamriel topo 2048.png' (762 KB)
Preview of image 'tamriel topo 2048.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tim Cook <z99### [at] gmailcom> wrote:
> And here's a sized-down version of the current version of the map.
> Turns out an 8192x8192 image isn't something my computer is particularly
> happy about being asked to work with, with multiple layers (even vector)
> in an image editor.
Looks good. Red lines are paved roads, yes?
Is it worth trying to convert this to a vector format, svg or something? This
type of graphic cries out to be in a non-bitmap form.
Bill
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 2012-10-25 02:26, Bill Pragnell wrote:
> Looks good. Red lines are paved roads, yes?
Thicker ones, yes. Started adding a few secondary unpaved roads; 7000
Steps up to High Hrothgar in particular was missing in the map mod I
had, so I had to compile and use the UESP wiki's map (which is much
better reference).
> Is it worth trying to convert this to a vector format, svg or something? This
> type of graphic cries out to be in a non-bitmap form.
Ah yeah, svg might be a better format to use than psp. I don't want to
hand-trace and optimize all the contour lines, though. :( The
coastline and waterways stage is going to be enough of a nuisance. Any
program that can do that for me?
It would massively reduce the file size.
Also note: the image should be able to be chopped up and converted into
.dds files and used as the in-game map, at this point. There's a bit of
distortion due to my initial rendering of the height map from Moray,
which doesn't have the orthographic camera type, but it should be minor.
--
Tim Cook
http://empyrean.sjcook.com
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
