Jaime Vives Piqueres <jai### [at] ignoranciaorg> wrote:

> > I ended up using a single containing object (box or plane) and then filling it
> > with a skewed y-gradient density to get a flat bottom and then adding a mixture
> > of wrinkles, bozo and crackle (form<1, 0, 0>) to try to approximate fluffy tops.
> > Some of my images over at www.landofthefirst.com were created using this. I am
> > still not 100% happy with them.
>
>    The ones at Othil Homtoh look very nice...
>
> --
> jaime

Here is the code:

    #macro SkyShell(minAlt, maxAlt, Int)
        difference
        {
            sphere {<0, 0, 0> 1000000+maxAlt}
            sphere {<0, 0, 0> 1000000+minAlt}
            hollow
            texture {pigment {color rgbf 1}}
            interior {Int}
            translate <0, -1000000, 0>
        }
    #end

    SkyShell(4000, 5000,
        interior {
            media {
                method 3
                samples 20
                scattering {2, color rgb 0.0075 extinction 1}
                density
                {
                    wrinkles
                    scale <4000, 1000, 4000>
                    warp { turbulence 2 }
                    lambda 4
                    color_map
                    {
                        [0.00 color rgb 1.0]
                        [0.50 color rgb 0.8]
                        [0.55 color rgb 0.0]
                        [1.00 color rgb 0.0]
                    }
                    translate <-4000, 0, -1000>
                }
                density
                {
                    gradient y
                    scale 1000
                    color_map
                    {
                        [0.0  color rgb 0.00]
                        [0.4  color rgb 1.00]
                        [0.9  color rgb 1.00]
                        [1.0  color rgb 0.00]
                    }
                }
            }
        }
    )

I lied. It was concentric spheres!

And nice solution for the artifacts! One to remember.

Post a reply to this message