|
![](/i/fill.gif) |
see: "Wouldn't it be nice: patterns and finish items" in povray.general
source:
camera {
location <-2.5,2.5,-5>
look_at 0
angle 40
}
light_source {
<-4.9,4.9,4.9>
rgb 1
}
#default { pigment { rgb y } }
#local fin0 = finish {};
#local fin1 = finish { specular 1 };
#local fin2 = finish { reflection 1 };
#local fin3 = finish { ambient .75 };
#local fin12 = finish { specular 1 reflection 1 };
#local fin13 = finish { specular 1 ambient .75 };
#local fin23 = finish { reflection 1 ambient .75 };
#local fin123 = finish { specular 1 reflection 1 ambient .75 };
#local tex01 = texture { finish { fin0 } };
#local tex02 = texture { finish { fin1 } };
#local tex03 = texture { finish { fin2 } };
#local tex04 = texture { finish { fin3 } };
#local tex05 = texture { finish { fin12 } };
#local tex06 = texture { finish { fin13 } };
#local tex07 = texture { finish { fin23 } };
#local tex08 = texture { finish { fin123 } };
#local tex09 = texture {
wrinkles
texture_map {
[0.0 tex01]
[0.5 tex01]
[0.5 tex02]
[1.0 tex02]
}
frequency 3
}
#local tex10 = texture {
wrinkles
texture_map {
[0.0 tex03]
[0.5 tex03]
[0.5 tex04]
[1.0 tex04]
}
frequency 3
}
#local tex11 = texture {
wrinkles
texture_map {
[0.0 tex05]
[0.5 tex05]
[0.5 tex06]
[1.0 tex06]
}
frequency 3
}
#local tex12 = texture {
wrinkles
texture_map {
[0.0 tex07]
[0.5 tex07]
[0.5 tex08]
[1.0 tex08]
}
frequency 3
}
#local tex13 = texture {
granite
texture_map {
[0.0 tex09]
[0.5 tex09]
[0.5 tex10]
[1.0 tex10]
}
}
#local tex14 = texture {
granite
texture_map {
[0.0 tex11]
[0.5 tex11]
[0.5 tex12]
[1.0 tex12]
}
}
#local final_tex = texture {
bozo
texture_map {
[0.0 tex13]
[0.5 tex13]
[0.5 tex14]
[1.0 tex14]
}
frequency 10
}
box {
<-5,-1,-5>, <5,9,5>
inverse
pigment { checker rgb 0 rgb 1 }
}
sphere {
0, 1
texture { final_tex }
}
Post a reply to this message
Attachments:
Download 'test3.jpg' (50 KB)
Preview of image 'test3.jpg'
![test3.jpg](/povray.binaries.images/attachment/%3Cweb.4405840ab0a85c3ef37ab23e0%40news.povray.org%3E/test3.jpg?ttop=441697&toff=4550&preview=1)
|
![](/i/fill.gif) |