"Dave Blandston" <nomail@nomail> wrote:
> "omniverse" <omn### [at] charternet> wrote:
> > Made a Merry Christmas picture and by pure coincidence ol' St. Nick seems to
> > have been reflected in some of the red ornaments. Not done on purpose. Just
> > snow-reflected light.
>
> Hey, that's pretty cool! Merry Christmas!
>
> Regards,
> Dave Swaim

Thanks Dave! I can't seem to post the scene file without leaving an error or
problem but I will try a third time anyway:

/* treeless ornaments around "warm" glow */

//cmd:+am2 +a0.2 +j1

#version 3.71; // 3.7 or use 3.71 with alpha or UberPOV

#local Radiosity=on;

#local Media=on;

#local Subsurface=on;

global_settings{assumed_gamma 1.0
 max_trace_level 8
 #if(Radiosity=on)
 radiosity{count 123
  adc_bailout 1/32 // fix for blank/black areas,
                // seen with 1/128, for example.
                // This was 2/1 before and meant to be 1/2, oops!
                // Something about HF or isosurface when used
                // with radiosity?
  normal on media on
 } #end
 #if(Subsurface=on)
 subsurface{samples 60,40 radiosity on}
 #end
 //mm_per_unit 50
}

// moonlight
light_source{<100,100,-100>,<0.2,0.4,0.6>*0.7
 area_light <5,0,0>,<0,0,5>,4,4
 area_illumination
 media_interaction off
 media_attenuation off}

// warm glow light
light_source{<0,7.5,0>,<0.9,0.5,0.3>*0.9
 area_light <0.33,0,0>,<0,0,0.33>,8,8 circular orient
 area_illumination
 fade_distance 9 fade_power 2
 media_interaction on
 media_attenuation on}

camera{location <0,2.4,-24>
 up y right image_width/image_height*x
 look_at <0,5,0>}

// starry sky
#declare StarY = function {
 pigment { brick rgb <1,1,0> rgb 0 mortar 0.001 }
}

sphere{0,333.33 // stars
 hollow on
texture {
  pigment {
    function { StarY(x,y,z).red}
    turbulence 3 scale 33 // bricks into stars
    }
    finish { diffuse 0 ambient 1 emission 1 }
}
texture{pigment{rgbf<1,1,0,1>}}
 radiosity {importance 0.1}
}

sphere{0,1 // sky color
 hollow on
 pigment{
  function {abs(y)}
  color_map{
   [0 rgbt <0.6,0.1,0.2,0.3>]
   [0.1 rgbt <0.3,0.2,0.5,0.5>]
   [0.3 rgbt <0.2,0.4,0.9,0.8>]
   [1 rgbt <0.1,0.3,0.9,1>]
  }
 }
 finish{diffuse 0 ambient 1 emission 1}
 scale 333
 radiosity {importance 0.8}
}

// localized air haze
#if(Media=on)
media{method 3 samples 50,50 // increase to reduce banding
 // jitter 0.1  // too messy?
 scattering{1,0.03}
density{spherical density_map{[0.93 rgb 0][1 rgb 0.67]}}
scale 334}
#end


// ornaments
#for(It,0,36,1)

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(360*It/6)
 material{
  texture{
 pigment{rgb <0,1,0>}
 finish{
  #if(version>3.7)fresnel 1.33 #end
  ambient 0 emission 0.05
  brilliance 3
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 2}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

sphere{<3-It/12,1+It/3,0>, 1-It/40
 rotate y*(145+360*It/6)
 material{
  texture{
 pigment{rgb <1,0,0>}
 finish{
  #if(version>3.7)fresnel 1.2 #end
  ambient 0 emission 0.05
  brilliance 4
  diffuse albedo 0.5
  specular albedo 0.9 roughness 0.01
  reflection{0,1 fresnel on falloff 0.9 exponent 3}
 }
  }
  interior{ior 1.5}
 }
 radiosity {importance 1}
}

#end // ornaments


// ground snow
intersection { // add thickness for subsurface scattering
 box{<-0.01,0.01,-0.01>,<0.99,1.01,0.99>}
height_field {
  function 333,333 {
    pattern {
      bozo scale 0.1
      }
  }
  smooth
} // HF
  translate -0.5
  scale <67,3,67>

  texture{
  pigment{rgb 1}
  normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15
   brilliance 0.8
   diffuse albedo 0.9
   specular albedo 3 roughness 0.01
   crand 0.1
   subsurface{translucency <0.8,0.9,1>}
  }
  }
  texture{
  pigment{bumps color_map{[0 rgb 1][0.2 rgbt 1]} scale 0.02}
  //normal{bumps 0.1 scale 0.3}
  finish{ambient 0.15 emission 0.05
   brilliance 0.4
   diffuse albedo 9
   specular albedo 9 roughness 0.01
   //crand 0.1
  }
  }
  interior{ior 1.34}
  translate y*0.25
 radiosity {importance 0.8}
} // intersection

Post a reply to this message