Give you


#version 3.7;



global_settings{
max_trace_level 3
assumed_gamma 1.0
adc_bailout 0.007
mm_per_unit 1000 //important for subsurface

radiosity{
 pretrace_start 64/image_width
 pretrace_end   4/image_width
 count 60
 nearest_count 6
 error_bound 0.64
 recursion_limit 8
 low_error_factor 0.5
 gray_threshold 0.0
 brightness 1
 media off
}


}

default{
texture{
    pigment {rgb<0.2,0.2,0.2>}
    finish{ambient 0 diffuse 0}
}
}
//---------------------background------------------------
background{rgb <0,0,0>}

//-------------------settings--------------------------------
//--------------------light source-----------------------------



light_source {
<-4, -2.5, 4>*100
color rgb <1.0, 0.88, 0.76>*1.75
parallel
point_at <0.0, 0.0, 0.0>
rotate <0,0,106>
}



sky_sphere{
    pigment {rgb <0.35,0.55,1>*0.6}
}


//------------------------------------------








camera{
location <10,5,6>
look_at <0, 0, 0>
right <-4/3,0,0>
sky <0,0,1>
angle 32
}
//----------------------------------------


//ground
#declare t_soil1=
texture{
    pigment{rgb<0.2,0.164,0.1>*0.8}
    finish{ambient 0 diffuse 1}
}


plane{
<0,0,1>,0
texture{t_soil1}
}










//media

#declare coverage = 0.30; // can adjust it
#declare coverage2 = 0.32; // can adjust it

#include "functions.inc"

#declare f_test =
function(x,y,z) {
coverage2*sum(i, 0, 4, pow(abs(f_noise3d(x*pow(2, i)/0.2, y*pow(2, i)/0.2,
z*pow(2, i)/0.2)), 2.5)/pow(2.0, i) )
}



#declare f_cloud_base =
function(x,y,z) {
0.5 - f_test(x,y,z)*3*3*z*exp(-3*z) - coverage*3*3*z*exp(-3*z)
}


#declare dens_cloud =
density{
    function{0.5 - 0.2*f_cloud_base(x,y,z)}
    color_map{
        [0   rgb 0]
        [0.5 rgb 0]
        [0.51 rgb 1]
        [1   rgb 1]
    }
}





box{
<-20.0, -1.0, 0.0>, <20.0, 1.0, 1.0>
hollow

    material{
        texture{
            pigment{rgbt<0,0,0,1>}
            finish{ambient 0 diffuse 0}
        }
        interior {
            media{
                samples 12

                scattering{
                1, rgb< 0.5, 0.75, 1.5 >*10.0
                extinction 1.0
                }
                density {
                dens_cloud
                }
            }
        }
    }
scale <1.6, 1.6, 1.0>
translate <0,0,0>

}





















//water

box{
<-20.01, -1.0, 0.1>, <20.01, 1.0, 0.45>

material{
    texture{
        pigment{rgbf<1,1,1, 0.99>}
        finish{
        ambient 0 diffuse 1 fresnel reflection{0.01, 1 fresnel }conserve_energy
        }

    }
    interior{
    ior 1.33
    }
}
scale <1.6, 1.6, 1.0>
}



//ditch
difference{
box{
<-20.0, -1.05, 0.0>, <20.0, 1.05, 1.0>
}
box{
<-20.01, -1.0, 0.1>, <20.01, 1.0, 1.01>
}

texture{
    pigment{rgb<0.4,0.4,0.4>}
    finish{ambient 0 diffuse 1}
}
scale <1.6, 1.6, 1.0>
translate <0,0,0>
}

Post a reply to this message

Attachments:
Download 'discharge.png' (92 KB)

Preview of image 'discharge.png'