Thomas de Groot <tho### [at] degrootorg> wrote:
> On 4-1-2017 14:30, omniverse wrote:
> > Version 3.7.
> >
> > Wondering if this might be a bug in media or something else.
> >
> > Posted picture showing two boxes with a boxed pattern for the media.
> >
> > http://news.povray.org/web.586ceedd76c376849c5d6c810%40news.povray.org
> >
> > The bright specks show conspicuously where the box surfaces intersect, but not
> > all places. Picture is post-processed to combine them. Test scene given in
> > message there.
> >
> > Another hollow box contains the scene and camera, no media itself, and that
> > dramatically increases the visibility of the specks. They are there without it
> > too.
> >
> > I couldn't find any way to prevent the specks by changing media parameters. Even
> > tried version changes to 3.5 and 3.6, but not those actual programs.
> >
> >
> >
>
> The result will probably different from what you intent to do, but how
> about merging the boxes? In your example it is a kind of union{} and
> there may be the problem. merge{} might be a solution.
>
> --
> Thomas

Despite the fact that omniverse has found a solution by scaling, merging the
boxes does not suffice. The results I found were annoying. White faces instead
of white dots. IIRC the issue is very old and is e.g. mentioned in the
documentation of the makecloud macros by Gilles Tran. Overlapping of containers
with media seems to cause artifacts since the introduction of media in POV.

My first thought was to have a bigger container and multiple translated
densities within the media-statement, but the result was annoying too. A close
container seems to be necessary. I then merged the Containers and put multiple
densities inside (translated alike the containing boxes). May be more to the
intent of omniverse - and no scaling needed.

Best regards,
Michael

/* test boxed pattern media bright specks */


#version 3.7;

camera {
 location -x*4 look_at 0
 up y
 right image_width/image_height*z /* x ????, never understood this */
 //angle 30
}

// try with and without this scene container (camera inside)
//box{-9,9 hollow pigment{rgb 0.1}} // specks much more apparent


#declare Media_Cont = merge {

   #for(It,0,1,1) // create multiple boxes

      box { -1,1
         rotate <30,30,30>*It
         translate -<1,1,1>*It/2+<1,1,1>*It/2
      }
   #end

   hollow on
}
object { Media_Cont
   pigment {
      rgbt 1
   }
   interior {
      media {
         //method 1
         //intervals 30
         //confidence 0.99
         //variance 1/10000
         //ratio 0.5
         //jitter 0.9
         //aa_threshold 0.1
         //aa_level 3
         //samples 33
         emission <0.1,0.1,0.8>
         //absorption 1
         #for(It,0,1,1) // create multiple densities according to the boxes
            density {
               boxed
               density_map {
                  [0 rgb 1] [0.1 rgb 0] [1 rgb 0]
               }
               rotate <30,30,30>*It /* same transforms as for the merged boxes
above */
               translate -<1,1,1>*It/2+<1,1,1>*It/2
            }
         #end
      }
   }
}

Post a reply to this message