Hi, everyone!

I've been so busy at work this year I've barely had time to lurk here. And
I've been spending most of my spare time at home learning Unix, and haven't
had much time for raytracing. Which is kind of ironic, considering I
installed Unix mostly because of POV. :)

I have done some things with POV, though. I was trying to make more
realistic sand, when I stumbled upon this texture, which immediately
reminded me of sandstone. I haven't done much with the colours yet, but I
hope these images show the potential.

I have a funny monitor. You may need to drop the brightness &/or gamma to
see my images the way I do.

Post a reply to this message

Attachments:
Download 'sandstoneaw1.jpg' (243 KB)

Preview of image 'sandstoneaw1.jpg'

// Persistence of Vision Ray Tracer Scene Description File
// File: Sandstone.pov
// Vers: 3.6
// Desc: Pyramid of sandstone blocks
// Date: 2006.02.06
// Auth: PM 2Ring
//
//  -d +A0.2 +AM2 +R2
//

#include "functions.inc"

global_settings {
  assumed_gamma 1.0
}

//Block dimensions etc
#declare W = 1.5;
#declare D = 1.5;
#declare H = 0.75*1.25;
#declare ROUGH = 0.30*.75;        //Bump height      //0.45, 0.22
#declare BUSY = 0.40;           //Bump period
#declare M=0.975; //1.0075;       //Mortar space adjustment
//#declare M=1.05;       //Mortar space adjustment

//Number of levels in pyramid. Also controls floorsize & light & camera
distance, along with H.
#declare LEVELS=12;

//---The functions--------------------------------------------------------

#declare f_Sandstone = function{f_wrinkles(x*BUSY, y*BUSY, z*BUSY)}

#declare f_Ground =
function{
   0.125*f_noise3d(x*1.5, y*1.5, z*1.5)
 + 0.005*f_noise3d(x*70,  y*60,  z*70)
}

//---The textures---------------------------------------------------------
#declare SkyBlue = rgb<.035, .27, .67>+.125;
#declare Sandy = rgb<1, .9, .675>;

#declare FSand1 =
finish{
  diffuse 0.75 ambient 0.125
  specular 1 roughness 1e-3
}

#declare FSandstone =
finish{
  diffuse 0.75 ambient 0.05
}

#declare NSand1 = normal{granite 0.125 scale 1.5E-3}

#declare TSand1 =
texture{
  pigment {Sandy }
  finish{FSand1}
  //normal{NSand1 .15}
}

#declare Transmit = .8;
#declare CM_Sandstone =
colour_map{
  [0.3 rgbt <1, 1, 1, 1.2*Transmit>]
  [0.4 rgbt <1, 0, 0, Transmit>]
  [0.41 rgbt <0.5, 0.2, 0.1, .5*Transmit>]
  [0.42 rgbt <1, 0, 0, .75*Transmit>]
  [0.6 rgbt <1, 0.5, 0, Transmit>]
  [0.7 rgbt <1, 1, 1, .5*Transmit>]
}

#declare TSandstone =
texture{
  pigment {Sandy}
  finish{FSandstone}
}

#declare TStain = texture{
  pigment{
    wrinkles
    turbulence 0.1875
    colour_map{CM_Sandstone}
    //scallop_wave

    translate 0.95*1.1
    rotate <10, 75, 25>
    scale 1.5*W*7
  }
  finish{FSandstone}
}

#declare TSandstone2 =
texture{TSandstone}
texture{TStain}

//---The objects---------------------------------------------------------

#declare TScale = 3.75;    //Texture scale adjustment
//#declare TScale = 2.345;    //Texture scale adjustment

//Plain block
#macro Block(cx,cy,cz)
box{
  -1,1
  scale <W, H, D>
  translate <cx, cy, cz>

  texture{
    TSandstone2
    normal{granite .25 scale 3e-2}
    translate <cx,cy,cz>*TScale
  }
  translate y*(H-0*.5*ROUGH)
}
#end

