I bit of a background type thing.  Nothing too original.  Playing with the
finish mostly.



#version 3.6;

//+w1280 +h1024 +a0.01

global_settings {
  assumed_gamma 1.0
}

camera {
  location  <0.0, 0.5, -5.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.5,  0.0>
}

light_source {
 <0, 0.5, -5.0>
 color rgb <1, 1, 1>
 fade_distance 500
 fade_power 2
}

sphere {
  0.0, 100
  texture {
    pigment {
     color rgb <1, 1, 1>
    }
  }
}

#declare tex =
  texture {
    pigment {
     color rgb 0
    }
    finish{
 ambient 0
 diffuse 1
      metallic
      reflection{
       0, 1
       falloff 5
       exponent 5
      }
    }
  }

#declare tex1 =
  texture {
    pigment {
     color rgbft <0.1, 0, 0, 0.5, 0.25>
    }
    finish{
 ambient 0
 diffuse 1
      metallic
      reflection{
       0, 1
       falloff 5
       exponent 5
      }
    }
  }

#declare cen0 = <0,0,0>;
#declare R = seed(0);
#declare i = 0;
#while (i<500)
 superellipsoid {
  <0.5+0.5*(rand(R)*rand(R)), 0.5+0.5*(rand(R)*rand(R))>
  rotate <360*rand(R), 360*rand(R), 360*rand(R)>
  scale 0.1+0.05*rand(R)
#declare cen1 = <4*rand(R)-2, 4*rand(R)-2, 20*rand(R)-4>;
  translate cen1
  texture {
   tex
  }
 }

 cylinder {
  cen0, cen1, .01
  texture {
   tex1
  }
 }

#declare cen0 = cen1;

 #declare i = i + 1;
#end

Post a reply to this message

Attachments:
Download 'black_ball.jpg' (250 KB)

Preview of image 'black_ball.jpg'