 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
A closer look, with the "open" option.
36hours (SIGH!) on Pentium200, 96MB RAM
Post a reply to this message
Attachments:
Download 'iso01.JPG' (55 KB)
Preview of image 'iso01.JPG'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Galy" <gal### [at] inwind it> wrote in message news:3c016b09@news.povray.org...
> A closer look, with the "open" option.
> 36hours (SIGH!) on Pentium200, 96MB RAM
What kind of function is this anyway? Looks interesting...
Frits van Bommel
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Galy <gal### [at] inwindit> wrote:
: 36hours
Could you post the source so that we could see if that render time could
be drastically reduced (with no change in the image, of course)?
--
#macro N(D,I)#if(I<6)cylinder{M()#local D[I]=div(D[I],104);M().5,2pigment{
rgb M()}}N(D,(D[I]>99?I:I+1))#end#end#macro M()<mod(D[I],13)-6,mod(div(D[I
],13),8)-3,10>#end blob{N(array[6]{11117333955,
7382340,3358,3900569407,970,4254934330},0)}// - Warp -
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Sun, 25 Nov 2001 23:04:49 +0100, Galy wrote:
>A closer look, with the "open" option.
>36hours (SIGH!) on Pentium200, 96MB RAM
Now fill those cones with emitting media and you've got
some beautiful fireworks, but you'll need to make it night
time aswell:-)
Nice work.
--
Cheers
Steve email mailto:ste### [at] zeroppsuklinuxnet
%HAV-A-NICEDAY Error not enough coffee 0 pps.
web http://www.zeropps.uklinux.net/
or http://start.at/zero-pps
3:45am up 48 days, 19:29, 1 user, load average: 1.00, 1.00, 1.00
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
background { color rgb <0.5, 0.7, 1> }
camera {
location <0.0, 2.0, -20.0>
look_at <0.0, 0.0, 1.0>
right x*image_width/image_height
}
// create a regular point light source
light_source {
0*x // light's position (translated below)
color rgb <1,1,1> // light's color
translate <0, 10, -20>
}
// create a isosurface object - the equipotential surface
// of a 3D math function f(x, y, z)
#declare fn_X = function(x,y,z,tau) {
8*(x^2-tau^4*y^2)*(y^2-tau^4*z^2)*(z^2-tau^4*x^2)*(x^4+y^4+z^4-2*(x^2*y^2+y^
2*z^2+z^2*x^2))+(3+5*tau)*(x^2+y^2+z^2-1)^2*(x^2+y^2+z^2-(2-tau))^2 }
isosurface {
function { fn_X(x, y, z,(1+sqrt(5))/2) } // alternative declared
function
contained_by { sphere { 0, 3 } } // container shape
accuracy 0.001 // accuracy of calculation [0.001]
max_gradient 3445031.481 // maximum gradient the
function can have [1.1]
// evaluate 1, 1.2, 0.99 // evaluate the maximum gradient
open
material {
texture {
pigment { color rgb <0.2, 0.7, 0.2> }
finish {
ambient 0.3 // ambient surface reflection color [0.1]
diffuse 0.6 // amount [0.6]
phong 0.5 // amount [0.0]
phong_size 40 // (1.0..250+) (dull->highly polished) [40]
reflection {
//0.0 // minimal reflection value (for variable
reflection)
1.0 // reflection amount (maximum for variable
reflection)
fresnel on // realistic variable reflection
falloff 1.0 // falloff exponent for variable reflection
exponent 1.0 // influence surface reflection
characteristic
metallic 1.0 // tint reflection in surface color
}
}
}
}
rotate y*30
scale 3
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Here's the code.
If i fill the cones with emitting media (and i doubt i could do such a
thing), i will render 'til next year. :o)
Obviously i find the function on a manual. :o)
Post a reply to this message
Attachments:
Download 'prova_suse6_4.pov.txt' (2 KB)
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Galy schrieb in Nachricht <3c0289bb@news.povray.org>...
> max_gradient 3445031.481 // maximum gradient the
OMG! Are you sure you need a that high max_gradient? Even if evaluate
reported this for you - did you try to cut it down by half or something?
Will save you lots of rendertime and most of the time will make no
difference. Only if you get holes in your Iso, you should be worried about
your max_gradient.
Marc-Hendrik
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Mon, 26 Nov 2001 19:38:27 +0100, Galy wrote:
>Here's the code.
>If i fill the cones with emitting media (and i doubt i could do such a
>thing), i will render 'til next year. :o)
>Obviously i find the function on a manual. :o)
Thanks for posting the code, I'll have a look at it.
--
Cheers
Steve email mailto:ste### [at] zeroppsuklinuxnet
%HAV-A-NICEDAY Error not enough coffee 0 pps.
web http://www.zeropps.uklinux.net/
or http://start.at/zero-pps
10:03pm up 49 days, 13:47, 1 user, load average: 1.00, 1.00, 1.00
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ehm, in fact i used the max_gradient reported by "evaluate".
Maybe you're right, I'll do a test with a much smaller one.
Tnx
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Try the below code. The rendering speed is about 5 times
faster than that of the original on my PC.
The gradient values near the origin is extremely smaller
than those near the container surface.
In such cases, it is better to calculate them separately.
The below code is not well optimized. Combination with other
techniques might increase the speed further.
c.f. http://news.povray.org/3bc417a4@news.povray.org
http://news.povray.org/3bd7f6e8$1@news.povray.org
R. Suzuki
-------------------------------------------------------------
#include "functions.inc"
background { color rgb <0.5, 0.7, 1> }
camera {
location <0.0, 2.0, -20.0>
look_at <0.0, 0.0, 1.0>
right x*image_width/image_height
}
light_source {
0*x
color rgb <1,1,1>
translate <0, 10, -20>
}
// create a isosurface object - the equipotential surface
// of a 3D math function f(x, y, z)
#declare fn_X = function(x,y,z,tau) {
8*(x^2-tau^4*y^2)*(y^2-tau^4*z^2)*(z^2-tau^4*x^2)
*(x^4+y^4+z^4-2*(x^2*y^2+y^2*z^2+z^2*x^2))
+(3+5*tau)*(x^2+y^2+z^2-1)^2*(x^2+y^2+z^2-(2-tau))^2 }
#macro ISO1(R1, R2, max_g, Open_flg)
isosurface {
function {fn_X(x,y,z,(1+sqrt(5))/2) & -f_sphere(x,y,z,R1)*max_g}
contained_by { sphere { 0, R2 } }
accuracy 0.001
max_gradient max_g
//evaluate 100, 1.20, 0.99
#if (Open_flg)
open
#end
}
#end
object{
union{
difference{
ISO1(2.49, 3.0, 3445031.481, on)
sphere{ 0, 2.5 }
}
ISO1(1.9, 2.5, 330000., on)
ISO1(1.4, 1.9, 13000., off)
ISO1(1.0, 1.4, 1500., off)
ISO1(0.72, 1.0, 70., off)
ISO1(0.6, 0.72, 5., off)
}
material {
texture {
pigment { color rgb <0.2, 0.7, 0.2> }
finish {
ambient 0.3 // ambient surface reflection color [0.1]
diffuse 0.6 // amount [0.6]
phong 0.5 // amount [0.0]
phong_size 40 // (1.0..250+) (dull->highly polished) [40]
reflection {
//0.0
1.0
fresnel on
falloff 1.0
exponent 1.0
metallic 1.0
}
}
}
}
rotate y*30
scale 3
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
