On 2026-07-19 21:02, ingo wrote:
> I've been trying to dig up an old macro/scene by Ron Parker. It's not on 
> the server anymore, it's not in https://usenetarchives.com/groups.php? 
> c=povray
> 
> It is a macro/scene for creating a arabeske/arabic like tiling 
> pattern.The beauty was that it did work in 3D, not just on a 2D plane. 
> By adding a slight rotation to it the pattern kept changeing, while 
> still being similar.
> 
> Does it ring a bell? Anyone?
> 
> Sadly I lost my complete newsgroup archive.
> 
> Cheers,
> 
> Ingo

Found it
---%<------%<------%<------%<---
// Arabesque_tile by Ron Parker

#macro Arabesque( Param )
   #declare Sd = seed(Param);
   #declare Rv = <rand(Sd),rand(Sd),rand(Sd)>*500;
   #local C=pigment{crackle solid
     color_map{
       [1/12 red 1]
       [1/12 red 1 green 1][3/12 red 1 green 1]
       [3/12 green 1][5/12 green 1]
       [5/12 green 1 blue 1][7/12 green 1 blue 1]
       [7/12 blue 1][9/12 blue 1]
       [9/12 blue 1 red 1][11/12 blue 1 red 1]
       [11/12 red 1]
     }
   }
   #local G=pigment{crackle
     pigment_map{[.05 rgb 0][.05 C]}
     scale .2
     translate Rv
     warp {repeat z flip z}
   }
   #local B=pigment{
     radial
     pigment_map{
       #local i=0;
       /*#while(i<6)
         [i/6 G rotate(30+60*i)*y]
         [(i+1)/6 G rotate(30+60*i)*y]
         #local i=i+1;
       #end*/
       #while(i<12)
         [i/12 G rotate(15+30*i)*y]
         [(i+1)/12 G rotate(15+30*i)*y]
         #local i=i+1;
       #end
     }
   }
   #local T2=sqrt(3)/2;
   radial
   pigment_map{
     [1/3 B translate<.5,0,-T2>]
     [1/3 B translate<-1,0,0>]
     [2/3 B translate<-1,0,0>]
     [2/3 B translate<.5,0,T2>]
   }
   translate x
   warp{repeat 1.5*x flip x}
   warp{repeat .5*sqrt(3)*z flip z}
#end

plane {y 0 pigment {Arabesque(7)rotate <0,0,0.6>} finish {ambient 1} }
camera {location 10*y sky z look_at 0}
---%<------%<------%<------%<---

Post a reply to this message