|
 |
I was experimenting with this rust texture a while back, and never used
it... maybe someone might be interested.
Andrew C
---------------------------------
camera {
location <0,0,-2.5>
look_at <0,0,1>
}
light_source {
<100,100,-100>
color rgb 1
}
light_source {
<-100,100,-100>
color rgb 0.5
}
background { color rgb <0.8,0.8,0.9> }
sphere {
0,1
texture {
pigment {
color rgb<0.6, 0.6, 0.6>
}
finish {
ambient 0
diffuse 1
specular 0.1
roughness 0.05
metallic
reflection 0.1
}
}
texture {
pigment {
bozo
translate <10, 10, 10>
pigment_map {
[ 0.0 color rgbt<0.55, 0.55, 0.55, 1> ]
[ 0.5 bozo
scale 0.1
pigment_map {
[ 0 color rgbt <0.55, 0.55, 0.55, 1> ]
[ 1 bozo
scale 0.4
color_map {
[ 0 rgb <0.5, 0.5, 0.5> ]
[ 1 rgb <0.55, 0.55, 0.55> ]
}
]
}
]
}
}
finish {
ambient 0
diffuse 1
specular 0.1
roughness 0.05
metallic
reflection 0.1
}
normal {
bozo
translate <10, 10, 10>
normal_map {
[ 0.0 bozo 0.1 scale <1, 0.1, 1> rotate z*30 ]
[ 0.5 bozo
scale 0.1
normal_map {
[ 0 bozo 0 ]
[ 1 bozo 2 ]
}
]
}
}
}
texture {
pigment {
bozo
pigment_map {
[ 0 color rgbt <0.7, 0.5, 0.3, 1> ]
[ 0.4 crackle scale 0.05
pigment_map {
[ 0 bozo scale 0.3
color_map {
[ 0 rgbt <0.7, 0.5, 0.3, 0.0> ]
[ 0.5 rgbt <0.7, 0.5, 0.2, 0.0> ]
[ 1 rgbt <0.7, 0.55, 0.4, 0.0> ]
}
]
[ 0.2 rgbt <0.6, 0.3, 0.2, 1> ]
[ 1 rgbt <0.6, 0.3, 0.2, 1> ]
}
]
[ 0.9 bozo scale 0.3
color_map {
[ 0 rgbt <0.7, 0.5, 0.3, 0.0>*0.9 ]
[ 0.5 rgbt <0.7, 0.5, 0.2, 0.0>*0.9 ]
[ 1 rgbt <0.7, 0.55, 0.4, 0.0>*0.8 ]
}
]
}
}
finish {
ambient 0
diffuse 1
specular 0.1
roughness 0.05
metallic
}
normal {
bozo
normal_map {
[ 0 bozo 0 ]
[ 0.4 crackle 0.1 scale 0.05 ]
[ 0.8 granite 0.1 scale 0.1 ]
}
}
}
}
Post a reply to this message
Attachments:
Download 'rust.jpg' (9 KB)
Preview of image 'rust.jpg'
|
|
de> wrote in message
news: