I've been trying to dig up an old macro/scene by Ron Parker. It's not on 
the server anymore, it's not in 
https://usenetarchives.com/groups.php?c=povray

It is a macro/scene for creating a arabeske/arabic like tiling 
pattern.The beauty was that it did work in 3D, not just on a 2D plane. 
By adding a slight rotation to it the pattern kept changeing, while 
still being similar.

Does it ring a bell? Anyone?

Sadly I lost my complete newsgroup archive.

Cheers,

Ingo

Post a reply to this message

On 2026-07-19 21:02, ingo wrote:
> I've been trying to dig up an old macro/scene by Ron Parker. It's not on 
> the server anymore, it's not in https://usenetarchives.com/groups.php? 
> c=povray
> 
> It is a macro/scene for creating a arabeske/arabic like tiling 
> pattern.The beauty was that it did work in 3D, not just on a 2D plane. 
> By adding a slight rotation to it the pattern kept changeing, while 
> still being similar.
> 
> Does it ring a bell? Anyone?
> 
> Sadly I lost my complete newsgroup archive.
> 
> Cheers,
> 
> Ingo

Found it
---%<------%<------%<------%<---
// Arabesque_tile by Ron Parker

#macro Arabesque( Param )
   #declare Sd = seed(Param);
   #declare Rv = <rand(Sd),rand(Sd),rand(Sd)>*500;
   #local C=pigment{crackle solid
     color_map{
       [1/12 red 1]
       [1/12 red 1 green 1][3/12 red 1 green 1]
       [3/12 green 1][5/12 green 1]
       [5/12 green 1 blue 1][7/12 green 1 blue 1]
       [7/12 blue 1][9/12 blue 1]
       [9/12 blue 1 red 1][11/12 blue 1 red 1]
       [11/12 red 1]
     }
   }
   #local G=pigment{crackle
     pigment_map{[.05 rgb 0][.05 C]}
     scale .2
     translate Rv
     warp {repeat z flip z}
   }
   #local B=pigment{
     radial
     pigment_map{
       #local i=0;
       /*#while(i<6)
         [i/6 G rotate(30+60*i)*y]
         [(i+1)/6 G rotate(30+60*i)*y]
         #local i=i+1;
       #end*/
       #while(i<12)
         [i/12 G rotate(15+30*i)*y]
         [(i+1)/12 G rotate(15+30*i)*y]
         #local i=i+1;
       #end
     }
   }
   #local T2=sqrt(3)/2;
   radial
   pigment_map{
     [1/3 B translate<.5,0,-T2>]
     [1/3 B translate<-1,0,0>]
     [2/3 B translate<-1,0,0>]
     [2/3 B translate<.5,0,T2>]
   }
   translate x
   warp{repeat 1.5*x flip x}
   warp{repeat .5*sqrt(3)*z flip z}
#end

plane {y 0 pigment {Arabesque(7)rotate <0,0,0.6>} finish {ambient 1} }
camera {location 10*y sky z look_at 0}
---%<------%<------%<------%<---

Post a reply to this message

On 8/16/26 09:54, ingo wrote:
> Found it

I'm glad you found it, and thanks for posting the code!

I did a number of v3.7 & v3.8 renders vs yuqk renders(a) given the code 
is exposed to the, multiple crackle uses within a thread, cache bug in 
the v3.7 and v3.8 code.

V3.8 beta 2 image on top and yuqk image on the bottom.

The color distribution looks better for the 'crackle solid' base pattern 
in yuqk, but I'm unsure why. I doubt it would be cache fix related - but 
maybe? Or, maybe something else with the yuqk re-write of the crackle 
code...

Results have me wondering how old POV-Ray versions rendered the scene, 
but I don't have any old compiles handy and no more time to play...

In any case, cool code!

Bill P.

(a) - I used 'crackle solid scale 0.3' for the base in the images attached.

Post a reply to this message

Attachments:
Download 'arabesque_rp_38b2_vs_yuqk.png' (598 KB)

Preview of image 'arabesque_rp_38b2_vs_yuqk.png'

hi,

William F Pokorny <ano### [at] anonymousorg> wrote:
> On 8/16/26 09:54, ingo wrote:
> > Found it
>
> I'm glad you found it, and thanks for posting the code!

+1.  seeing the pattern, immediately a question of "cosmic importance" :-) came
to mind, attached.


> Results have me wondering how old POV-Ray versions rendered the scene,
> but I don't have any old compiles handy and no more time to play...

will post a second reply with a v3.7.0.8 render attached.


regards, jr.

Post a reply to this message

Attachments:
Download 'hippietie.png' (193 KB)

Preview of image 'hippietie.png'

Post a reply to this message