//Stone Block
#macro IsoBlock(cx,cy,cz)
isosurface{
  function {
    max(
      abs(x-cx)-(W-ROUGH*f_Sandstone(x, y, z)),
      abs(y-cy)-(H-ROUGH*f_Sandstone(x, y, z)),
      abs(z-cz)-(D-ROUGH*f_Sandstone(x, y, z))
    )
  }
  contained_by{box{<cx-W, cy-H, cz-D>, <cx+W, cy+H, cz+D>}}
  max_gradient 1.2 // 1.1 // 1.25 // 1 1.4
  accuracy 1e-3

  texture{TSandstone2 translate <cx,cy,cz>*TScale}
  translate y*(H-0.5*ROUGH)
}
#end

#declare U=W*M;
#declare V=D*M;
#declare HH=H*2;
#declare HH=(HH-ROUGH);

//Stack blocks into a hollow pyramid.
#declare Pyramid =
union{
  #declare mk=2;
  #declare k=LEVELS-1;
  #while(k>=mk)
    #declare j=-k;
    #while(j<=k)
      #declare i=-k;
      #while(i<=k)
        #if(abs(i)=k | abs(j)=k | k=mk)
          //Block(i*U, (LEVELS-k-1)*HH, j*V)
          IsoBlock(i*U, (LEVELS-k-1)*HH, j*V)
        #end
        #declare i=i+2;
      #end
      #declare j=j+2;
    #end
    #declare k=k-1;
  #end
}

#declare BB=6 * LEVELS;

#declare Ground =
isosurface{
  function{y - f_Ground(x/6, y/6, z/6)}

  max_gradient 1.1
  contained_by { box{ <-BB,-1,-BB>, <BB,1,BB>} }
  accuracy 5e-3

  texture{TSand1 scale 4}
}

//---The scene---------------------------------------------------------

#if(1)
  sky_sphere{
    pigment{
      function{y}
      color_map{
        [0.0 SkyBlue]
        [0.19 rgb <0.0,0.1,0.8>*.60]
      }
      translate -y * .275
      scale 0.85
    }
  }
#else
  background{SkyBlue}
#end

object{Ground}
object{Pyramid rotate -25*y}

//#declare CamPos = <0, 4.875, -7.75> * 1.25 * LEVELS*H;

#declare CamPos = <0, 1.875*H, -1.875*W> * 1.2 * LEVELS;
camera {
  location CamPos
  direction z
  right     x*image_width/image_height up y
  look_at   1.0*LEVELS*H*y
  angle 30
}

light_source {
  <-0.5, 1, -1> * 8 * LEVELS*H
  rgb 1.25
  //area_light .2*x,.2*z, 3,3 jitter adaptive 1 orient circular
}

//---The end---------------------------------------------------------

Post a reply to this message

Attachments:
Download 'sandstoneeg1s.jpg' (115 KB)

Preview of image 'sandstoneeg1s.jpg'

Very cool...

Can we get the source to the first picture you posted? The code you posted
is too advanced for me, and I want to render it in 1600x1200 for a
wallpaper.

Post a reply to this message

"etrask" <et7### [at] yahoocom> wrote:
> Very cool...

Thanks!

> Can we get the source to the first picture you posted? The code you posted
> is too advanced for me, and I want to render it in 1600x1200 for a
> wallpaper.

Sorry, I've only got modified versions here at home: the original is on my
machine at work. This one is pretty close, though. To get closer, play with
the H variable in the Ground isosurface, & the scale parameter in TStain.
Also play with the gradient vector & turbulence.

Warning: this can be very slow to render with high anti-alias.

// Persistence of Vision Ray Tracer Scene Description File
// File: Sandstone.pov
// Vers: 3.6
// Desc:
// Date: 2006.02.06
// Auth: PM 2Ring
//
//  -F -A0.5 +AM2 +R1
//  -d +W1200 +H900 +A0.1 +AM2 +R3
//  -d +A0.2 +AM2 +R2
//

//#include "colors.inc"
#include "functions.inc"

global_settings {
  assumed_gamma 1.0
}

