 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
This two pictures are the last of the patterns in my tiling patch.
Yep... It's a code patch, not a script.
Available soon on http://pov.grimbert.cjb.net/
I'm not happy at all with the naming used, but I have no time
to find good names... I'm still hooked on the 2D paving of the plane,
specially with n connected square/hexagon/triangle pieces.
The good news is that, at least for that kind of paving, I have found
a naming scheme.
In the meantime, maybe someone will find a macro/script to provide the
same kind of paving, but I doubt it...
Post a reply to this message
Attachments:
Download 'carrelage14.jpg' (32 KB)
Download 'carrelage15.jpg' (25 KB)
Preview of image 'carrelage14.jpg'
Preview of image 'carrelage15.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Alas no 3.4.3.3.4, nor its dual the `Cairo' tessellation.
--
Anton Sherwood -- br0### [at] p0b0x com -- http://ogre.nu/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Anton Sherwood wrote:
>
> Alas no 3.4.3.3.4, nor its dual the `Cairo' tessellation.
>
the 3.4.3.3.4 is still on the design table, I just need more time...
as well as the two 6.3.3.3.3 versions, and 12.6.4 and 12.12.3
The "cairo"* is also part of the new patterns I have found, thanks to
Vahur Krouverk and a little web surfing. I did not realise it was the dual
of the 3.4.3.3.4 . I wonder if any of the other archimedians have duals, and
what they would look like... Thanks :-> I already had so little time, now I
have a new branch to explore !
Post a reply to this message
|
|
| |
| |
|
|
From: Wlodzimierz ABX Skiba
Subject: Re: Strata (Tiling) [25 + 32 Kbu, jpg]
Date: 14 May 2001 13:59:34
Message: <3b001d06@news.povray.org>
|
|
|
| |
| |
|
|
Jérôme Grimbert wrote in message <3AFD2235.18DEAD6A@free.fr>...
> This two pictures are the last of the patterns in my tiling patch.
> Yep... It's a code patch, not a script.
> In the meantime, maybe someone will find a macro/script to provide the
> same kind of paving, but I doubt it...
are you talking about universal macro generating pigment form count of
segment/vertex/figures or script for selected patterns ?
here is my result for your first pigment
script is not optimized, I want to show way of finding
of course MegaPOV required
--
#macro Sig(A,B,X)_(A,B)_(B,X)_(X,A)#end#macro _(A,B)cylinder{<A.x,A.y,3>,<B.u,
B.v,3>.1,9}#end global_settings{max_trace_level 9}light_source{0 1}camera{up y
*4right-3*x}blob{_(<3,1>,<1,-5>)_(<2,-2>,<4,-2>)Sig(x,<-1,1.5>,<1,3>)_(z-1,z-4
)pigment{rgb 1}}box{-3 3pigment{rgb 0}finish{reflection 1}hollow} // POV-Ray31
Post a reply to this message
Attachments:
Download 'strata.jpg' (39 KB)
Download 'strata.pov.txt' (3 KB)
Preview of image 'strata.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Mon, 14 May 2001 19:58:36 +0200, Wlodzimierz ABX Skiba wrote:
>Jérôme Grimbert wrote in message <3AFD2235.18DEAD6A@free.fr>...
>> This two pictures are the last of the patterns in my tiling patch.
>> Yep... It's a code patch, not a script.
>> In the meantime, maybe someone will find a macro/script to provide the
>> same kind of paving, but I doubt it...
>
>are you talking about universal macro generating pigment form count of
>segment/vertex/figures or script for selected patterns ?
>here is my result for your first pigment
>script is not optimized, I want to show way of finding
>of course MegaPOV required
Why "of course"? Here are a few that work in plain ol' POV. I started
to do 6.4.3 but never finished it.
#macro _6_6_6()
#local G=pigment {gradient x color_map {[0 rgb 1][1 rgb 0]} scale 1.000001}
#local B=pigment{
radial
pigment_map{
#local i=0;
#while(i<6)
[i/6 G rotate(30+60*i)*y]
[(i+1)/6 G rotate(30+60*i)*y]
#local i=i+1;
#end
}
}
#local T2=sqrt(3)/2;
radial
pigment_map{
[1/3 B translate<.5,0,-T2>]
[1/3 B translate<-1,0,0>]
[2/3 B translate<-1,0,0>]
[2/3 B translate<.5,0,T2>]
}
translate x
warp{repeat 1.5*x flip x}
warp{repeat .5*sqrt(3)*z flip z}
#end
#macro _8_8_4()
#local G=pigment {gradient x color_map {[0 rgb 1][1 rgb 0]} scale .5000001}
#local H=pigment {
gradient x
pigment_map {
[.5 G][.5 G translate -.5*x scale <1-sqrt(2),1,1> translate .5*x]
}
}
radial
pigment_map{
#local i=0;
#local j=8;
#while(i<j)
[i/j H rotate(180/j+360/j*i)*y]
[(i+1)/j H rotate(180/j+360/j*i)*y]
#local i=i+1;
#end
}
rotate 180/j*y
warp{repeat .5*x flip x}
warp{repeat .5*z flip z}
#end
#macro _12_4_6( )
#local G=pigment {gradient x color_map {[0 rgb 1][1 rgb 0]} scale .5000001}
#local T15=tan(pi/12);
#local Hx=pigment {
radial
pigment_map{
#local i=0;
#while(i<6)
[i/6 G scale <T15*sqrt(3),1,1> rotate(30+60*i)*y]
[(i+1)/6 G scale <T15*sqrt(3),1,1> rotate(30+60*i)*y]
#local i=i+1;
#end
}
rotate 30*y
}
#local H=pigment{
gradient x
pigment_map {[.5 G][.5 Hx translate (.5+T15*sqrt(3)/2)*x]}
}
#local J=pigment{
gradient x
pigment_map {[T15/2 G scale <T15,1,1>]
[T15/2 Hx translate (T15*(1+sqrt(3)))/2*x]}
}
#local Sq=pigment {
radial
pigment_map{
#local i=0;
#while(i<4)
[i/4 J rotate(45+90*i)*y]
[(i+1)/4 J rotate(45+90*i)*y]
#local i=i+1;
#end
}
rotate 45*y
}
#local I=pigment{
gradient x
pigment_map {[.5 G][.5 Sq translate (.5+.5*T15)*x]}
}
#local B=pigment{
radial
pigment_map{
#local i=0;
#while(i<12)
[i/12 #if (i/2 = int(i/2)) I #else H #end rotate(15+30*i)*y]
[(i+1)/12 #if (i/2 = int(i/2)) I #else H #end rotate(15+30*i)*y]
#local i=i+1;
#end
}
rotate 15*y
}
#local T2=sqrt(3)/2;
radial
pigment_map{
[1/3 B translate<.5,0,-T2>*(.5+T15*sqrt(3)/2)]
[1/3 B translate<-1,0,0>*(.5+T15*sqrt(3)/2)]
[2/3 B translate<-1,0,0>*(.5+T15*sqrt(3)/2)]
[2/3 B translate<.5,0,T2>*(.5+T15*sqrt(3)/2)]
}
translate (.5+T15*sqrt(3)/2)*x
warp{repeat 1.5*x*(.5+T15*sqrt(3)/2) flip x}
warp{repeat .5*sqrt(3)*z*(.5+T15*sqrt(3)/2) flip z}
#end
#macro _12_12_3( )
#local G=pigment {gradient x color_map {[0 rgb 1][1 rgb 0]} scale 1.00001}
#local P=tan(15*pi/180)/sqrt(3);
#local H=pigment {gradient x
pigment_map {[.5/(1+P) G scale <.5/(1+P),1,1>]
[.5/(1+P) G scale <.5/(1+P),1,1> translate -.5/(1+P)*x
scale <-P,1,1> translate .5/(1+P)*x]}
scale <2,1,1>
}
#local B=pigment{
radial
pigment_map{
#local i=0;
#local j=12;
#while(i<j)
[i/j H rotate(180/j+360/j*i)*y]
[(i+1)/j H rotate(180/j+360/j*i)*y]
#local i=i+1;
#end
}
rotate 180/j*y
}
#local T2=sqrt(3)/2;
radial
pigment_map{
[1/3 B translate<.5,0,-T2>]
[1/3 B translate<-1,0,0>]
[2/3 B translate<-1,0,0>]
[2/3 B translate<.5,0,T2>]
}
translate x
warp{repeat 1.5*x flip x}
warp{repeat .5*sqrt(3)*z flip z}
#end
//plane {y 0 pigment {_6_6_6()} finish {ambient 1}}
//plane {y 0 pigment {_8_8_4()} finish {ambient 1}}
//plane {y 0 pigment {_12_12_3()} finish {ambient 1}}
plane {y 0 pigment {_12_4_6()} finish {ambient 1}}
camera {location 3*y sky z look_at 0}
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 14 May 2001 14:32:42 -0400, Ron Parker wrote:
>Why "of course"? Here are a few that work in plain ol' POV. I started
>to do 6.4.3 but never finished it.
And here's that code:
#macro _6_4_3( )
#local G=pigment {gradient x color_map {[0 rgb 1][1 rgb 0]} scale .500001}
#local G1=pigment {gradient x color_map {[0 rgb 1][1 red 0]} scale .500001}
#local SquG=pigment {gradient x pigment_map {
[.5/sqrt(3) G scale 1/sqrt(3)]
[.5/sqrt(3) G scale 1/3 translate (.5/3+.5/sqrt(3))*x]}}
#local Sq = pigment {
radial
pigment_map {
#local i=0;
#while(i<4)
[i/4 SquG rotate(45+90*i)*y]
[(i+1)/4 SquG rotate(45+90*i)*y]
#local i=i+1;
#end
}
rotate 45*y
}
#local HexG=pigment {gradient x pigment_map {
[.5 G1][.5 Sq translate (.5/sqrt(3)+.5)*x]}}
#local Hex = pigment {
radial
pigment_map {
#local i=0;
#while(i<6)
[i/6 HexG rotate(30+60*i)*y]
[(i+1)/6 HexG rotate(30+60*i)*y]
#local i=i+1;
#end
}
}
radial
pigment_map{
[1/3 Hex translate<.5,0,-sqrt(3)/2>*(.5+.25*sqrt(3))]
[1/3 Hex translate<-1,0,0>*(.5+.25*sqrt(3))]
[2/3 Hex translate<-1,0,0>*(.5+.25*sqrt(3))]
[2/3 Hex translate<.5,0,sqrt(3)/2>*(.5+.25*sqrt(3))]
}
translate (.5+.25*sqrt(3))*x
warp{repeat 1.5*x*(.5+.25*sqrt(3)) flip x}
warp{repeat .5*sqrt(3)*z*(.5+.25*sqrt(3)) flip z}
#end
plane {y 0 pigment {_6_4_3()}finish {ambient 1}}
camera {location 5*y sky z look_at 0}
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 14 May 2001 17:45:56 -0400, Ron Parker wrote:
Oops, looks like I left some debugging stuff in.
> #local G1=pigment {gradient x color_map {[0 rgb 1][1 red 0]} scale .500001}
Delete this line.
> #local HexG=pigment {gradient x pigment_map {
> [.5 G1][.5 Sq translate (.5/sqrt(3)+.5)*x]}}
This G1 should be G.
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
From: Wlodzimierz ABX Skiba
Subject: Re: Strata (Tiling) [25 + 32 Kbu, jpg]
Date: 15 May 2001 04:08:21
Message: <3b00e3f5@news.povray.org>
|
|
|
| |
| |
|
|
Ron Parker wrote in message ...
>On Mon, 14 May 2001 19:58:36 +0200, Wlodzimierz ABX Skiba wrote:
> > of course MegaPOV required
>
> Why "of course"?
"of course" because of keyword function{} and becouse "version unofficial
megapov .6;"
I was sure that it is possible
> Here are a few that work in plain ol' POV.
and it is great
--
#macro Sig(A,B,X)_(A,B)_(B,X)_(X,A)#end#macro _(A,B)cylinder{<A.x,A.y,3>,<B.u,
B.v,3>.1,9}#end global_settings{max_trace_level 9}light_source{0 1}camera{up y
*4right-3*x}blob{_(<3,1>,<1,-5>)_(<2,-2>,<4,-2>)Sig(x,<-1,1.5>,<1,3>)_(z-1,z-4
)pigment{rgb 1}}box{-3 3pigment{rgb 0}finish{reflection 1}hollow} // POV-Ray31
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Tue, 15 May 2001 10:07:13 +0200, Wlodzimierz ABX Skiba wrote:
>> Here are a few that work in plain ol' POV.
>
>and it is great
Actually, there are bugs in some of them, particularly the 6.4.3.4
implementation (starting with its name, but the tiling is a little off
too.) Also, I've rewritten them to work with nongradient pigments as
arguments and completed the set (well, almost completed the set... I
still lack the two versions of 6.3.3.3.3)
If anyone finds this even vaguely interesting, I'd be happy to post the
whole set to a scene-files newsgroup.
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 16 May 2001 12:41:55 -0400, Ron Parker wrote:
>On Tue, 15 May 2001 10:07:13 +0200, Wlodzimierz ABX Skiba wrote:
>>> Here are a few that work in plain ol' POV.
>>
>>and it is great
>
>Actually, there are bugs in some of them, particularly the 6.4.3.4
>implementation (starting with its name, but the tiling is a little off
>too.) Also, I've rewritten them to work with nongradient pigments as
>arguments and completed the set (well, almost completed the set... I
>still lack the two versions of 6.3.3.3.3)
>
>If anyone finds this even vaguely interesting, I'd be happy to post the
>whole set to a scene-files newsgroup.
One last update... I now have both versions of 6.3.3.3.3 as well.
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
In article <slr### [at] fwicom>, Ron Parker says...
> On Tue, 15 May 2001 10:07:13 +0200, Wlodzimierz ABX Skiba wrote:
> >> Here are a few that work in plain ol' POV.
> >
> >and it is great
>
> Actually, there are bugs in some of them, particularly the 6.4.3.4
> implementation (starting with its name, but the tiling is a little off
> too.) Also, I've rewritten them to work with nongradient pigments as
> arguments and completed the set (well, almost completed the set... I
> still lack the two versions of 6.3.3.3.3)
>
> If anyone finds this even vaguely interesting, I'd be happy to post the
> whole set to a scene-files newsgroup.
>
>
yes, please! povray.text.scene-files, if possible :)
--
Regards, Sander
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Wed, 16 May 2001 23:29:15 +0200, Sander wrote:
>yes, please! povray.text.scene-files, if possible :)
Done.
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
In article <slr### [at] fwicom>, Ron Parker says...
> On Wed, 16 May 2001 23:29:15 +0200, Sander wrote:
> >yes, please! povray.text.scene-files, if possible :)
>
> Done.
>
Thanks! Great! Now I have work for the whole summer :)
--
Regards, Sander
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
>
> [Image]
I'm propably pinpointing (as usual), but the joint on the hexagon seems to be
far to big
when compared to the triangle/square
Post a reply to this message
|
|
| |
| |
|
|
From: Wlodzimierz ABX Skiba
Subject: Re: Strata (Tiling) [25 + 32 Kbu, jpg]
Date: 17 May 2001 05:22:23
Message: <3b03984f@news.povray.org>
|
|
|
| |
| |
|
|
Jérôme Grimbert wrote in message <3B039159.D2B51A7A@atosorigin.com>...
> I'm propably pinpointing (as usual), but the joint on the hexagon seems to be
> far to big
> when compared to the triangle/square
I noticed this but this is easy to do mortar just like in your examples.
I just used linear gradient along various distances.
--
#macro Sig(A,B,X)_(A,B)_(B,X)_(X,A)#end#macro _(A,B)cylinder{<A.x,A.y,3>,<B.u,
B.v,3>.1,9}#end global_settings{max_trace_level 9}light_source{0 1}camera{up y
*4right-3*x}blob{_(<3,1>,<1,-5>)_(<2,-2>,<4,-2>)Sig(x,<-1,1.5>,<1,3>)_(z-1,z-4
)pigment{rgb 1}}box{-3 3pigment{rgb 0}finish{reflection 1}hollow} // POV-Ray31
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
You know about the 17 "wallpaper" symmetry groups?
Jérôme Grimbert wrote:
> . . . I wonder if any of the other archimedians have duals, and
> what they would look like... Thanks :-> I already had so little
> time, now I have a new branch to explore !
Every tiling has a dual.
The dual of a semiregular tiling is a Voronoi map, and thus can be
implemented as a variant of crackle, with the nuclei on a lattice.
Yet another crackle extension that I want to try. (see also
http://ogre.nu/tumble/) Is there a faq somewhere for patchers-wannabe?
--
Anton Sherwood -- br0### [at] p0b0xcom -- http://ogre.nu/
Post a reply to this message
|
|
| |
| |
|
|
From: Christoph Hormann
Subject: Re: Strata (Tiling) [25 + 32 Kbu, jpg]
Date: 17 May 2001 12:43:11
Message: <3B03FFC5.141F33B0@gmx.de>
|
|
|
| |
| |
|
|
Anton Sherwood wrote:
>
> [...]
> Is there a faq somewhere for patchers-wannabe?
I think Chris Huff once wrote something about that, but i don't recall in
detail. Best way is probably choosing one of the previously made patches
in megapov and look for all of the changes. For a new pattern, for
example look for all occurences of 'PigmentPatternPatch' in the source
files and you will get a quick insight what things are required.
For an extension of the crackle pattern, 'CracklePatch' might be
especially interesting.
Christoph
--
Christoph Hormann <chr### [at] gmxde>
IsoWood include, radiosity tutorial, TransSkin and other
things on: http://www.schunter.etc.tu-bs.de/~chris/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Thu, 17 May 2001 09:25:32 -0700, Anton Sherwood wrote:
>You know about the 17 "wallpaper" symmetry groups?
>
>Jérôme Grimbert wrote:
>> . . . I wonder if any of the other archimedians have duals, and
>> what they would look like... Thanks :-> I already had so little
>> time, now I have a new branch to explore !
>
>Every tiling has a dual.
>The dual of a semiregular tiling is a Voronoi map, and thus can be
>implemented as a variant of crackle, with the nuclei on a lattice.
>
>Yet another crackle extension that I want to try. (see also
>http://ogre.nu/tumble/) Is there a faq somewhere for patchers-wannabe?
No, but if you have any specific questions or want to know where to start
with crackle, the folk in povray.programming would be more than happy to
help out.
I'm probably the local expert on the current crackle implementation, since
I wrote the MegaPOV mods. Nathan's done some work on them, too, so I'm sure
he could help as well. All ya gotta do is modify that, the parser, and
the list of tokens, and one of your parents has a brother named Robert. If
you need any help with any of those three things, feel free to ask in an
appropriate forum and I'll answer to the best of my ability..
I'm investigating the possibility of adding the two things you already
mentioned, or at the very least the metric infinite thing, myself, although
probably not to MegaPOV. Stay tuned.
Adding an option for duals of archimedean tilings would somewhat stretch
the existing crackle code, though (not to mention that it'd be only 2d.)
It'd be better as a separate pattern. Some of the duals are boring, too:
6.6.6 is the dual of 3.3.3.3.3.3, and 4.4.4.4 is its own dual. The rest
are tilings of irregular (but symmetric) triangles (the duals of 8.8.4,
12.4.6, and 12.12.3) quadrilaterals (the dual of 6.4.3.4) and pentagons
(the duals of 4.4.3.3.3, 4.3.4.3.3, and the two 6.3.3.3.3's.)
To see the dual of a specific tiling, use my tiling macros in p.t.s-f and
replace the definition of G with
#local G=pigment {gradient z color_map {[.1 rgb 0][.1 rgb 1]}}
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 17 May 2001 12:49:01 -0400, Ron Parker wrote:
>To see the dual of a specific tiling, use my tiling macros in p.t.s-f and
>replace the definition of G with
>
>#local G=pigment {gradient z color_map {[.1 rgb 0][.1 rgb 1]}}
#local G=pigment {gradient z color_map {[.05 rgb 0][.05 rgb 1]} scale 2}
works better, because 3.3.3.3.3.3 needs more white to the edges. Doing this
pointed out a possible bug in my 6.3.3.3.3 implementation, too, so maybe I'll
be fixing that soon.
--
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbf 1}hollow interior{media{emission 3-T}}}#end
Z(-x-x.2x)camera{location z*-10rotate x*90normal{bumps.02scale.05}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