Attachments:
Download 'arabesque_tile.png' (231 KB)

Preview of image 'arabesque_tile.png'

On 2026-08-16 21:56, William F Pokorny wrote:
> Results have me wondering how old POV-Ray versions rendered the scene, 
> but I don't have any old compiles handy and no more time to play...

I found it in obscure directory with house renovation files dated 2003 
and 2006. My guess it would have been made with POV-Ray 3.1

ingo

Post a reply to this message

On 2026-08-17 07:27, jr wrote:
> 
> +1.  seeing the pattern, immediately a question of "cosmic importance" :-) came
> to mind, attached.
> 
Oh my, coffee on the keyboard :) :)

ingo

Post a reply to this message

On 8/17/26 01:27, jr wrote:
> +1.  seeing the pattern, immediately a question of "cosmic importance" 🙂 came
> to mind, attached.

:-) Hah! I do miss banging on POV-Ray with you guys. Maybe I'll more 
play time this winter.

Bill P.

Post a reply to this message

On 8/17/26 01:31, ingo wrote:
> On 2026-08-16 21:56, William F Pokorny wrote:
>> Results have me wondering how old POV-Ray versions rendered the scene, 
>> but I don't have any old compiles handy and no more time to play...
> 
> I found it in obscure directory with house renovation files dated 2003 
> and 2006. My guess it would have been made with POV-Ray 3.1
> 
> ingo

Thank you (& jr) for the additional information.

I woke up this morning remembering I released R15 of yuqk with the 
crackle cache disabled (a hack). It was done so I would always have 
handy crackle results without bad results due same thread cache 
collisions. Running this version showed no changes in the crackle solid 
color distribution.

I then decided to read my own yuqk release notes... I ran across this 
for R16: "Of note, the dependency the ip_solid option had on the noise 
generators was removed."

(ip_solid being yuqk's new internal pattern keyword for solid)

I've updated the release notes for this change to read:

Of note, the dependency the ip_solid option had on the noise generators 
was removed. This done so the solid values generated are evenly 
distributed between zero and one rather than being a sloppy, 
normalized/Gaussian set of values roughly centered about 0.5.

The color differences are due an intentional change to yuqk that I'd 
forgotten!

Bill P.

Post a reply to this message

On 16/08/2026 15:54, ingo wrote:

> 
> Found it
> ---%<------%<------%<------%<---
> // Arabesque_tile by Ron Parker
 >
> [snip]>

Really very interesting. Thanks for sharing.




-- 
klp
compagnie de la banquise

Post a reply to this message

hi,

William F Pokorny <ano### [at] anonymousorg> wrote:
> :-) Hah! I do miss banging on POV-Ray with you guys. Maybe I'll more
> play time this winter.

that would be good.  who knows, maybe the winter will be long enough to see you
getting "bored" and adding an '-into' option ;-).  cheers.


@ingo
.... coffee ...
(sorry.. ;-))


regards, jr.

Post a reply to this message

William F Pokorny <ano### [at] anonymousorg> wrote:

> I did a number of v3.7 & v3.8 renders vs yuqk renders

Nice!

This looks like a similar pattern posted by Mike Williams, and also a bit like
the patterns by Tek that I animated.

I would imagine that there are tons of variations we could do with this, as well
as perhaps applying "attractors" to vary the pattern.

- BE

Post a reply to this message

"Bald Eagle" <cre### [at] netscapenet> wrote:
> William F Pokorny <ano### [at] anonymousorg> wrote:
>
> > I did a number of v3.7 & v3.8 renders vs yuqk renders
>
> Nice!
>
> This looks like a similar pattern posted by Mike Williams, and also a bit like
> the patterns by Tek that I animated.
>
> I would imagine that there are tons of variations we could do with this, as well
> as perhaps applying "attractors" to vary the pattern.
>
> - BE

I had a somewhat similar idea for patterns. First create a "WorleyForceFiled", a
smooth vector field pointing away from every nearby Worley feature point.

This you can feed into a domain warp that pushes the pattern away a bit, or
pulls it in. Inspired by the black hole warp but without the black holes and
somewhat different.

In my ray-tracer source:

proc worleyWarp*(
    p: PatternSpec,
    amount: float32 = 1.0f,
    radius: float32 = 1.2f,
    seed: int64 = 0,
    searchRadius: int = 1,
): PatternSpec =

  let force = worleyForceField(seed, radius, searchRadius)
  let displaceFn = proc(point: Vec3): Vec3 {.gcsafe.} =
    point + force(point) * amount
  warpedBy(p, displaceFn)

it works, but the ray-tracer as a whole currently not, so no pretty pictures.

ingo

Post a reply to this message