//---The textures---------------------------------------------------------

#declare Sandy = color rgb<1, .9, .65>;

#declare Transmit = .8;
#declare CM_Sandstone =
colour_map{
  [0.3 rgbt <1, 1, 1, 1.2*Transmit>]
  [0.4 rgbt <1, 0, 0, Transmit>]
  [0.41 rgbt <0.5, 0.3, 0.1, .5*Transmit>]
  [0.42 rgbt <1, 0, 0, .75*Transmit>]
  [0.6 rgbt <1, 0.5, 0, Transmit>]
  [0.7 rgbt <1, 1, 1, .5*Transmit>]
}

#declare FSandstone =
finish{
  diffuse 0.85 ambient 0.05
}

#declare TSandstone =
texture{
  pigment {Sandy}
  finish{FSandstone}
}

#declare TStain = texture{
  pigment{
    //agate
    gradient <.3, 2, .1>//2
    turbulence 0.15
    colour_map{CM_Sandstone}
    scale 0.75
  }
  finish{FSandstone}
}

#declare TSandstone2 =
texture{TSandstone}
texture{TStain}

//---The objects---------------------------------------------------------

#declare f_Height = function{0.5*f_wrinkles(x*.4, y*.4, z*.4)}

#declare H = 0.6;
#declare Ground =
isosurface {
  function {(y - f_Height(x, 0, z))/H}
  max_gradient 2.0
  contained_by {box {<-4,-5,-4>, < 4, 1, 4>}}
  accuracy 1e-3
}

//---The scene---------------------------------------------------------

object{Ground texture{TSandstone2 translate 17.123}}

#declare CamPos = <0.45, 6, -8>* .35;
//#declare CamPos = 4*y;

camera {
  location CamPos
  direction z
  right     x*image_width/image_height up y
  look_at   y* 0.25
  angle 40
}

light_source {
  <-0.5, 1, -1> * 8
  #if(1)
    rgb 1.15 // 1.75
  #else
    rgb 45
    fade_distance 1.25 fade_power 2
  #end
}

//---The end---------------------------------------------------------

Post a reply to this message

Very realistic indeed! An excellent sandstone, especially when it has been
exposed to weathering and/or ground water seepage. I shall certainly take it
up in my (small) collection of geological textures.

Thomas

Post a reply to this message

"Thomas de Groot" <t.d### [at] internlnet> wrote:
> Very realistic indeed! An excellent sandstone, especially when it has been
> exposed to weathering and/or ground water seepage. I shall certainly take it
> up in my (small) collection of geological textures.
>
> Thomas

Thanks, Thomas. It's always nice to get your geologist's approval of my
stones.
Living in Sydney, I've seen weathered sandstone all my life, and plenty
weathered by seepage. Sydney basin is built on sandstone and shale. As well
as the white, yellow and apricot colours of my palette, the real stones have
some beautiful shades of red, ranging from pale rose pinks to an almost
purple colour. I know the reds & yellows come from iron, but I don't know
about the purple.

Here's a large stone block sitting on a floor in a geology museum (maybe :)
Sorry, the source code is a bit messy...

// Persistence of Vision Ray Tracer Scene Description File
// File: Sandstone.pov
// Vers: 3.6
// Desc:
// Date: 2006.02.06
// Auth: PM 2Ring
//
//  -D +A0.1 +AM2 +R2
//  -F -A0.5 +AM2 +R1
//  -F +A0.6 +AM2 +R2
//  -d +W1200 +H900 +A0.3 +AM2 +R2
//  -d +W1200 +H900 +A0.1 +AM2 +R3
//
//  -d +A0.2 +AM2 +R2 +C
// povray SandstoneD.pov +p +A0.2 +AM2 +R2 +W800 +H600
//

//#include "colors.inc"
#include "functions.inc"

global_settings {
  assumed_gamma 1.0
  max_trace_level 5
}

