You used green tubes _on top of_ blue tubes.

Nieminen Juha wrote:
> 
>   Here's a more advanced version of my previous maze. I changed the color
> so that it wouldn't look so gross...
> 
>   Now, guess how is it done. Note that the pipes don't intersect anywhere.
> 
>  [Image]
> 
> --
> main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
> ):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

-- 
Mr. Art

"Often the appearance of reality is more important 
than the reality of the appearance."
Bill DeWitt 2000

Post a reply to this message

mr.art <mr.### [at] gcinet> wrote:
: You used green tubes _on top of_ blue tubes.

  Forget the blue tubes. I was not speaking about them. They are just an
ornament so that the picture would not be so monotonic.

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Hey, mr.art, *if* that's your real name, there is no sarcasm allowed in this
group. It's obvious that he used primitives and CSG. He probably even used a
macro or two, I'd bet. I'm willing to go so far to say he used pigment{} and
finish{} statements. Heh.

--
Paul Vanukoff
van### [at] primenetcom

"Nieminen Juha" <war### [at] sarakerttunencstutfi> wrote in message
news:38be8de4@news.povray.org...
> mr.art <mr.### [at] gcinet> wrote:
> : You used green tubes _on top of_ blue tubes.
>
>   Forget the blue tubes. I was not speaking about them. They are just an
> ornament so that the picture would not be so monotonic.
>
> --
> main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
> ):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Paul Vanukoff <van### [at] primenetcom> wrote in message
news:38be9727$1@news.povray.org...
> Hey, mr.art, *if* that's your real name, there is no sarcasm allowed in
this
> group. It's obvious that he used primitives and CSG. He probably even used
a
> macro or two, I'd bet. I'm willing to go so far to say he used pigment{}
and
> finish{} statements. Heh.
>

I was thinking he went to green worm training school. :)

Post a reply to this message

In article <38be75da@news.povray.org>, Nieminen Juha 
<war### [at] sarakerttunencstutfi> wrote:

>   Here's a more advanced version of my previous maze. I changed the color
> so that it wouldn't look so gross...
> 
>   Now, guess how is it done. Note that the pipes don't intersect anywhere.

An out of control delivery truck carrying a shipment of green and blue 
food dye went on a rampage in a spaghetti factory?

That looks a lot like the sphere_sweep object from MegaPOV using a 
non-linear spline...did you modify the maze macro to use sphere_sweeps 
instead of torus/cylinder segments?
I notice that although none of the pipes cross, some do touch the 
neighboring ones.

-- 
Chris Huff
e-mail: chr### [at] yahoocom
Web page: http://chrishuff.dhs.org/

Post a reply to this message

Nieminen Juha wrote:

>   Here's a more advanced version of my previous maze. I changed the color
> so that it wouldn't look so gross...
>
>   Now, guess how is it done. Note that the pipes don't intersect anywhere.

Sure looks to me like they do. They don't cross paths though...
Same way you made the other one but with different shape tiles?

--
___     ______________________________________________________
 | \     |_                 <dav### [at] faricynet> <ICQ 55354965>
 |_/avid |ontaine               http://www.faricy.net/~davidf/

"Sitting on a cornflake, waiting for the van to come" -Beatles

Post a reply to this message

Nieminen Juha wrote:
> 
>   Now, guess how is it done. Note that the pipes don't intersect
> anywhere.

Either a fractal, or random selection from a tilable set.

-- 
ICQ: 46085459

Post a reply to this message

Chris Huff <chr### [at] yahoocom> wrote:
: That looks a lot like the sphere_sweep object from MegaPOV using a 
: non-linear spline...did you modify the maze macro to use sphere_sweeps 
: instead of torus/cylinder segments?

  Nope. It uses cylinders and torii (and spheres for the endings).

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

David Fontaine <dav### [at] faricynet> wrote:
: Same way you made the other one but with different shape tiles?

  You got it.
  I tried the same idea with a triangular tile and noticed how organic-looking
the pipes became. Looked cool to me.

  The source code, if anyone cares:

#declare R=.06;
#declare f60=sin(radians(60));
#declare Pipes=
  union
  { torus { .25,R } torus { .5,R }
    sphere { z*.75,R rotate y*30 }
    torus { .125,R translate z*.375 rotate y*-30 translate x }
    #declare d=.375*f60-.125;
    union
    { torus
      { d,R clipped_by { box { <-d-R, -R-.01, 0><0, R+.01, d+R> } }
        translate z*(.75-d)
      }
      cylinder { <-d, 0, .75-d><-d, 0, .3>,R }
      rotate y*-30 translate x
    }
    union
    { torus { .125,R clipped_by { box { <-.25,-R-.01,-.25><.25,R+.01,0> } } }
      cylinder { x*.125, <.125,0,.2>, R }
      rotate y*-30 translate x*(.75-.125)
    }
    clipped_by
    { intersection
      { box { <0,-R-.01,0><1,R+.01,1> }
        box { <0,-R-.01,0><1,R+.01,1> rotate y*30 }
        box { <0,-R-.01,0><-1,R+.01,1> rotate y*-30 translate x }
      }
    }
  }

#declare t30=tan(radians(30));
#declare Rseed=seed(4);
#macro PlacePipes(place, angleOffset)
  object
  { Pipes
    translate <-.5,0,-.5*t30> rotate y*(int(rand(Rseed)*3)*120+angleOffset)
    translate place+z*(angleOffset?.5/cos(radians(30))-.5*t30:0)
  }
#end

union
{ #declare indX=-2;
  #while(indX<12)
    #declare indZ=-2;
    #while(indZ<12)
      PlacePipes(<indX,0,indZ>, 0)
      PlacePipes(<indX+.5,0,indZ>, 180)
      PlacePipes(<indX,0,indZ+f60>, 180)
      PlacePipes(<indX+.5,0,indZ+f60>, 0)
      #declare indZ=indZ+f60*2;
    #end
    #declare indX=indX+1;
  #end
  pigment { rgb x/2+y } finish { specular .5 }
}
union
{ #declare indX=-2;
  #while(indX<12)
    #declare indZ=-2;
    #while(indZ<12)
      PlacePipes(<indX,-R*2,indZ>, 0)
      PlacePipes(<indX+.5,-R*2,indZ>, 180)
      PlacePipes(<indX,-R*2,indZ+f60>, 180)
      PlacePipes(<indX+.5,-R*2,indZ+f60>, 0)
      #declare indZ=indZ+f60*2;
    #end
    #declare indX=indX+1;
  #end
  pigment { rgb z+y/4 } finish { specular .5 }
}

camera { location <-2,1.5,-3> look_at 0 angle 45 }
light_source { <20,25,-10> 1 }


-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Seems to anal to me.

I would suggest loosening up a bit.
In both your art and life.

Not an easy task, but it is something I try
to do everyday.

Post a reply to this message