The classic got new clothes.
  I thought that since we have got lots of new cool features, why not try
them on the classic image? The image uses the following features:

  - Blinn highlights
  - Variable reflection
  - Blurred reflection
  - Photon mapping (unfortunately almost invisible)
  - Radiosity (gives the overall orange tint to the image)
  - Soft-glow

    Total Time:    2 hours 43 minutes  12.0 seconds (9792 seconds)

  Perhaps it could be used as example scene in pov 3.5?

Post a reply to this message

Attachments:
Download 'Sphere.jpg' (61 KB)

Preview of image 'Sphere.jpg'

Nieminen Juha <war### [at] sarakerttunencstutfi> wrote in message
news:38be3132@news.povray.org...
>   The classic got new clothes.

Very nice - I've often thought that "Reflecting Spheres on Chequered
Background" would make an amusing and enlightening IRTC subject.

Post a reply to this message

Nieminen Juha wrote:

>   Perhaps it could be used as example scene in pov 3.5?

What's with the strange shadow lines ?

*see attached image for reference.

-- 
Ken Tyler -  1300+ Povray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message

Attachments:
Download 'shadow.jpg' (16 KB)

Preview of image 'shadow.jpg'

Ken <tyl### [at] pacbellnet> wrote:
: What's with the strange shadow lines ?

  Yes, it looks like the half of the gap that is closer to the camera (ie. the
normal points away from the camera) should be brighter than the other one
(normal pointing towards the camera), but they look equal in brightness.
  The main light source is rotated just 20 degrees from the z-axis so it's
not that much facing the above mentioned gap half. Perhaps that is the
reason. Or perhaps there's still some strange normal bug?
  Or perhaps you are talking about the white lines in the gap? I'm not
completely sure where does them come. Perhaps they are reflections from
the sphere and/or highlights. Or perhaps another normal bug?

  I can post the source code if someone wants to investigate.

-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Nieminen Juha wrote:
> 
> Ken <tyl### [at] pacbellnet> wrote:
> : What's with the strange shadow lines ?
> 
>   Yes, it looks like the half of the gap that is closer to the camera (ie. the
> normal points away from the camera) should be brighter than the other one
> (normal pointing towards the camera), but they look equal in brightness.
>   The main light source is rotated just 20 degrees from the z-axis so it's
> not that much facing the above mentioned gap half. Perhaps that is the
> reason. Or perhaps there's still some strange normal bug?
>   Or perhaps you are talking about the white lines in the gap? I'm not
> completely sure where does them come. Perhaps they are reflections from
> the sphere and/or highlights. Or perhaps another normal bug?
> 

I was thinking it might be a side effect of using the variable and/or
blurred reflection parameters.

I do know that if I rendered this as one of the example scenes that
come with the program I might be tempted to ask if it is a bug.

-- 
Ken Tyler -  1300+ Povray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message

>  I can post the source code if someone wants to investigate.


Please do! The image is just lovely, and I have so much trouble with the
blurred reflection thing (can't make it fast enough and good enough results
compared to the rendering time ... this one seemed moderate in rendering
time, you see?)

Simen.

Post a reply to this message

Nieminen Juha wrote:

>- Photon mapping (unfortunately almost invisible)
>

I struggle with this phenomena a lot.
Tried making a picture of a photo floating in a white whashing-tray. The 
caustics of the water are almost invisible.
When I do this in the real world in my darkroom, the caustics are very 
visible. It seems the eye can adjust for brightness levels. Pov-Ray can 
not.

Nathan: Is it possible to make the photon intensity variable so they are 
not only visible in shaded areas but also in bright surroundings?

Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

#version unofficial MegaPov 0.4;

global_settings
{ max_trace_level 3
  reflection_blur_max 2
  post_process { soft_glow {1, 8}  }
  photons { count 10000 jitter .5 }
  ambient_light 0.01
  ini_option "+QR"
  radiosity
  { pretrace_start 0.08
    pretrace_end   0.02
    count 50             // CHANGE range from 20 to 150
    nearest_count 5      // CHANGE range from 3 to 10
    error_bound 1        // CHANGE - range from 1 to 3 - should correspond with
pretrace_end
                         //   1 : pretrace_end = 0.02
                         //   3 : pretrace_end = 0.08
                         //   use pretrace_start = 0.08
                         // you can go lower than 1, but then you probably will want
to set
                         // pretrace_end to 0.01, which is really slow
    recursion_limit 3    // CHANGE
    
    low_error_factor .5  // leave this
    gray_threshold 0.0   // leave this
    minimum_reuse 0.015  // leave this
    brightness 1         // leave this
    
    adc_bailout 0.01/2   // CHANGE - use adc_bailout = 0.01 / brightest_ambient_object
    normal on
  }
}

