"Brad" <bra### [at] gmailcom> wrote:
> clipka <ano### [at] anonymousorg> wrote:
> >
> > You could use a fourth POV-Ray scene, using an orthographic camera, and
> > applying the other image files as textures.
>
> Thanks to both of you for your response. This sounds like it might work. Do you
> know of any simple examples online for me to see how this is done exactly?

Play with these scene files.  First render brad_source.pov with the given
command line arguments to generate the individual images, then render
brad_montage.pov to compile them.
______________________________________________________________________

//brad_source.pov

//+a +w200 +h150 +kff3 +fn
#include "shapes.inc"
global_settings { assumed_gamma 1 }

camera { location <0.3, 0.3, -7> look_at 0 angle 30 }

light_source { <-1, 1, -1> * 1000, rgb 1 parallel point_at 0 }

sky_sphere
{ pigment
  { gradient y color_map
    { [0 rgb <0.6, 0.7, 0.9>]
      [1 rgb <0.2, 0.3, 0.6>]
    }
  }
}

plane
{ y, -1
  pigment { checker rgb <0, 0.4, 0.1> rgb <1, 0.75, 0> }
}

object
{ #switch (frame_number)
    #case (3) Round_Cone_Union (-y, 1, y, 0.15, 0.15) #break
    #case (2) Round_Cylinder_Union (-y, y, 1, 0.2) #break
    #else sphere { 0, 1 }
  #end
  pigment { rgb <0.61, 0.61, 0.64> }
  finish
  { reflection { 0.9 metallic }
    diffuse 0.06
    ambient rgb 0.01
    brilliance 3
    specular 1000 metallic
    roughness 0.0001
  }
}
______________________________________________________________________

//brad_montage.pov

//+w220 +h490 -a
global_settings { assumed_gamma 1 }

camera
{ orthographic
  location <100, 235, -1>
  right 220 * x
  up 490 * y
}

background { rgb <0.2, 0.02, 0> }

#default
{ finish
  { diffuse 0
    #if (version < 3.7)
      ambient 1
    #else
      ambient 0
      emission 1
    #end
  }
}

box
{ 0, 1
  pigment { image_map { png "brad_source1" } }
  scale <200, 150, 1>
  translate 320 * y
}
box
{ 0, 1
  pigment { image_map { png "brad_source2" } }
  scale <200, 150, 1>
  translate 160 * y
}
box
{ 0, 1
  pigment { image_map { png "brad_source3" } }
  scale <200, 150, 1>
}
______________________________________________________________________

Post a reply to this message