|
 |
Trying to impress the boss, I knocked this up...
It was the first time that I've ever used an "upright" plane. I really
liked the effect the normal created on the wall, gave a nice rough-rendered
feel.
Anyway heres the code if you want to impress yur boss (or help me impress
mine).
#include "colors.inc"
#include "textures.inc"
#include "functions.inc"
#include "shapes.inc"
#include "metals.inc"
#declare useRadiosity = 0; // 1 = use radiosity, 0 = use lights
#declare useMedia = 1; // 1 = use media, 0 dont use media
#declare smoothWall = 0; // 1 = wall smooth, 0 = wall rough
// radiosity (global illumination) settings
#if(useRadiosity=1)
global_settings {
radiosity {
pretrace_start 0.08 // start pretrace at this size
pretrace_end 0.04 // end pretrace at this size
count 35 // higher -> higher quality (1..1600) [35]
nearest_count 5 // higher -> higher quality (1..10) [5]
error_bound 1.8 // higher -> smoother, less accurate [1.8]
recursion_limit 3 // how much interreflections are
calculated (1..5+) [3]
low_error_factor .5 // reduce error_bound during last pretrace
step
gray_threshold 0.0 // increase for weakening colors (0..1)
[0]
minimum_reuse 0.015 // reuse of old radiosity samples [0.015]
brightness 100 // brightness of radiosity effects
(0..1) [1]
adc_bailout 0.01/2
normal on // take surface normals into account [off]
media on // take media into account [off]
always_sample on // turn sampling in final trace off [on]
max_sample 1.0 // maximum brightness of samples
}
}
#end
#if(useMedia=1)
box { <0,0,0>,
<1,1,1>
texture { pigment { Clear } }
hollow
scale 30
translate <-10,-10,-2>
interior {
media { // atmospheric media sample
intervals 1 //10
scattering { 1, rgb 0.01 } // 0.03
samples 1, 10
confidence 0.9999
variance 1/1000
ratio 0.9
}
}
}
#end
#declare theText = union {
text {
ttf "arial.ttf" "Technical" 0.1, 0
translate <-3.5,1.5,1>
}
text {
ttf "arial.ttf" "direct" 0.1, 0
scale <0.8,0.8,0.8>
translate <0.8,1.52,1>
}
texture {
pigment { Gold }
finish {
reflection { 0.1, 0.7 }
}
finish { ambient 0 }
}
}
camera {
//location <0,-1.5,-3>
//location <0,0,-17>
//good one
location <6,2,-8>
//location <4,2,-10>
//location <8,2,1.5>
//location <15,2,-2>
look_at <0,2,0>
}
background { Black }
#if(useRadiosity=0)
light_source { <60, 10, -50> color White*0.8 photons {reflection on
refraction on } }
light_source { <90, 56, -50> color rgb <0.2, 0.25, 0.3> shadowless }
#end
plane { <0,-1,0>,1
texture {
pigment {
Tan
}
#if(smoothWall=0)
normal { agate scale <0.2,10,0.1> }
#end
finish {
diffuse 0.3
ambient 0
}
}
hollow
rotate <90,0,0>
translate <0,0,3>
}
#declare Support = union {
cylinder {
<0,0,10>,
<0,0,1.39>,
0.15
texture { T_Brass_3C finish { ambient 0 }}
}
sphere {
<0,0,1.39>,0.1
texture { T_Brass_3C finish { ambient 0 }}
}
}
#declare theSign = union {
object {
theText
scale <1.5,1.5,1.5>
rotate <0,0,0>
translate <0.7,-1,0>
}
box {
<-5,1,-0.1>
<5,-1,.3>
texture {
pigment
{
Clear
}
finish {
reflection {0.1,0.12}
specular 0.5
ambient 0
diffuse 0.7
}
}
hollow
interior {
ior 1.3
}
translate <0,1.8,1.5>
}
object { Support translate <-4.7,2.55,0> }
object { Support translate <4.7,2.55,0> }
}
#declare aLight = union {
difference {
difference {
object {
Round_Box(<-1,-1,-1>, < 1, 1, 1>,
0.6, yes)
texture { T_Chrome_2A
finish {
ambient 0
reflection 0
}
}
scale <0.6,1.5,0.6>
translate <0,0,-2>
}
box {
<-1,-1,-1>,
<1,1,1>
texture {T_Chrome_2A
finish {
ambient 0
reflection 0
}
}
rotate <35,0,0>
translate <0,-2.2,-2.5>
}
}
cone {
<0,-1.1,0>,
1,
<0,0,0>,
0
texture {
T_Silver_5E
}
scale <0.6,1,0.6>
rotate <35,0,0>
translate <0,-0.5,-1.65>
}
}
cylinder {
<0,0,0>,
<0,0,4>,
0.2
translate <0,1,-6>
texture {T_Chrome_2A
finish {
ambient 0
}
}
}
//
//
//
#if(useRadiosity=1)
sphere {
<0,0,0>, 0.08
texture {
pigment { White }
finish {
ambient 1
}
}
translate <0,-0.9,-2>
}
#else
light_source { <0,0,0> colour White translate <0,-0.9,-2> photons
{ reflection on refraction on } }
#end
}
#declare theLightFitting = union {
object {
aLight
rotate <0,180,0>
translate <-3,5,-3>
}
object {
aLight
rotate <0,180,0>
translate <3,5,-3>
}
box {
<1,1,1>,
<-1,-1,-1>
scale <5,0.7,0.5>
translate <0,6,2>
texture {T_Chrome_2A
finish {
ambient 0
}
}
}
}
object { theLightFitting }
object { theSign }
Post a reply to this message
Attachments:
Download 'TDLogo2.jpg' (219 KB)
Preview of image 'TDLogo2.jpg'
|
|
com> wrote in message
news: