On Mon, 22 Apr 2002 18:36:46 +0200, Christoph Hormann <chr### [at] gmxde>
wrote:
> Have you tried turning your monitor upside down and walking 3 times around
> the table before?

Thorsten said some day there is no magic in parser but message told me it is
an exception so I will perform this test next time :-)

ABX

Post a reply to this message

Christoph Hormann <chr### [at] gmxde> wrote:
> I still get a crash with the second problem from:

> http://news.povray.org/3CB1B39A.3F70A85A%40gmx.de

  It would be really nice to get a short (and undivided) example code that
demonstrates this. It's not nice to have to get some include file from
somewhere.

-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message

Warp wrote:
> 
>   It would be really nice to get a short (and undivided) example code that
> demonstrates this. It's not nice to have to get some include file from
> somewhere.

All right, but i'm afraid it's no more that short then.

// BEGIN POV-Code

camera {
  location <0.2,0.2,-1>  
  look_at  <0,0,0>
  right (4/3)*x                
} 

light_source {     
  <1000, 2500, -5000> 
  color rgb 1.2
}     
                              
#include "transforms.inc" 

#declare IC_Arr=array[12] 

#macro IC_Merge_Array(Array)
  #local Size=dimension_size(Array,1);

  function {
    min(
      #local Counter=0;
      #while (Counter<Size)
        #if (Counter>0) , #end
          Array[Counter] (x,y,z)
        #local Counter=Counter+1;
      #end
    )
  }
#end  


#macro IC_Matrix (Fn, Mtrx)  

  function {
    Fn(x*Mtrx[0][0] + y*Mtrx[0][1] + z*Mtrx[0][2],
       x*Mtrx[1][0] + y*Mtrx[1][1] + z*Mtrx[1][2],
       x*Mtrx[2][0] + y*Mtrx[2][1] + z*Mtrx[2][2])
  }
#end

#macro IC_RotateR (Fn, Vect)
  #local Vect=Vect+<0,0,0>;

  #local Cx=-Vect.x;
  #local Cy=-Vect.y;
  #local Cz=-Vect.z;

  #local MtrxA=array[3][3]
  #local MtrxB=array[3][3]
  #local MtrxC=array[3][3]

  #local MtrxA[0][0] = 1.0;
  #local MtrxA[0][1] = 0;
  #local MtrxA[0][2] = 0;
  #local MtrxA[1][0] = 0;
  #local MtrxA[1][1] = cos(Cx);
  #local MtrxA[1][2] = -sin(Cx);
  #local MtrxA[2][0] = 0;
  #local MtrxA[2][1] = sin(Cx);
  #local MtrxA[2][2] = cos(Cx);

  #local MtrxB[0][0] = cos(Cy);
  #local MtrxB[0][1] = 0;
  #local MtrxB[0][2] = sin(Cy);
  #local MtrxB[1][0] = 0;
  #local MtrxB[1][1] = 1;
  #local MtrxB[1][2] = 0;
  #local MtrxB[2][0] = -sin(Cy);
  #local MtrxB[2][1] = 0;
  #local MtrxB[2][2] = cos(Cy);

  #local MtrxC[0][0] = cos(Cz);
  #local MtrxC[0][1] = -sin(Cz);
  #local MtrxC[0][2] = 0;
  #local MtrxC[1][0] = sin(Cz);
  #local MtrxC[1][1] = cos(Cz);
  #local MtrxC[1][2] = 0;
  #local MtrxC[2][0] = 0;
  #local MtrxC[2][1] = 0;
  #local MtrxC[2][2] = 1;

  #local fn_X=IC_Matrix (function(x, y, z){ Fn(x, y, z) }, MtrxA)
  #local fn_Y=IC_Matrix (function(x, y, z){ fn_X(x, y, z) }, MtrxB)

  IC_Matrix (function(x, y, z){ fn_Y(x, y, z) }, MtrxC)

#end

#macro IC_Rotate (Fn, Vect) 
  #local Vect=Vect+<0,0,0>;

  #local Cx=(Vect.x/180)*pi;
  #local Cy=(Vect.y/180)*pi;
  #local Cz=(Vect.z/180)*pi;
  IC_RotateR (function(x, y, z){ Fn(x, y, z) }, <Cx, Cy, Cz>)
#end

#macro IC_Cone (Start, Radius1, End, Radius2)
  #local Start=Start+<0,0,0>;

  #local Cx=Start.x;
  #local Cy=Start.y;
  #local Cz=Start.z;

  #local Len=vlength(End-Start);

  #if (Len=0)
    #error "iso_csg.inc: Error: zero height cone"
  #end

  #local fn_T=function { Reorient_Trans(End-Start, x)  }

  #local fn_X=function(x, y, z){
    max(sqrt(y^2 + z^2) - Radius1+x*((Radius1-Radius2)/Len), -x, x-Len)
  }
  #local fn_Y=
  function(x, y, z){
    fn_X(fn_T(x, y, z).x,
         fn_T(x, y, z).y,
         fn_T(x, y, z).z)
  }

  function {
    (fn_Y((x-Cx),(y-Cy),(z-Cz)))
  }
