"Mike Miller" <mil### [at] gmailcom> wrote:
> "Bald Eagle" <cre### [at] netscapenet> wrote:
> > "Mike Miller" <mil### [at] gmailcom> wrote:
> > > Brain Attack pulp style cover using brain bots, pipes and tanks. [...]
> >
> > Pretty cool PS post-render effects.
> >
> > I'm wondering what can be done in that respect directly in POV-Ray, [...]
>
> Not sure how to get the edge and cel-shade look directly from POV.

One idea for the outlines is to build a new object out of several copies, like
so (I attached an image of the result):

#declare Obj =
 union{
  #local W = .3;
  #local Obj_ =
   merge{
    cylinder{-x, x, W}
    sphere{-x, W}
    sphere{x, W}
   }
  object{Obj_}
  object{Obj_ rotate y*90}
  object{Obj_ rotate z*90}
 }

// object without outlines
object{
 Obj
 pigment{rgb .7}
}

// outlines
merge{
 // change these two things
 #local NPts = 8;
 #local LineThickness = 0.03;

 // golden spiral points on sphere
 #local Inc = pi * (3 - sqrt(5));
 #local Off = 2 / NPts;
 #local Seed = seed(1001);
 #for(K, 0, NPts-1)
  #local Y = K * Off - 1 + (Off / 2);
  #local R = sqrt(1 - Y*Y);
  #local Phi = K * Inc;
  object{
   Obj
   translate LineThickness*<cos(Phi)*R, Y, sin(Phi)*R>
  }
 #end
 texture{pigment{rgbt 1}}
 interior_texture{pigment{rgb 0}}
 interior{ior 1.0001}
 no_shadow
 no_reflection
}

^That technique requires some things to be merged.

Another idea is to keep using whatever post-process effect you have been using
up til now, but feed it a simpler image without reflections, shadows, etc. Maybe
give it an image rendered with +q0 or something. The problem with that, however,
is some areas will not have lines because the adjacent colors will be the same.
The only fix I know for that is to give different areas slightly different
colors, so that the line algorithm has something to work with. (I hope that
makes sense ;P)

> Attached is styled with posterized shadows with a 1/2 tone process dot per Sam's
> suggestion - thanks Sam. I'm liking the comic book feel. I also removed the
> reflection pass to reduce the busyness, especially in the pipes. Will continue
> to play with this.
> Mike.

It's looking good!

Sam

Post a reply to this message

Attachments:
Download 'basicobjectoutline.jpg' (18 KB)

Preview of image 'basicobjectoutline.jpg'