|
 |
I started a scene for a new radiosity test and I had this strange
result...Where is the problem ? in my scene ? the result is the same
with or without radiosity...
David
CODE:
#version unofficial MegaPov 0.6; // MegaPOV 0.6A
global_settings {
max_trace_level 15
assumed_gamma 1.0
}
camera {
location <-2.5, 10.0, -10.0>
sky <0.0, 1.0, 0.0>
look_at <0.0, 5.0, 0.0>
}
light_source {<-150.0, 50.0, -200.0> color rgb 1.0}
//==================== PROBLEM ============
sphere {
<0.0, 0.0, 0.0>, 500.0
pigment {color rgb 1.0}
finish {ambient 0.5}
inverse
}
//=========================================
/*
//================== NO PROBLEM ===========
sky_sphere {pigment {color rgb 1.0}}
//=========================================
*/
// ground
box {
<-500.0, -0.5, -500.0>, <500.0, 0.0, 500.0>
pigment {color 0.4}
finish {ambient 0.0 diffuse 0.5}
}
// blue box
box {
<-1.5, 0.0, -0.5>, <1.5, 8.0, 0.5>
pigment {color rgb <0.25, 0.25, 1.0>}
finish {ambient 0.0 diffuse 0.6}
}
Post a reply to this message
Attachments:
Download 'artifact.jpg' (8 KB)
Preview of image 'artifact.jpg'
|
|
|
|
gemelli david wrote:
>
> I started a scene for a new radiosity test and I had this strange
> result...Where is the problem ? in my scene ? the result is the same
> with or without radiosity...
>
The problem is in:
> // ground
> box {
> <-500.0, -0.5, -500.0>, <500.0, 0.0, 500.0>
> pigment {color 0.4}
> finish {ambient 0.0 diffuse 0.5}
> }
>
Change 'pigment {color 0.4}' to 'pigment {color rgb 0.4}'
'color 0.4' expands to 'color rgbft 0.4' and thereby you get a partly
transparent floor. The ghost shape appears on the lower level of the
ground box.
Christoph
--
Christoph Hormann <chr### [at] gmx de>
IsoWood include, radiosity tutorial, TransSkin and other
things on: http://www.schunter.etc.tu-bs.de/~chris/
Post a reply to this message
|
|
