> to render every time to see what the changes you make are going to look
> like is a serious pain
> I have something I want to
> do and need a simple, clear, and easily tweakable method to match
> existing textures, without having to use something that generates a
> tillable image, instead of a native texture. Nothing "recent" seems to
> do this.

> you can tweak settings and see what will happen *before* having to
> render some complex scene to see the result.

> Sure, if you are used to doing it the hard way, and you have a clear
> idea what effects you will get, it works OK to throw 3-4 things
> together, render, then tweak. Its useless if you only have the vaguest
> clue what you are trying for

To avoid rendering a complex scene just to test a texture, what about making a
simple texture test scene in POV-Ray SDL? The incdemo files bundled with
POV-Ray illustrates this in a much better way, even with animation.

But perhaps this small example is something you could use? It allows for testing
of to different variables at the same time. Render the scene, pick the values
you like and insert them in the code. Then continue with two other variables.
This should help you to narrow down the effect you like in a rather short time.
As your experience increases you will need fewer and fewer tries to get what you
want ;)

Good luck!

-Peter

// +h1000 +w1000 +a0.3

camera{
        orthographic
        location z*-10 look_at 0 angle 60
        right x up y
}

light_source{<5,5,-20>,1}

#local Space = 0.1;

#local X = 0;
#while (X <= 1)
        #local Y = 0;
        #while (Y <= 1)
                #local Location = <-5+X*10,-5+Y*10,0>;

                sphere{0,Space*4
                        texture{
                                pigment {rgb 1}
                                finish {phong X}
                                normal{granite Y}
                                }
                translate Location
                }

                text{ttf "arial.ttf"
                        concat("X: ",str(X,3,1), " Y: ",str(Y,3,1)) 1,0
                        pigment {rgb y*1}
                        scale Space translate Location-Space*<3,5,0>
                }
        #local Y = Y+Space;
        #end
#local X = X+Space;
#end

Post a reply to this message