//Block dimensions
#declare W = 1.25;
#declare D = 1.5;
#declare H = 0.75;
#declare ROUGH = 0.45;          //Bump height
#declare BUSY = 0.40;           //Bump period

//---The textures---------------------------------------------------------

#declare SkyBlue = rgb<.035, .27, .67>;              //For water & sky
#declare Sandy = rgb<1, .9, .65>;

#declare Transmit = .8;
#declare CM_Sandstone =
colour_map{
  [0.3 rgbt <1, 1, 1, 1.2*Transmit>]
  [0.4 rgbt <1, 0, 0, Transmit>]
  [0.41 rgbt <0.5, 0.2, 0.1, .5*Transmit>]
  [0.42 rgbt <1, 0, 0, .75*Transmit>]
  [0.6 rgbt <1, 0.5, 0, Transmit>]
  [0.7 rgbt <1, 1, 1, .5*Transmit>]
}

#declare FSandstone =
finish{
  diffuse 0.85 ambient 0.05
  //brilliance .5
}

#declare TSandstone =
texture{
  pigment {Sandy}
  finish{FSandstone}
}

#declare TStain = texture{
  pigment{
    //agate    //maybe try something derived from f_Height
    //wrinkles  //good!
    //wood
    marble
    //gradient <.3, 2, .1>/2
    turbulence 0.1875
    colour_map{CM_Sandstone}
    //scallop_wave

    translate 0.95*1.1
    rotate <10, 75, 25>
    scale 1.5*W*7
  }
  finish{FSandstone}
}

#declare TSandstone2 =
texture{TSandstone}
texture{TStain}

//---The objects---------------------------------------------------------

#declare f_Height = function{f_wrinkles(x*BUSY, y*BUSY, z*BUSY)}
#declare smod = function(A,B) {mod(B+mod(A,B),B)}

//#declare f_cnoise = function(x,z) {(W-R)*f_snoise3d(floor(x*.5/W), 0,
floor(z*.5/W))}
//#declare f_modnoise = function(x,z) {smod(x,2*W)-W+f_cnoise(x,z)}

//Stone Blocks
#declare IsoBlocks =
isosurface{
  function {
    max(
      smod(x,2)-(W-ROUGH*f_Height(x, y, z)),
      smod(z,2)-(D-ROUGH*f_Height(x, y, z)),

      //abs(x)-W*(1-ROUGH*f_Height(x, y, z)),
      abs(y)-(H-ROUGH*f_Height(x, y, z))
      //abs(z)-D*(1-ROUGH*f_Height(x, y, z))
    )
  }
  contained_by{box{<-W*5, -H, -D*5>, <W*5, H, D*5>}}
  max_gradient 16
  accuracy 3e-4
  //all_intersections
}

#declare IsoBlock =
isosurface{
  function {
    max(
      abs(x)-(W-ROUGH*f_Height(x, y, z)),
      abs(y)-(H-ROUGH*f_Height(x, y, z)),
      abs(z)-(D-ROUGH*f_Height(x, y, z))
    )
  }
  contained_by{box{<-W, -H, -D>, <W, H, D>}}
  max_gradient 1.3
  accuracy 1e-5
  //all_intersections
}

#declare Ground =
isosurface {
  function {(y - f_Height(x, y, z))}
  max_gradient 3.6
  contained_by {box {<-4,-5,-4>, < 4, 1, 4>}}
  accuracy 1e-3
}

#declare BB=12;
#declare Floor =
box{
  <-BB,-1,-BB>,<BB,0,BB>
  pigment{checker rgb .1, rgb 1 rotate -45*y}
  finish{
    ambient 0.1 reflection 0.175
  }
}

//---The scene---------------------------------------------------------

object{IsoBlock texture{TSandstone2}  rotate -30*y translate y*(H-ROUGH/2)}

#if(0)
  object{Ground texture{TSandstone2 translate 17.123}}
#else
  object{Floor}
#end

#if(0)
  //#declare SkyBlue = 2; //2.5 + SkyBlue;
  sky_sphere {
    pigment {
      gradient y
      color_map {
        [0.4 0.1*SkyBlue]
        [0.9 0.8*SkyBlue]
        [1   1.0*SkyBlue]
      }
    }
  }