camera { location <-5,2,-4>*1.2 look_at 0 angle 35 }
light_source
{ -z*20, 1
  spotlight point_at 0 radius 7 falloff 10
  area_light x*5,y*5,10,10 adaptive 0
  rotate <45,-20>
  photons { reflection on area_light }
}
light_source
{ -z*20, <1,.7,.2>*.5
  spotlight point_at 0 radius 5 falloff 7
  area_light x*5,y*5,10,10 adaptive 0
  rotate <30,90>
  photons { reflection on area_light }
}

box { -20,20 inverse pigment { rgb x+y*.5 } finish { ambient 10 } }

sphere
{ 0,1
  pigment { rgb <.5,.75,1> }
  finish
  { blinn 2 metallic
    reflection_min .3 reflection_max 1
    reflection_blur .03 reflection_samples 50
  }
  interior { ior 4 }
  photons { target reflection on }
}

#declare Marble1=
  pigment { marble color_map { [0 rgb .5][1 rgb .6] } turbulence .6 scale .3 }
#declare Marble2=
  pigment { marble color_map { [0 rgb .9][1 rgb 1] } turbulence .8 scale .3 }
#declare TileNormal=
  normal
  { gradient x 1 slope_map { [0 <0,1>][.03 <1,0>][.97 <1,0>][1 <0,-1>] }
  }
plane
{ y,-1
  texture
  { pigment { checker pigment { Marble1 }, pigment { Marble2 rotate <30,50> } }
    normal
    { average normal_map
      { [1 TileNormal]
        [1 TileNormal rotate y*90]
        [.4 bumps .5 scale .03]
      }
    }
    finish
    { specular .75
      reflection .5 reflection_blur .05 reflection_samples 20
    }
    scale 2
  }
}


-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Nieminen Juha wrote:
> 
> #version unofficial MegaPov 0.4;

I believe it would be better had you posted this in the text.scene-files
group with a short message here announcing it's location. I will let you
get away with it this time but don't let it happen again or you will be
punished.

<g>

-- 
Ken Tyler -  1300+ Povray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message

Ken <tyl### [at] pacbellnet> wrote in message
news:38BE7705.E9CF2B8C@pacbell.net...
>
>
> Nieminen Juha wrote:
> >
> > #version unofficial MegaPov 0.4;
>
> I believe it would be better had you posted this in the text.scene-files
> group with a short message here announcing it's location

Just out of curiousity (JOOC?), why is this rule in place?

Post a reply to this message

Tom Melly wrote:
> 
> Ken <tyl### [at] pacbellnet> wrote in message
> news:38BE7705.E9CF2B8C@pacbell.net...
> >
> >
> > Nieminen Juha wrote:
> > >
> > > #version unofficial MegaPov 0.4;
> >
> > I believe it would be better had you posted this in the text.scene-files
> > group with a short message here announcing it's location
> 
> Just out of curiousity (JOOC?), why is this rule in place?

To help keep the groups organized. I am sure that you have noticed
that there is an enormous amount of traffic in this group. You may
remember an image from two months ago but trying to find it again
is never an easy task. If someone looks for the source for your image
it is much easier to look for it in one of the scene-files groups,
where the message volume is much lower, than it is here buried at
the bottom of a 20 message thead in this group.

Not only does it keep the groups better organized but it also helps
in finding resources by placing them in the right group to begin
with.

-- 
Ken Tyler -  1300+ Povray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message

> Not only does it keep the groups better organized but it also helps
> in finding resources by placing them in the right group to begin
> with.

P.S. There is no problem is someone wants to know for example what
     texture you used on your sphere or something like that to post
     a snippet of your code here as an example. However if you are
     posting your entire scene file with lights and camera and
     everything then it should be placed in one of the scene file
     groups.

-- 
Ken Tyler -  1300+ Povray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message

I think the problem is simply that you used a normal
instead of doing it with real relief. Normals are fine in
the distance (mostly) but they don't work well up close...

		Jerome
-- 
******************************* Jérôme M. BERGER
* Doctor Jekyll had something * mailto:ber### [at] inamecom
* to Hyde...                  * http://www.enst.fr/~jberger
*******************************

Post a reply to this message

try adding some small surface imperfections to the surface like the polish on
a car little scratches but smaller than a carand dont have it sitting in the
mittle of a frid move the tile over a little bit and mabey put a few more off
in the shadows with focal blur

