"Jay" <pjy### [at] gmailcom> wrote:
> i want to generate 25 images by moving camera like this.
>
> this is the sequence of movement of camera i want to make.
>
> (1)  (2)  (3)  (4)  (5)
> (6)  (7)  (8)  (9)  (10)
> (11) (12) (13) (14) (15)
> (16) (17) (18) (19) (20)
> (21) (22) (23) (24) (25)
>
> all these cameras are arranged at the same plane and looking at the orthogonal
> position.
>
> i know how to make the first line (1)~(5)
>
> but i can't figure out how to move camera(5) to (6) and goes on the movement.
>
> anyone who know how to do this stuff, plz let me know. i appreciate

Although I am probably the wrong person to answer this I will try, hope you can
figure this out:

/* access array 0 to 24 (25 entries)
and place camera to view 5 X 5 grid */

//cmd:+ki0 +kf1 +kfi0 +kff24


#declare X=25;

#declare X5=array [X] {1,2,3,4,5,1,2,3,4,5,1,2,3,4,5,1,2,3,4,5,1,2,3,4,5};

#declare Y=25;

#declare Y5=array [Y] {1,1,1,1,1,2,2,2,2,2,3,3,3,3,3,4,4,4,4,4,5,5,5,5,5};


camera {
  orthographic
  location <-0.5+X5[frame_number],0.5-Y5[frame_number],-1>
  look_at  <-0.5+X5[frame_number],0.5-Y5[frame_number],0>
  right x            // horizontal size of view
  up y               // vertical size of view
}

// overview to see all 25 locations at once
//camera {location <5/2,-5/2,-5> look_at <5/2,-5/2,0>}

box {         // this box fits exactly in view
  <0,0,0>, <5,-5,1>
  texture {
  pigment {checker rgb <1, 0, 0> rgb <0, 0, 1>}
  finish {emission 1}
  }
}

#declare XYt=0;

#for (Yt,-1,-5,-1)
#for (Xt,1,5,1)

#declare XYt=XYt+1;

text {ttf "arial" str(XYt,0,0) 1, 0
 pigment {rgb 1}
 finish {emission 1}
 scale 0.5
 translate <-0.75,0.25,0>
 translate <Xt,Yt,-0.1>
 }

#end
#end

Post a reply to this message