#end

#declare IC_Arr=array[12]

#macro IC_Merge_Array(Array)  
  #local Size=dimension_size(Array,1);

  function {
    min(
      #local Counter=0;
      #while (Counter<Size)
        #if (Counter>0) , #end
          Array[Counter] (x,y,z)
        #local Counter=Counter+1;
      #end
    )
  }
#end

#declare IC_Arr[0]=IC_Cone(0, 0, x+y, 1)                     
#declare IC_Arr[1]=IC_Rotate(IC_Arr[0], 30*z)                   
#declare IC_Arr[2]=IC_Rotate(IC_Arr[1], 60*z)
#declare IC_Arr[3]=IC_Rotate(IC_Arr[2], 90*z)
#declare IC_Arr[4]=IC_Rotate(IC_Arr[3], 120*z)
#declare IC_Arr[5]=IC_Rotate(IC_Arr[4], 150*z)     
#declare IC_Arr[6]=IC_Rotate(IC_Arr[5], 180*z)
#declare IC_Arr[7]=IC_Rotate(IC_Arr[6], 210*z)
#declare IC_Arr[8]=IC_Rotate(IC_Arr[7], 240*z)      
#declare IC_Arr[9]=IC_Rotate(IC_Arr[8], 270*z)    
#declare IC_Arr[10]=IC_Rotate(IC_Arr[9], 300*z)      
#declare IC_Arr[11]=IC_Rotate(IC_Arr[10], 330*z)   

#declare fn_XX= IC_Merge_Array(IC_Arr) 

isosurface
{                                                                                     
  function { fn_XX(x, y, z) }  
  max_gradient 1.6 
  contained_by { box { -2, 2 } }
  pigment { rgb <0, 0.2, 1.1> } 
  finish { specular 0.3 } 
  scale 0.1
} 

// END POV-Code


-- 
POV-Ray tutorials, IsoWood include,                 
TransSkin and more: http://www.tu-bs.de/~y0013390/  
Last updated 20 Apr. 2002 _____./\/^>_*_<^\/\.______

Post a reply to this message

On 21 Apr 2002 19:41:55 -0400, Warp <war### [at] tagpovrayorg> wrote:
> I might have missed some bugs reported since the last buglist, so feel
> free to reply with a note.
>
>  Officially confirmed bugs:
>  -------------------------

Probably nothing to worry about but ... In changes.txt there is note about
Change 1523 : "Partial fix for radiosity recursion problems" in RC2 section.
If it is a partial fix then there must be something left still not work. But
there is no note in your list about anything like official not fixed bug in
radiosity.

ABX

Post a reply to this message

Ok, noted. (Although a shorter example would have been nicer...)

-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message

Curiously it doesn't crash in the unix version...

-- 
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}//  - Warp -

Post a reply to this message

On 23 Apr 2002 11:11:32 -0400, Warp <war### [at] tagpovrayorg> wrote:
>  Curiously it doesn't crash in the unix version...

Confirm crash of this shorter version of script on
POV 3.5 RC2 icl on WinNT Sp 6 PII 233 with 128 MB

ABX

Post a reply to this message

Skiba <abx### [at] babilonorg>  wrote:

> Probably nothing to worry about but ... In changes.txt there is note about
> Change 1523 : "Partial fix for radiosity recursion problems" in RC2 section.
> If it is a partial fix then there must be something left still not work. But
> there is no note in your list about anything like official not fixed bug in
> radiosity.

Because there is change 1526...

    Thorsten

____________________________________________________
Thorsten Froehlich, Duisburg, Germany
e-mail: tho### [at] trfde

Visit POV-Ray on the web: http://mac.povray.org

Post a reply to this message

On Tue, 23 Apr 2002 18:30:26 +0200, "Thorsten Froehlich" <tho### [at] trfde>
wrote:
> > Change 1523 : "Partial fix for radiosity recursion problems" in RC2 section.
> > If it is a partial fix then there must be something left still not work.
>
> Because there is change 1526...

Then the name of 1526 fix should be fixed to "Final fix for radiosity
recursion problems" in next RC then ;-)

YKIHBRTL

Post a reply to this message

On Tue, 23 Apr 2002 13:41:53 +0200, Christoph Hormann <chr### [at] gmxde>
wrote:
>
> All right, but i'm afraid it's no more that short then.

After walking around rotated monitor I have good news for you Chris :-).
On my tests crash disappear when sequence of:

> #macro IC_Matrix (Fn, Mtrx)  
> #macro IC_RotateR (Fn, Vect)
> #macro IC_Rotate (Fn, Vect) 

is replaced with short

#macro IC_Rotate (Fn, Vect) 
  #local f_T=function{transform{rotate -Vect}};
  function{Fn(f_T(x,y,z).x,f_T(x,y,z).y,f_T(x,y,z).z)}
#end

It not changes that your macros shouldn't crash however you can make stable
version. I think in correct form it shuld rather
transform{rotate Vect inverse}

ABX

Post a reply to this message