Nieminen Juha wrote:

>   The classic got new clothes.
>   I thought that since we have got lots of new cool features, why not try
> them on the classic image? The image uses the following features:
>
>   - Blinn highlights
>   - Variable reflection
>   - Blurred reflection
>   - Photon mapping (unfortunately almost invisible)
>   - Radiosity (gives the overall orange tint to the image)
>   - Soft-glow
>
>     Total Time:    2 hours 43 minutes  12.0 seconds (9792 seconds)
>
>   Perhaps it could be used as example scene in pov 3.5?
>
>  [Image]
>
> --
> main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
> ):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

That shadow looks quite prominent, particularly to the left of the 
image, I can see it on both the brown and cream tiles (bottom left).

Impressive results with the blurred reflection on the sphere, and 
the radiosity makes a big difference. 

-- 
Cheers
Steve              email mailto:sjl### [at] ndirectcouk

%HAV-A-NICEDAY Error not enough coffee  0 pps. 

web http://www.ndirect.co.uk/~sjlen/

or  http://start.at/zero-pps

 12:39pm  up  8:56,  2 users,  load average: 1.13, 1.13, 1.05

Post a reply to this message

Purdy.
I think I see the photons; yellowish area on black tile at right?

--
___     ______________________________________________________
 | \     |_                 <dav### [at] faricynet> <ICQ 55354965>
 |_/avid |ontaine               http://www.faricy.net/~davidf/

"Sitting on a cornflake, waiting for the van to come" -Beatles

Post a reply to this message

What is the machine spec for this compile time?

"Nieminen Juha" <war### [at] sarakerttunencstutfi> wrote in message
news:38be3132@news.povray.org...
>   The classic got new clothes.
>   I thought that since we have got lots of new cool features, why not try
> them on the classic image? The image uses the following features:
>
>   - Blinn highlights
>   - Variable reflection
>   - Blurred reflection
>   - Photon mapping (unfortunately almost invisible)
>   - Radiosity (gives the overall orange tint to the image)
>   - Soft-glow
>
>     Total Time:    2 hours 43 minutes  12.0 seconds (9792 seconds)
>
>   Perhaps it could be used as example scene in pov 3.5?
>
>


----------------------------------------------------------------------------
----


>
>
> --
> main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
> ):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

ingo <ing### [at] homenl> wrote...
> Nathan: Is it possible to make the photon intensity variable so they are
> not only visible in shaded areas but also in bright surroundings?

The brightness of the caustics is calculated using the surface properties.
You can adjust it by adjusting the surface properties and the brightness of
the light source.

It would be technically possible to add an intensity parameter, but I
probably won't add it.  It would make objects take more memory, add more
confusion to the already-complex photon settings, and create inconsistency
in the lighting model.

If you want more reflected light increasing the 'reflection' parameter of
the 'finish' should do the trick.  Also, play around with the surface
normals to make sure that the caustics are what you'd expect - specifically,
make sure your normal doesn't disturb the water surface too much, or those
photons will get spread out over too large of a space and the energy will
get dispersed so much that you can't see it.

-Nathan

Post a reply to this message

Very nice an realistic!!
I really like it!

Fabian.

Nieminen Juha a écrit :
> 
>   The classic got new clothes.
>   I thought that since we have got lots of new cool features, why not try
> them on the classic image? The image uses the following features:
> 
>   - Blinn highlights
>   - Variable reflection
>   - Blurred reflection
>   - Photon mapping (unfortunately almost invisible)
>   - Radiosity (gives the overall orange tint to the image)
>   - Soft-glow
> 
>     Total Time:    2 hours 43 minutes  12.0 seconds (9792 seconds)
> 
>   Perhaps it could be used as example scene in pov 3.5?
> 
>  [Image]
> 
> --
> main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
> ):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Noah A <vip### [at] powersurfrcom> wrote:
: try adding some small surface imperfections to the surface like the polish on
: a car little scratches but smaller than a car

  Which surface? I did this with the floor. The sphere is a polished metallic
sphere so it's supposed to be smooth.

: and dont have it sitting in the
: mittle of a frid move the tile over a little bit

  Actually that's the most natural place to put it. If you put a sphere in
a floor like that and the sphere rotates even a bit, it will most probably
end on one of the intersections :)

: and mabey put a few more off in the shadows with focal blur

  Sorry, I'm not completely sure if I understood this completely.


-- 
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Hi Niemenen,

