|
|
Hi, I rendered some pictures to interpretation my method. You can just use the
'reflection' keyword to render the highlight.
The first one is a scene that contains a point light_source, a (looks_like)
white emission sphere but no_radiosity and no_shadow. A ground, and some
reflection spheres.
You can see the effect.
//----------------start of scene-----------------
#version 3.7
global_settings{
assumed_gamma 1
max_trace_level 8
}
//------------------light source--------------
#declare light_pos = <0, 0.12, -0.5>;
#declare light_color = rgb <0.5,1,1>;
light_source{
light_pos
color light_color
fade_distance 1
fade_power 2
}
#declare light_r = 0.12;
#declare emission_area = 4*pi*light_r*light_r;
sphere{
light_pos, light_r
no_shadow
no_radiosity
pigment{light_color}
finish{ambient 0 emission 1 diffuse 0}
}
//-----------------camera--------------------
camera {
location<3,2,0>
look_at<0,0,0>
}
//-----------------object--------------------
plane{
<0,1,0>,0
texture{
checker
texture{pigment{rgb <0.7,0.65,0.1>} finish{ambient 0 diffuse 1
brilliance 1.5 reflection{0.02,0.52 falloff 3}}},
texture{pigment{rgb <0.7,0.65,0.1>} finish{ambient 0 diffuse 1}}
scale <0.6,1,1.5>
rotate <0,45,0>
}
}
#declare sphere1=
sphere{
<0,0.14,0.3>, 0.14
texture{
pigment{rgb<0.19,0.18,0.19>}
finish{ambient 0 diffuse 1 brilliance 1.5 reflection {0.01,0.2 falloff
3}}
}
}
#declare GOLDEN_RATIO = (1+sqrt(5))/2;
#declare sitting_r = 4;
#declare sitting_center = <0,0,0>;
#declare sphere_amount = 250;
#for(i, 20, 49)
#local this_r = sqrt(1/2+i)/sqrt(sphere_amount);
#local this_theta = i*2*pi*(1-1/GOLDEN_RATIO);
#local this_point = <this_r*cos(this_theta), 0,
this_r*sin(this_theta)>*sitting_r;
object{
sphere1
translate sitting_center + this_point
}
#end
//----------------end of scene---------------
Post a reply to this message
Attachments:
Download 'finish test2 1.png' (132 KB)
Preview of image 'finish test2 1.png'
|
|