Alain <ele### [at] netscapenet> wrote:
> Charles nous apporta ses lumieres en ce 2007/09/01 19:39:
> > Hello everyone,
> >
> > For a research project, I need to make a physically accurate simulation of
> > candlewax.


Hi!

I made a demo scene with wax this spring (see below).

The material is slightly altered from the one first provided by Andy Cocker
in his posting:
http://news.povray.org/povray.text.scene-files/thread/%3C3fcddaec$1@news.povray.org%3E/?ttop=238503&toff=100
The media density is very high (seven).

Perhaps try this, should render in a few seconds.


Yours,
Bu.


Only code follows:

//////////////////////////////////////////////////////////////////////
// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.6
// Desc: Checkered Floor Example
// Date: mm/dd/yy
// Auth: ?
//

#version 3.6;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
  max_trace_level 5
}

// ----------------------------------------

camera {
  location  <0.0, 0.5, -4.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

// ----------------------------------------

plane {               // checkered floor
  y, -1
  texture
  {
    pigment {
      checker
      color rgb 1
      color blue 1
      scale 0.5
    }
    finish{
      diffuse 0.8
      ambient 0.1
    }
  }
}
//
http://news.povray.org/povray.text.scene-files/thread/%3C3fcddaec$1@news.povray.org%3E/?ttop=238503&toff=100

#declare Obj_Col = <1, 0.6, 0.2>;
#declare Obj_Absorption = 1 - Obj_Col;
#declare Media_Density = 7;    //was 6.5; // must be adapted to size
#declare SSS_Tex =
     texture {
          pigment {
               rgb Obj_Col
               filter 1.2 // was 1.0
          }
          finish {
               brilliance 4 // wasn't included from Andy Cocker
               specular 0.5
               roughness 0.2
               ambient 0.2
               reflection {
                    0.0,
                    0.5
                    fresnel
               }
               conserve_energy
          }
     }
#declare SSS_Int =
     interior {
          ior  1.3 // close to water
          // Media with absorption and scattering
          media {
               absorption Obj_Absorption*2
               scattering {
                              4, // Rayleigh
                              Media_Density //see above
               }
               method 3 // adaptive sampling, is default anyway
          }
     }

#declare SSS_Material =
material {
     texture {
          SSS_Tex
     }
     interior {
          SSS_Int
     }
}



//
cylinder{
     <0, -1, 0>
     <0, 0.3, 0>
     0.3
     hollow
     material {SSS_Material}
}

//end of file

Post a reply to this message