Since we are showcasing megapov, I added an isosurface to give a truely
bevelled surface.

Here's a small image and the code that replaces the plane in your posted
scene file.

#declare fnBevel = function { 
  pigment { 
    gradient x 
    colour_map {
      [0 rgb 0.03]
      [0.03 rgb 0]
      [0.97 rgb 0]
      [1 rgb 0.03]
    } 
  } 
}

isosurface {
  function { y + max(fnBevel(x,0,0), fnBevel(z,0,0)) }
  contained_by { box { -<10,0.1,10>, <10,0.1,10> } }
  eval
  texture
  { pigment { checker pigment { Marble1 }, pigment { Marble2 rotate
<30,50> } }
    normal { bumps .2/2.4 scale .03 }
    finish
    { specular .75
      reflection .5 reflection_blur .05 reflection_samples 20
    }
  }
  scale 2
  translate -y
}


Nieminen Juha wrote:
> 
>   The classic got new clothes.
>   I thought that since we have got lots of new cool features, why not try
> them on the classic image? The image uses the following features:
> 
>   - Blinn highlights
>   - Variable reflection
>   - Blurred reflection
>   - Photon mapping (unfortunately almost invisible)
>   - Radiosity (gives the overall orange tint to the image)
>   - Soft-glow
> 
>     Total Time:    2 hours 43 minutes  12.0 seconds (9792 seconds)
> 
>   Perhaps it could be used as example scene in pov 3.5?
> 
>  [Image]
> 
> --
> main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
> ):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/

Post a reply to this message

Attachments:
Download 'plane.jpg' (13 KB)

Preview of image 'plane.jpg'

"Michael Andrews" <M.C### [at] readingacuk> wrote :
>
>   contained_by { box { -<10,0.1,10>, <10,0.1,10> } }
>

    I can never get contained_by{ } to work, I always have to replace it
with bounded_by. Anyone know the reason?

Post a reply to this message

Good floor, but the aliasing in the image you posted is quite ugly! If you let
a longer render go it would be an awesome pic.

--
___     ______________________________________________________
 | \     |_                 <dav### [at] faricynet> <ICQ 55354965>
 |_/avid |ontaine               http://www.faricy.net/~davidf/

"Sitting on a cornflake, waiting for the van to come" -Beatles

Post a reply to this message

On Fri, 3 Mar 2000 16:16:26 -0500, "Bill DeWitt"
<the### [at] earthlinknet> wrote:

>    I can never get contained_by{ } to work, I always have to replace it
>with bounded_by. Anyone know the reason?

Are you using MegaPOV 0.3? If yes, consider downloading 0.4.


Peter Popov
pet### [at] usanet
ICQ: 15002700

Post a reply to this message

"Peter Popov" <pet### [at] usanet> wrote :
>
> Are you using MegaPOV 0.3? If yes, consider downloading 0.4.
>

    What is really funny is that I did download 0.4 ... I simply failed to
install it...

Post a reply to this message

Ken wrote:
> 
> What's with the strange shadow lines ?
> 

This is just an artifact of using a normal map instead of actual geometry.
You can improve the look of the intersections by using a boxed pattern instead
of averaged gradients; but this will not get rid of the edge artifacts. For
that, I'd suggest an isosurface.

Margus

Post a reply to this message

Better?

normal{
  boxed 1 slope_map{[0 <0,0>][.06 <1,0>]}
  scale .5 translate (x+z)*.5
  warp{repeat x}
  warp{repeat z}
}

Post a reply to this message

Attachments:
Download 'sp.jpg' (14 KB)

Preview of image 'sp.jpg'

On Sat, 04 Mar 2000 17:25:26 +0200, Margus Ramst wrote:
>This is a multi-part message in MIME format.
>--------------6549A269A67923EAA2564B2F
>Content-Type: text/plain; charset=us-ascii
>Content-Transfer-Encoding: 7bit
>
>Better?

Hey you know what that reminds me of, (_|_)


-- 
Cheers
Steve              email mailto:sjl### [at] ndirectcouk

%HAV-A-NICEDAY Error not enough coffee  0 pps. 

web http://www.ndirect.co.uk/~sjlen/

or  http://start.at/zero-pps

  1:41am  up 2 days,  1:54,  3 users,  load average: 1.63, 1.48, 1.20

Post a reply to this message

Margus Ramst <mar### [at] peakeduee> writes:

> Better?

Much better!

Thomas

-- 
http://thomas.willhalm.de/ (includes pgp key)

Post a reply to this message

Dude

Post a reply to this message