Thomas de Groot <tho### [at] degrootorg> wrote:
> Op 29-11-2023 om 16:04 schreef Alain Martel:
> > If the metal is to have a varnish coat, add a second mostly to fully
> > transparent pigment layer above the metallic one. Add an interior
> > statement for the IOR : interior{ ior 1.5 } And use the fresnel
> > attribute : reflection{ 1 fresnel }.
> >
> > That way, at high angle, you'll see almost only the metallic surface,
> > but, at grazing angles, you get the fresnel reflection dominating.
> > Tried that and compared with actual metals, brass actually, coated with
> > a varnish, and the result matched my physical samples.
>
> I probably made a mistake somewhere, but I have a problem with this. The
> object looses its shadow in my code (see the egg in attached image).
>
> This is the code used for the egg finish:
>
> ovus { 1.00, 0.65
>    pigment {rgb <0.4, 0.9, 0.4>}
>    pigment {rgbt <0.9, 0.1, 0.1, 0.99>} //varnish coating!
>    finish {
>      metallic
>      diffuse 0.0
>      specular 0.80
>      roughness 1/20
>      reflection {0.90 fresnel metallic}
>    }
>    interior {ior 1.5}
>    scale 0.5
>    translate <0, 0.5, 0>
> } // end of ovus --------------------------------------

Try it this way:

ovus { 1.00, 0.65
   texture {
      pigment {rgb <0.4, 0.9, 0.4>}
      finish {
         metallic
         diffuse 0.0
         ambient 0.0
         specular 0.80
         roughness 1/20
         reflection {0.90 metallic}
      }
   }
   texture {
      pigment {rgbt <0.9, 0.1, 0.1, 0.99>} //varnish coating!
      finish {
         reflection {0.90 fresnel}
      }
   }
   interior {ior 1.5}
   scale 0.5
   translate <0, 0.5, 0>
} // end of ovus --------------------------------------

Post a reply to this message