#else
  background{rgb .5}
#end

#declare CamPos = <0.45, 3.75, -6.25> * 0.9;
//#declare CamPos = 4*y;
camera {
  location CamPos
  direction z
  right     x*image_width/image_height up y
  look_at   y* 0.3
  angle 40
}

light_source {
  <-0.5, 1, -1> * 8
  #if(0)
    rgb 1.25 // 1.75
  #else
    rgb 50
    //spotlight point_at <-1,-1,0> falloff 2.25 radius 0.35
    //area_light .2*x,.2*z, 3,3 jitter adaptive 1 orient circular
    fade_distance 1.25 fade_power 2
  #end
}

//---The end---------------------------------------------------------

Post a reply to this message

Attachments:
Download 'sandstonee0s.jpg' (123 KB)

Preview of image 'sandstonee0s.jpg'

It's amazing how many good background images I get out of these 
groups...  Maybe the POV team should publish a compilation, "The Best of 
P.B.I." ?

...Chambers

Post a reply to this message

> some beautiful shades of red, ranging from pale rose pinks to an almost
> purple colour. I know the reds & yellows come from iron, but I don't know
> about the purple.

Manganese?
See e.g. http://web.uct.ac.za/depts/geolsci/dlr/kirstenbosch/mang1.htm
Nice fresh-hewn sandstone btw.

DLM

Post a reply to this message

"PM 2Ring" <nomail@nomail> schreef in bericht
news:web.445210571843be3376ba2c900@news.povray.org...
>
> Thanks, Thomas. It's always nice to get your geologist's approval of my
> stones.

Oh hum... <grin>

> Living in Sydney, I've seen weathered sandstone all my life, and plenty
> weathered by seepage. Sydney basin is built on sandstone and shale. As
well
> as the white, yellow and apricot colours of my palette, the real stones
have
> some beautiful shades of red, ranging from pale rose pinks to an almost
> purple colour. I know the reds & yellows come from iron, but I don't know
> about the purple.
>
It very much depends on the minerals in solution percolating through. Iron
of course, manganese like dlm says. I am not too familiar with that branch
of the trade. The irony is of course that I am living in a country that is
very poor in hard rock! But you can get the same kind of staining in sands
too, especially in the older deposits from the Pleistocene. And sands are
the building blocks of sandstones, so...


Thomas

Post a reply to this message

"Thomas de Groot" <t.d### [at] internlnet> a écrit dans le message de
news:44531438@news.povray.org...
>
>The irony is of course that I am living in a country that is
> very poor in hard rock!

Just wait few millions years ;-)

Marc

Post a reply to this message

"PM 2Ring" <nomail@nomail> wrote:

>
> Here's a large stone block sitting on a floor in a geology museum (maybe :)
> Sorry, the source code is a bit messy...
>

Wow, that's really excellent. Thanks for posting the code, especially the
isosurface functions. I look forward to playing around with those.

Ken

Post a reply to this message

"Marc Jacquier" <jac### [at] wanadoofr> schreef in bericht
news:4453b0c2@news.povray.org...
>
> "Thomas de Groot" <t.d### [at] internlnet> a écrit dans le message de
> news:44531438@news.povray.org...
> >
> >The irony is of course that I am living in a country that is
> > very poor in hard rock!
>
> Just wait few millions years ;-)
>

<grin> yes, I intend to! There will probably be a small ocean over here, if
the Lower Rhine slenk continues to open a bit more. Nothing spectacular
however. We have first to close the Mediterranean (and relocate all those
poor tourists).

Thomas

Post a reply to this message

High!

Thomas de Groot wrote:
> The irony is of course that I am living in a country that is
> very poor in hard rock!

Yes, the Netherlands aren't exactly Afghanistan... but what if you take 
a closer look at Mt. Vaalserberg in your far south?

See you in Khyberspace!

Yadgar

