Hi folks!
My first focal blur test..without reading the docs.. I just found the insert
menu! well maybe not, but it sure is useful :)
Questions:
How do I smooth the blur more? Tried to increase blur_samples to 30 but it
didn't help at all..
The focal point goes alle the way on the x-axis, how do I "center" the
focus, cylindral camera?

10x10 Area light (one of my first tests with area lights too, lovely stuff!
:)
Radiosity (taken straight from the insert menu)

1h 20m @ PII 450mhz 256ram win2k POV Beta 16


--
_.-=^=-._.-=[ Peter ]=-._.-=^=-._
   _.-=[ http://hertel.no/peter]=-._

// SCENE
#default {finish {reflection 0.5}}

camera {
  location <3,10,-3> look_at <1,1,3>
  right     x*image_width/image_height
  aperture 3
  blur_samples 20
  focal_point <1,1,1>
  confidence 0.95
  variance 1/500
}

// standard radiosity from insert menu (only count increased)
global_settings {
  radiosity {
    pretrace_start 0.08
    pretrace_end   0.04
    count 400
    nearest_count 5
    error_bound 1.8
    recursion_limit 3
    low_error_factor .5
    gray_threshold 0.0
    minimum_reuse 0.015
    brightness 1
    adc_bailout 0.01/2
    }
}

light_source {<6,6,-10> rgb 1
area_light
<4, 0, 0> <0, 0, 4>
10,10
circular
orient
}

sphere {<0,1,0>,1 pigment {rgb <1,0,0>}}
box {<-2,0,2>,<4,2,1.9> pigment {rgb 1}}
cylinder {<2,0,3.5>,<2,4,3.5>,1 pigment {rgb <1,1,0>}}
box {<-100,-1,-100>,<100,0,100> pigment {checker rgb 1 rgb 0.5}}

Post a reply to this message

Attachments:
Download 'P_blur01_area_rad.jpg' (68 KB)

Preview of image 'P_blur01_area_rad.jpg'

I like your image Peter, it has vibes of Venus and Mars, (I'm thinking
about the Wings album cover).  

-- 
sphere{z*5,1pigment{rgb.5}finish{reflection.3specular.5}}box{<-50,-3,-50>
<50,-2,50>pigment{checker/*\__\\__/  * \_\\__*/scale 2}finish{ambient.7}}
light_source/*__\\__\\__\\__\\__\(    ~ )\__\\__\\__\\__\\*/{<2,5,1>*4,1} 
/*\\__\\__\\__\\__\\__\\__\\__\\__\~  -/__\\__\\__\\__\\__\\*//* Steve */

Post a reply to this message

I like the picture. But what about getting rid of that grainy look at the
upper edge of the yellow pole? I know it's a focal blur issue. Will
increasing the amount of samples deal with the problem?

--
Apache
http://geitenkaas.dns2go.com/experiments/
apa### [at] yahoocom

Post a reply to this message

Hey, don't just look at the pictures, read the text as well :-)
He was just asking questions about that!
Marc


3cb7912e@news.povray.org...
> I like the picture. But what about getting rid of that grainy look at the
> upper edge of the yellow pole? I know it's a focal blur issue. Will
> increasing the amount of samples deal with the problem?
>
> --
> Apache
> http://geitenkaas.dns2go.com/experiments/
> apa### [at] yahoocom
>
>

Post a reply to this message

I should get some sleep. I'm to greedy. I want to see pretty pictures!!!

--
Apache
http://geitenkaas.dns2go.com/experiments/
apa### [at] yahoocom

Post a reply to this message

lol good night, pretty pictures are what POV is aimed to ;-)
Marc

3cb7d102$1@news.povray.org...
> I should get some sleep. I'm to greedy. I want to see pretty pictures!!!
>
> --
> Apache
> http://geitenkaas.dns2go.com/experiments/
> apa### [at] yahoocom
>
>

Post a reply to this message

On Sat, 13 Apr 2002 01:44:13 +0200, "Peter Hertel"
<peter@hertel**NOSPAM**.no> wrote:

>How do I smooth the blur more? Tried to increase blur_samples to 30 but it
>didn't help at all..

Decrease variance and increase confidence.

The number of samples you supply is the *maximum* number POV-Ray will
shoot. However, to speed things up, it employs some statistics.
Confidence shows how 'confident' POV-Ray should be that the result is
smooth before it stops shooting rays, and is a value from 0 to 1
representing 0% to 100%. Variance shows how little the next samples
should be expected to contribute to the smoothness before POV-Ray
stops shooting rays, and is a positive value, the lower, the better.

Try this out, slowly increasing the amount of Focal_Blur_Accuracy
until you get a satisfying result. Use the macro instead of specifying
confidence and variance, as in:

#macro Focal_Blur_Accuracy (FB_Accuracy)
  confidence 1-pow(10,-FB_Accuracy)
  variance pow(10,-FB_Accuracy-2)
#end

camera {
  [something]
  Focal_Blur_Accuracy(1)
}

See if it helps any. Also, try Francois' Automatic DOF macro on
www.wozzeck.net .

Good luck.


Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] vipbg
TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message

> I want to see pretty pictures!!!
what do you say?!! that my picture aren't pretty?!! :)
just kidding, I'll post the better blurred version when I get the time to
render the full pic..

--
_.-=^=-._.-=[ Peter ]=-._.-=^=-._

Post a reply to this message

> Try this out, slowly increasing the amount of Focal_Blur_Accuracy
> until you get a satisfying result. Use the macro instead of specifying
> confidence and variance, as in:

Thanks a lot!
I don't have the time to fiddle with it right now..so I just did:
blur_samples 100
Focal_Blur_Accuracy(9)
:)
Attatched two details of the new blur, I'll render the full picture next
week..
Have a nice weekend!

_.-=^=-._.-=[ Peter ]=-._.-=^=-._

Post a reply to this message

Attachments:
Download 'P_blur02_detail.jpg' (6 KB) Download 'P_blur02_detail2.jpg' (4 KB)

Preview of image 'P_blur02_detail.jpg'

Preview of image 'P_blur02_detail2.jpg'

> I like your image Peter
thanks :) just have to sort out that focal blur stuff..
> it has vibes of Venus and Mars, (I'm thinking
> about the Wings album cover).
sorry..didn't catch that one..?

_.-=^=-._.-=[ Peter ]=-._.-=^=-._

Post a reply to this message