in news:3m3cvv0lak15tgvcguu7eapdf86585dvjg@4ax.com Stephen McAvoy
wrote: 

> This is low quality (no AA and low Media intervals (10)) settings. To
> reduce the time of render.

Did you use atmospheric media or contained media? The latter is faster.

> It shows the dullness I am experiencing
> with Media.

You could add a density pattern with some turbulence to make the 
lightbeam more attractive. Also maybe put the spotlight closer to the 
object, so the beam gets less parallel

> The spotlight is two spotlights one reacting to media to
> give the visible beam the other to give the spot on the ground. My
> initial idea was to control a spotlight but it developed into a long
> learning curve. I don't think I'd get a job as a spotlight
> operator:-} Any advice on media would be appreciated.

Below is a small scene. 
- The fade_power/disytance is used to make the light brighter near the 
spot (doesn't show much though :( )
- To animate the spot, add a clock to the PointAt variable.
- The cone is a bit too short, I didn't feel like figuring out the math.
- To vary the density, change the 'rgb 1' in scattering or play with the 
color_map in the density block.

Your danceuse is great!

---%<------%<------%<---
#version 3.5;
global_settings {
  assumed_gamma 1.0
}
camera {
  location  <0.0, 1, -6.0>
  right     x*image_width/image_height
  look_at   <-1.0, 2, 0.0>
}

#declare Location=<-20,20,-5>;
#declare PointAt=<0,0,0>; //animate

light_source {
  Location
  rgb 1 
  spotlight
  point_at PointAt
  radius 1
  falloff 3
  tightness 0
  fade_distance vlength(PointAt-Location)
  fade_power 2
}

cone {
  Location,0 PointAt,3.1  //a bit wider than falloff
  hollow
  pigment {rgbf 1}
  finish {ambient 0 diffuse 0}
  interior {
    media {
      intervals 1      
      samples 1,1       
      scattering {      
        2,        // play with this      
        rgb 1          
        extinction 0.0    
      }
      method 3
      density {
        wood
        scale 2
        turbulence 0.5
        octaves 7
        lambda 0.5
        omega 0.5
        color_map{
          [0.0, rgb 0.1]
          [0.7, rgb 0.2]  //vary intesity of scattering
        }
      }
    }
  }      
}

plane {     
  y, 0
  pigment { color rgb <0.7,0.5,0.3> }
}

sphere {
  <0,0.6,0> 0.6
  texture {
    pigment {
      rgb<1,0,0>
    }
    finish{
      specular 0.6
    }
  }
}
---%<------%<------%<---

Ingo

Post a reply to this message

On 3 Jan 2004 07:11:33 -0500, ingo <ing### [at] tagpovrayorg> wrote:

>Did you use atmospheric media or contained media? The latter is faster.

I used contained media but it was a large-ish container. I am still
experimenting with media.

>> It shows the dullness I am experiencing
>> with Media.
>
>You could add a density pattern with some turbulence to make the 
>lightbeam more attractive. Also maybe put the spotlight closer to the 
>object, so the beam gets less parallel

I will add a density pattern with some turbulence later but first things first.
Since I like to make cyclic animations the smoky effect will need to be
carefully thought out. I have a lot of experience of looking at lighting in the
theatre. I initially had the spot much closer to the stage but the cone was too
obvious. Since I create my scenes using Moray I don't have the option of using
the point_at keyword and have to use the rotate <x,y,z>. This is not such a
great disadvantage because the meshes I use are displaced internally and as far
as PovRay is concerned they are static through out the animation. I used a
spline to control the rotation. I've just reread my initial statement and your
answer and I think there was some misunderstanding. When I said dullness I meant
lack of clarity or as if the objects were tarnished. I now think this is due to
a too high rgb value in the media.


>Below is a small scene. 
>- The fade_power/disytance is used to make the light brighter near the 
>spot (doesn't show much though :( )
>- To animate the spot, add a clock to the PointAt variable.
>- The cone is a bit too short, I didn't feel like figuring out the math.
>- To vary the density, change the 'rgb 1' in scattering or play with the 
>color_map in the density block.

In your scene you use a cone as a container, I tried that and because I needed
to use some secondary lighting, the container cone created a shadow (it looked
like a dark halo around the container cone). If I made it shadowless I got a
whiteout :-} so I used one spot reacting with media for the visible light
(strange phrase) and another to give a spot on the floor. Bob Hughes thought
that this problem could have been caused by the floor finish having a too low
diffuse value (Tested and true). So that is fixed.

>Your danceuse is great!

Thank you, I think I have "cracked" using bvh files in Poser.
I appreciate your comments.

Regards
        Stephen

Post a reply to this message