Now playing: In the Dutch Mountains (The Nits) ;-)

Post a reply to this message

"Jörg 'Yadgar' Bleimann" <yaz### [at] gmxde> a écrit dans le message de
news:4454de9f$1@news.povray.org...
> High!
>
> Thomas de Groot wrote:
> > The irony is of course that I am living in a country that is
> > very poor in hard rock!
>
> Yes, the Netherlands aren't exactly Afghanistan...
The Netherlands and Afghanistan have something common, they both are.. very
different :-)

Marc

Post a reply to this message

Jörg 'Yadgar' Bleimann wrote:
> High!
> 
> Thomas de Groot wrote:
> 
>> The irony is of course that I am living in a country that is
>> very poor in hard rock!
> 
> 
> Yes, the Netherlands aren't exactly Afghanistan... but what if you take 
> a closer look at Mt. Vaalserberg in your far south?
> 
I think you'll find limestone there, not a particularly hard rock.

> See you in Khyberspace!
> 
> Yadgar
> 
> Now playing: In the Dutch Mountains (The Nits) ;-)
The only Dutch Mountains worth mentioning.

now playing: nothing.

Post a reply to this message

"Jörg 'Yadgar' Bleimann" <yaz### [at] gmxde> schreef in bericht
news:4454de9f$1@news.povray.org...
> High!
>
> Thomas de Groot wrote:
> > The irony is of course that I am living in a country that is
> > very poor in hard rock!
>
> Yes, the Netherlands aren't exactly Afghanistan... but what if you take
> a closer look at Mt. Vaalserberg in your far south?
>
Sure. That's why I said "poor". Only the extreme east and south of the
country.

>
> Now playing: In the Dutch Mountains (The Nits) ;-)

<grin> the only Dutch mountains I know of are the "Frisian Mountains" that
appear on the label of Beerenburg bottles!!!


Thomas

Post a reply to this message

That's a great sandstone texture.
-- 
Bill Hails
http://billhails.net/

Post a reply to this message

"dlm" <me### [at] addressinvalid> wrote:
> > some beautiful shades of red, ranging from pale rose pinks to an almost
> > purple colour. I know the reds & yellows come from iron, but I don't know
> > about the purple.
>
> Manganese?
> See e.g. http://web.uct.ac.za/depts/geolsci/dlr/kirstenbosch/mang1.htm

Hmmm... Yes that does look like the right hue. I guess I should really look
up some local geology info. Or visit the Sydney Geology Museum with a sample
in hand. :)

> Nice fresh-hewn sandstone btw.
>
> DLM

Thanks, DLM, and thanks to everybody for your kind comments about this
stone.

Post a reply to this message

"Thomas de Groot" <t.d### [at] internlnet> wrote:
> "PM 2Ring" <nomail@nomail> schreef in bericht
> news:web.445210571843be3376ba2c900@news.povray.org...
> >
> > Thanks, Thomas. It's always nice to get your geologist's approval of my
> > stones.
>
> Oh hum... <grin>
>
> > Living in Sydney, I've seen weathered sandstone all my life, and plenty
> > weathered by seepage. Sydney basin is built on sandstone and shale. As
> well
> > as the white, yellow and apricot colours of my palette, the real stones
> have
> > some beautiful shades of red, ranging from pale rose pinks to an almost
> > purple colour. I know the reds & yellows come from iron, but I don't know
> > about the purple.
> >
> It very much depends on the minerals in solution percolating through. Iron
> of course, manganese like dlm says. I am not too familiar with that branch
> of the trade. The irony is of course that I am living in a country that is
> very poor in hard rock! But you can get the same kind of staining in sands
> too, especially in the older deposits from the Pleistocene. And sands are
> the building blocks of sandstones, so...

Yes, I was expecting you to be an expert in sedimentary rocks, from your
location. I guess you're attracted to more exotic geography. :)

There's a big tunnel being built here at the moment and my route to work
lets me see most of the constructions. So I've seen plenty of freshly
exposed sandstone lately. Some of the pieces have been beautiful.

