Gentlemen,

I rendered the following SDL with both 3.62 and 3.7RC1, and got
different output between them.
In 3.7RC1, it looks like no_reflection option of the black sphere
doesn't work.
Are there any changes about no_reflection? I couldn't find in
change log.

Best Regards,

---- from here ----

#version 3.6;

#include "colors.inc"

global_settings {
    max_trace_level 10
}

camera {
    angle 35
    location <0,1.4,-6>
    look_at <0,0.8,0>
    sky y
}

background {
    Black
}

//  The floor
plane {
    y,0
    pigment { White }
    finish {
        reflection 0.2
        ambient 0.4
    }
    hollow
}

union {
    //  A black sphere
    sphere {
        0, 0.25
        pigment {
            Black
        }
        finish {
            ambient 0
        }
        no_shadow
        no_reflection  //  to not render reflection image on the floor
    }

    //  Halo around the sphere
    sphere {
        0, 0.5
        pigment { Clear }
        interior {
            media {
                emission White
                density {
                    spherical
                    color_map {
                        [ 0.6  color 0 ]
                        [ 0.75 color 1 ]
                    }
                }
            }
        }
        hollow
        no_shadow
        no_reflection  //  to not render reflection image on the floor
    }

    //  to render blighter halo on the floor
    sphere {
        0, 0.5
        pigment { Clear }
        interior {
            media {
                emission White
                density {
                    spherical
                    color_map {
                        [ 0.6  color 0 ]
                        [ 0.75 color 7 ]
                    }
                }
            }
        }

        hollow
        no_image
        no_shadow
    }

    translate <0,0.8,0>
}

Post a reply to this message