A proximity pattern test. This type of proximity method can be quite noisy at
times, depending on the number of samples used. This object got 12 samples and
the scene took 35 seconds to render using low radiosity and focal blur settings.

Just in case any wants it, here's the proximity macro:

/* Proximity pattern macro
 ProxObject = input object
 Radius   = proximity radius
 Samples   = number of priximy samples
 TurbScale  = scale of turbulence
 TurbAmt   = amount of turbulence
 Example: Object_Prox(MyObject, .3, 20, 1000, 100)
*/
#macro Object_Prox(ProxObject, Radius, Samples, TurbScale, TurbAmt)
 pigment_pattern{
  average
  pigment_map{
   // fermat spiral-sphere distribution
   #local Inc = pi * (3 - sqrt(5));
   #local Off = 2 / Samples;
   #for(K, 0, Samples-1)
    #local Y = K * Off - 1 + (Off / 2);
    #local R = sqrt(1 - Y*Y);
    #local Phi = K * Inc;
    [1
     // object pattern with small-scale turbulence
     pigment_pattern{
      object{ProxObject}

      scale TurbScale
      warp{turbulence TurbAmt lambda 1}
      scale 1/TurbScale

      translate <cos(Phi)*R, Y, sin(Phi)*R>*Radius
     }
    ]
   #end
  }
 }
#end

Post a reply to this message

Attachments:
Download 'denoise-prox-test3.jpg' (338 KB)

Preview of image 'denoise-prox-test3.jpg'