Post a reply to this message

"PM 2Ring" <nomail@nomail> schreef in bericht
news:web.445621421843be3376ba2c900@news.povray.org...
>
> Yes, I was expecting you to be an expert in sedimentary rocks, from your
> location. I guess you're attracted to more exotic geography. :)

Well yes, I do certainly. But that said, the soft rock geology we have here
can be very complex too and poses a lot of challenges. However, the main
problem is that you have to do most work from boreholes, and I miss those
beautiful outcrops sometimes....
>
> There's a big tunnel being built here at the moment and my route to work
> lets me see most of the constructions. So I've seen plenty of freshly
> exposed sandstone lately. Some of the pieces have been beautiful.
>

Oh dear! Temptation! Temptation!  :-)

Thomas

Post a reply to this message

"Thomas de Groot" <t.d### [at] internlnet> wrote:
> "PM 2Ring" <nomail@nomail> schreef in bericht
> news:web.445621421843be3376ba2c900@news.povray.org...
> >
> > Yes, I was expecting you to be an expert in sedimentary rocks, from your
> > location. I guess you're attracted to more exotic geography. :)
>
> Well yes, I do certainly. But that said, the soft rock geology we have here
> can be very complex too and poses a lot of challenges.

Understood. Soft rock is just so much more porous than most hard rocks, and
even if the main particles are not very reactive (like quartz), they
provide plenty of spaces for other molecular species to react with each
other and with whatever is binding the sedimentary rock.

> However, the main
> problem is that you have to do most work from boreholes, and I miss those
> beautiful outcrops sometimes....
> >
> > There's a big tunnel being built here at the moment and my route to work
> > lets me see most of the constructions.

This is a tunnel for motor vehicles, running several kilometres. My
apartment is near one end, my place of work near the other. A collapse
happened (near the middle) in one of the ventillation tunnels late last
year, causing damage to an apartment block. Here's a link:
http://www.industrysearch.com.au/news/viewrecord.asp?id=19863

> > So I've seen plenty of freshly exposed sandstone lately.
> > Some of the pieces have been beautiful.

> Oh dear! Temptation! Temptation!  :-)

I've been tempted to grab some samples, before they get crushed and disposed
of... I'd send you some, but the postage would kill me. :)

Post a reply to this message

"PM 2Ring" <nomail@nomail> schreef in bericht
news:web.4458bb911843be331bd1c060@news.povray.org...

> This is a tunnel for motor vehicles, running several kilometres. My
> apartment is near one end, my place of work near the other. A collapse
> happened (near the middle) in one of the ventillation tunnels late last
> year, causing damage to an apartment block. Here's a link:
> http://www.industrysearch.com.au/news/viewrecord.asp?id=19863
>
Interesting!! Thanks for the info. A familiar problem surfacing here...

>
> I've been tempted to grab some samples, before they get crushed and
disposed
> of... I'd send you some, but the postage would kill me. :)
>
Thank you  indeed for your kind thought! But don't! It would be rather
expensive to send useless rocks around the world just for the fun of it. :-)
I have done it for work of course, and also when coming back from holidays I
tend to have a few rocks in my luggage, getting strange looks and frowns
from custom officers....

Thomas

Post a reply to this message

"Thomas de Groot" <t.d### [at] internlnet> wrote:

> I have done it for work of course, and also when coming back from holidays I
> tend to have a few rocks in my luggage, getting strange looks and frowns
> from custom officers....
>

I brought back a rock from Australia a few years ago. It was a birthday
present and it is striped brown and beige. Its name is Dinkum.

Yes it’s a fair Dinkum :-)

Stephen

Post a reply to this message

"Thomas de Groot" <t.d### [at] internlnet> wrote:
> "PM 2Ring" <nomail@nomail> schreef in bericht
> news:web.4458bb911843be331bd1c060@news.povray.org...
>
> > A collapse
> > happened (near the middle) in one of the ventillation tunnels late last
> > year, causing damage to an apartment block. Here's a link:
> > http://www.industrysearch.com.au/news/viewrecord.asp?id=19863
> >
> Interesting!! Thanks for the info. A familiar problem surfacing here...

I don't think they've solved the problem yet. They still have a huge machine
near the collapse point which looks like it's still taking vertical core
samples. People should be more careful when building tunnels. I guess it's
hard when you can't really see what you're doing...

> >
> > I've been tempted to grab some samples, before they get crushed and
> disposed of... I'd send you some, but the postage would kill me. :)
> >
> Thank you  indeed for your kind thought! But don't! It would be rather
> expensive to send useless rocks around the world just for the fun of it. :-)

:)

> I have done it for work of course, and also when coming back from holidays I
> tend to have a few rocks in my luggage, getting strange looks and frowns
> from custom officers....

That would be fun. Have they ever threatened to break them up to look for
contraband hidden inside? :)

Post a reply to this message

"Stephen" <mca### [at] hotmailcom> wrote:
> "Thomas de Groot" <t.d### [at] internlnet> wrote:
>
> > I have done it for work of course, and also when coming back from holidays I
> > tend to have a few rocks in my luggage, getting strange looks and frowns
> > from custom officers....
> >
>
> I brought back a rock from Australia a few years ago. It was a birthday
> present and it is striped brown and beige. Its name is Dinkum.
>
> Yes it’s a fair Dinkum :-)
>
> Stephen

Strewth, mate! :)

Post a reply to this message

"PM 2Ring" <nomail@nomail> schreef in bericht
news:web.445b08321843be331bd1c060@news.povray.org...
>
> I don't think they've solved the problem yet. They still have a huge
machine
> near the collapse point which looks like it's still taking vertical core
> samples. People should be more careful when building tunnels. I guess it's
> hard when you can't really see what you're doing...
>
I have the feeling that it was a combination of time and money that led to
the collapse....

> > I have done it for work of course, and also when coming back from
holidays I
> > tend to have a few rocks in my luggage, getting strange looks and frowns
> > from custom officers....
>
> That would be fun. Have they ever threatened to break them up to look for
> contraband hidden inside? :)
>
Well... it is always the question "what is allowed/not allowed for export".
Believe it or not, rocks can give problems, if they are sent in large
quantities (samples for study for instance) and you need special permits.
But for the tourist, there is little to worry about generally, except really
in the case of fossils...

Oh dear! I am afraid we are wandering off into the off topic area.....

Thomas

Post a reply to this message

"Thomas de Groot" <t.d### [at] internlnet> wrote:
> "PM 2Ring" <nomail@nomail> schreef in bericht
> news:web.445b08321843be331bd1c060@news.povray.org...
> I have the feeling that it was a combination of time and money that led to
> the collapse....

Agreed.

> Well... it is always the question "what is allowed/not allowed for export".
> Believe it or not, rocks can give problems, if they are sent in large
> quantities (samples for study for instance) and you need special permits.

I believe it. We're very fussy about quarantining here.

> But for the tourist, there is little to worry about generally, except really
> in the case of fossils...
>
> Oh dear! I am afraid we are wandering off into the off topic area.....

Yes. Let's get back to raytracing!

Here's a stereo pair I just did of the sandstone block pyramid I posted
earlier. It doesn't look good as a colour anaglyph, unfortunately.

Post a reply to this message

Attachments:
Download 'sandstoneeh0rls.jpg' (172 KB)

Preview of image 'sandstoneeh0rls.jpg'

"PM 2Ring" <nomail@nomail> schreef in bericht
news:web.445b87391843be331bd1c060@news.povray.org...
> Here's a stereo pair I just did of the sandstone block pyramid I posted
> earlier. It doesn't look good as a colour anaglyph, unfortunately.
>
>
Ah yes, that's nice!

I just thought too that your sandstone texture would be excellent for use
with fossils, like those from the lithographic limestone of Solenhofen in
Germany or those from Liaoning in China... Hmm. Shall think about that
possibility...

Thomas

Post a reply to this message