Greetings,

From an effect noticed by a forum gent named "Ard":

In PoV-Ray 3.7 beta 6, media lit by a cylindrical light_source which is in 
the camera view, does not show in front of the light's aperture.  This 
produces the effect of a "hole" in the media where the light_source is in 
the scene.

This only impacts the media illumination from *that* light.  Media effects 
caused by other light sources in the scene are still rendered for the 
affected pixels.

The code example below has a red cylindrical light aimed directly at the 
camera, showing a scattering media hole over the aperture.  A green 
cylindrical light is aimed across the view and through the affected zone, to 
show that the lights do not interact with each other.  However a closer look 
at the green light source shows its aperture is also dark with respect to 
media with a similarly sharp boundary.

Note:  This is not in expectation of a looks_like effect on lights, just 
about media behaviour.  The original "black hole" problem of V3.5 and 3.6 is 
fixed however -- thanks!  Now we just have a "transparent hole"  :-)

Tested on the 32-bit executable.

Thanks and kind regards,
  Brian

---- code ----

camera {location <0, 1, -1.5> look_at y}

// Enclosing container
sphere
{ 0, 2.1 hollow
  pigment  {bozo scale 0.2}
  interior {media {scattering {2, rgb 0.5 extinction 0}}}
}

// Red light aimed at the camera
light_source
{ <0, 1,  0.5>
  color rgb <1, 0, 0>
  cylinder
  radius  0.05
  falloff 0.1
  point_at <0, 1, -1.5>
}

// Green light on left, aimed right,
light_source
{ <-1, 1, 0.5>
  color rgb <0, 5, 0>
  cylinder
  radius 0.05
  falloff 0.1
  point_at <1, 1, 0.5>
}

//Tiny white indicators placed at the light sources
sphere {< 0, 1, 0.5>, 0.02 pigment {rgb 1} finish {ambient 1}}  // at red
sphere {<-1, 1, 0.5>, 0.02 pigment {rgb 1} finish {ambient 1}}  // at green

Post a reply to this message