Christian Froeschlin <chr### [at] chrfrde> wrote:
> nemesis wrote:
>
> > completely unacceptable render time for such a flat, untextured scene.
>
> well I suppose the planet is using a lot of media although
> it may be overkill at such a scale. I wonder if SSLT would be
> appropriate for distant planetary views where the atmosphere
> appears to be very thin.

Are you using scattering media for the atmosphere? I suggest using emissive
media with a gradient map instead. Renders much faster, gives you more artistic
control and looks better as you don't geht a sharp shadow at the terminator.
This is what i've been using:

#declare R0 = 10; // planet radius
#declare ah = 0.25; // atmosphere height

sphere { 0, R0 } // the planet

sphere { // the atmosphere
  0, 1 pigment { rgbf 1 } hollow

  interior {
    media{
      emission 2.2*1/255 //scale to need

      density {
        spherical
        density_map {

          [ah/(R0+ah)*0.00 rgb <  0,  0,  0>]//sky
          [ah/(R0+ah)*0.20 rgb <  9, 10, 18>]
          [ah/(R0+ah)*0.30 rgb < 10, 14, 21>]
          [ah/(R0+ah)*0.40 rgb < 14, 18, 28>]
          [ah/(R0+ah)*0.50 rgb < 20, 23, 38>]
          [ah/(R0+ah)*0.55 rgb < 27, 33, 52>]
          [ah/(R0+ah)*0.60 rgb < 29, 39, 61>]
          [ah/(R0+ah)*0.65 rgb < 30, 45, 74>]
          [ah/(R0+ah)*0.70 rgb < 30, 54, 90>]
          [ah/(R0+ah)*0.75 rgb < 37, 67,109>]
          [ah/(R0+ah)*0.80 rgb < 48, 82,190>]
          [ah/(R0+ah)*0.85 rgb < 61, 99,151>]
          [ah/(R0+ah)*0.90 rgb < 80,118,171>]
          [ah/(R0+ah)*0.95 rgb <104,139,187>]
          [ah/(R0+ah)*1.00 rgb <154,173,203>]//ground

        }
      }

      density {
        gradient y
        translate -y/2
        scale 2
        density_map {
          [0.00 rgb <10,  8,  8>/255]//day side
          [0.40 rgb <10,  8,  8>/255]
          [0.45 rgb <37, 12,  6>/255]
          [0.50 rgb <59, 34, 15>/255]//terminator
          [0.55 rgb <66, 58, 56>/255]
          [0.60 rgb 0.65]
          [1.00 rgb 0.65]//night side
        }
      }
    }
  }
  scale R0+ah
}

Regards Roman

Post a reply to this message

Attachments:
Download 'atmosphere.jpg' (88 KB)

Preview of image 'atmosphere.jpg'