By chance, I've just run across an amazingly wacky problem in POV 3.6.1c (on
Windows), having to do with media illuminated (or not!) by a spotlight.
Frankly, I don't know how I missed this before now.

A picture is worth 1000+ words, so I posted an image over at p.b.i

I took a *long* look at the various newsgroups (including beta-test) but
didn't see a reference to this particular issue. I realize that
media/transparency is still an on-going deal with the betas, so I don't
know if this particular problem has already been addressed. (Currently, I
can't download the latest beta, due to temporary technical issues at my
end.)

In a nutshell, here's the visual oddity:  The spotlight "cone" is actually
visible in an object's media, in a highly distorted way, when the object is
nowhere near the actual light cone (but in-between the cone and the camera.)
I've included a scene file to illustrate.  The spotlight, at upper left and
with a narrow spread,  is aimed at a simple solid box object.  There are
also two small emission media spheres in the scene, but FAR away from the
impinging spotlight, near to the camera. Completely out of the light.
(They're positioned to show off the abberation.) The same thing happens if
the spheres are behind the light cone. Even stranger is that the
"invisible" part of the light cone (the part UNDER the floor plane) is also
visible!

Some facts from experimenting:
1) it happens with all three media types
2) a cylinder light (which includes a spotlight) also shows it
3) the various media modifiers -- method, samples, intervals, accuracy,
etc.--don't affect it (although higher values for samples and/or intervals
lessen the effect)
4) camera re-positioning has no effect
5) turning no_shadow on or off in the media spheres has no effect
6) media_interaction OFF in the spotlight eliminates the problem (a solution
for emission and absorption media, but not for scattering media)

The problem seems to lie in the media's DENSITY block: no density block, no
cone appearance. But a density using ANY pattern with a color_map (either
default or user-defined) exhibits the problem. (And/or, perhaps it's an
issue with the inherent slope_maps in some of the patterns? Just a guess.)
Each pattern causes a different visual result. A spherical pattern
actually looks kind of interesting--like airbrush masking. (Hmm...seems
that even abnormal behavior has its uses!)

I can't tell if the distortion completely disappears when the spheres are IN
the light cone, but it looks to be so. And I didn't try moving the camera
and spheres closer to the cone, to see if that varied the effect.

Can someone run this on the latest POV beta?

Ken W.

------ code -----

camera {
  perspective
  location  <22,24,-55>
  look_at   <4,.1,.1>
  right     x*image_width/image_height
  angle 90
}

light_source {
  0*x
  color <1,0,0>
  spotlight
  translate <-36, 36, -36>
  point_at <0,0,0>
  radius 7
  tightness 10
  falloff 9
  // media_interaction off
}

// floor
object{
        box { <-65,-1, -40>, <75,0,50>
        texture{
                pigment{agate scale 15}
                finish {
                        ambient .2
                        diffuse .8
                       }
                }
            }
       }


// oblong box
box{<0,0,0>, <8,30,8>
        texture{
                pigment {color rgb 1}
                finish{
                        ambient .1
                        diffuse .9
                      }

               }
     translate <-4,0,-4>
    }

#declare media_sphere =
sphere{0,1 hollow no_shadow
    texture{
        pigment{color rgbt 1}
        finish{ // not needed, but does not alter problem
                ambient 0
                diffuse 0
              }
           }

    interior{
         media{
                emission .4
                density{bozo}
              }
            }
      }

object{media_sphere translate <22.5,22,-52>} // to right

object{media_sphere translate <18.9,23.4,-52>} // to left

Post a reply to this message