POV-Ray : Newsgroups : povray.binaries.images : The Shallows II (2/3) : Re: The Shallows II (2/3) Server Time
26 Nov 2022 04:53:13 EST (-0500)
  Re: The Shallows II (2/3)  
From: ingo
Date: 22 Nov 2022 13:45:00
Message: <web.637d184d9d632bff17bac71e8ffb8ce3@news.povray.org>
"Mr" <m******r******at_hotmail_dot_fr> wrote:

>
> Do you think such a result could be achieved using HG POV displacement or
> isosurface displacement macros? If yes an include like you did for Granite would
> really be worth it, and if not, maybe a tutorial ?

It can probably be done with the meshmaker.inc that comes with POV-Ray.

A crude crackle cylinder example:

---%<------%<------%<---

#version 3.8;

#include "meshmaker.inc"

global_settings {assumed_gamma 1.0}
camera {
   location  <0,1,-10>
   look_at   <0,0,0>
   angle 20
}
light_source { <500,500,-500> rgb <1,0.9,0.8> }
light_source { <-100,100,-500> rgb <0.3,0.3,0.5> }

#declare Crack= function {
  pigment {
    crackle
    colour_map{
      [0, rgb .01]
      [1, rgb .05]
    }
    scale 0.05
  }
}
#declare R= function(u,v) {
  Crack(u,v,0).gray
}

#declare F1= function(u,v){(.5+R(u,v))*cos(u)}
#declare F2= function(u,v){(.5+R(u,v))*sin(u)}
#declare F3= function(u,v){v}

object{
   Parametric(
      F1, F2, F3,
      <0, -1>,
      <2*pi, 1>,
      500, 500, ""
   )
   uv_mapping
   pigment{rgb 1}
   finish{specular 0.5}
   rotate <60,0,0>
}

---%<------%<------%<---


Post a reply to this message

Copyright 2003-2021 Persistence of Vision Raytracer Pty. Ltd.