These spheres look great on a black background, but when I put them on a
grey one, they look horrible.  Why is this?

material {
  texture {
    pigment {
      agate
      color_map {
        [0 rgbt <.1, .1, 1, .8>]
        [1 rgbt 1]
      }
      agate_turb .4
    }
    finish {
      phong .3
      phong_size 80
      ambient 0.1
      diffuse 0.1
      reflection .25
      specular 1
      roughness 0.001
    }
  }
  interior {
    ior 1.3
    media {
      emission rgb <.05, .05, .5>
      density {
        radial
        color_map {
          [0 rgbt <0, 0, 0, 0>]
          [1 rgbt 1]
        }
        frequency 5
        turbulence .6
      }
    }
  }
}

Post a reply to this message

Attachments:
Download 'spheres.jpg' (32 KB) Download 'spheres2.jpg' (21 KB)

Preview of image 'spheres.jpg'

Preview of image 'spheres2.jpg'

Ben Lauritzen wrote:
> 
> These spheres look great on a black background, but when I put them on a
> grey one, they look horrible.  Why is this?
> 

I'd say there are mainly 2 reasons:
1) You are using a reflective finish, so the reflection of the brighter
surroundings basically decreases the contrast of the spheres; see if using
reflection_exponent will alleviate this problem.
2) You are using only emitting media; the colour of emitting media is added to
any colour seen through it. On a light background this will give a washed-out
look, because the combined colour gets too bright (saturated with white). Try
adding absorbing properties to the media - bear in mind that the hue of the
absorbing media should generally be the inverse of the emission colour.
Something like this:
media{
  emission <1,0,0>
  absorption <0,.5,.5>
  density{...}
}

-- 
Margus Ramst

Personal e-mail: mar### [at] peakeduee
TAG (Team Assistance Group) e-mail: mar### [at] tagpovrayorg
Home page http://www.hot.ee/margusrt

Post a reply to this message