Ever wondered how on earth you could verify that your POV gamma settings are ok?
This scene is the answer.

Render this scene at 800x600 with strong anti-aliasing (+am2 +r3 +a0.1 does
nicely) and preview enabled.

When viewed with squinted eyes (or without glasses, if you need them for
computer work), the shot should seem to show nothing but a plain gray
rectangle. If that is the case, your gamma settings are ok. Use these
(including the "assumed_gamma" setting) for *ALL* scenes you do. If that makes
your other scenes look too bright or too dark, it's *NOT* the gamma's fault,
but the lighting conditions'. Note that wrong gamma settings will mess up color
saturation in your scenes in a nonlinear, unrealistic way.

Make sure you do *NOT* tamper with the "assumed_gamma 1.0" statement if you can
help it. If you absolutely must to get proper results with both preview and
file output, make sure you use the same value in your other scenes as well.

With POV 3.6, the setting you will want to toy around with is "Display_Gamma".
With POV 3.7, you also have the possibility of toying around with "File_Gamma"
separately to change your output files' gamma. This may be especially handy if
your display gamma is something other than 2.2, but you want to create files
ready for the internet, where a display gamma of 2.2 is a quasi-standard.


--------------------------------------------------
// +w800 +h600 +am2 +r3 +a0.1

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

camera {
  location  <0.0, 0.0, -4.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0, 0.0>
}

// ----------------------------------------

plane {
  -z, -1
  texture {
    pigment {
      checker
      color rgb 1
      color rgb 0
      scale .02
    }
    finish{
      ambient 1
      diffuse 0
      specular 0
    }
  }
  rotate x*45
}

sphere {
  0.0, 1
  texture {
    pigment { color rgb 0.5 }
    finish{
      ambient 1
      diffuse 0
      specular 0
    }
  }
}
--------------------------------------------------

Post a reply to this message