Does replacing

--------code---------
#declare disque=union{
object{top}
object{bottom}
clipped_by{Cube}
};


#declare Disque=union{
object{Cube}
object{disque}
};
------end code-------

with


--------code---------
#declare Disque=difference{
object{Cube}
object{top}
object{bottom}
};
------end code-------

produce what you want?

Abe

"jimmy" <nomail@nomail> wrote:
> Hello all,
> I need you help with a scene of mine.
> Basically i'm trying to modell a "flared" disc of gaz...
>
> The disc is the surface inside a cylinder and between 2 paraboloids...
> I fill it with emitting media...
>
> i wanted to tell the code i want more emmiting media to the center of the
> disc...i did it with a cylindrical density pattern.
>
> my problem is that bright part of my media is not centered in the disc...it
> seems that it has nothing to do with the cylindrical pattern...
> i spent many hours trying to understand what i did wrong...i figure it may
> be a silly error of mine, but it can also be something i simply did not
> understand so i'm requesting your help! :D
>
> i'm looking forward for your advices
> jimmy
>
>
> here's a paste of my scene file:
>
> #include "colors.inc"
> #include "functions.inc"
> #include "shapes.inc"
>
> //rayons min et max du disque....
> #declare r_in = 10;
> #declare r_out = 500;
>
>
> //hauteur min et max du disque
> #declare h_min =10;
> #declare h_max =80;
>
>
> //cylinder encompassing the disc
> #declare Cube = cylinder{<0,-h_max,0>,<0,h_max,0>,r_out open }  ;
>
>
>
>
> //top and bottom surfaces
> #declare top = object{Paraboloid_Y
> scale r_out
> scale ((h_max-h_min)/r_out)*y
> translate h_min*y
> }
> ;
>
> #declare bottom=object{top
> rotate 180*x
> };
>
>
>
>
>
> //construction of the flared disc
> #declare disque=union{
> object{top}
> object{bottom}
> clipped_by{Cube}
> };
>
>
> #declare Disque=union{
> object{Cube}
> object{disque}
> };
>
>
>
>
> //color map
> #declare gradient_disque= color_map{
> [0.0 rgb<0.002,0.0,0.0>]
>
> [0.05 rgb<0.03,0.0,0.0>]
> [0.1 rgb<0.035,0.0,0.0>]
> [0.2 rgb<0.04,0.0,0.0>]
> [0.3 rgb<0.05,0.0,0.0>]
> [0.4 rgb<0.1,0.0,0.0>]
> [0.6 rgb<0.2,0.00,0.00>]
> [0.7 rgb<0.3,0.00,0.0>]
> [0.8 rgb<0.4,0.0,0.0>]
> [0.9 rgb<0.5,0.08,0.0>]
> [1.0 rgb<1.0,0.2,0.05>]
>
> }
>
>
>
> //object{bottom texture{pigment{color Green}} finish{diffuse 0.6}  }
> //object{top texture{pigment{color Green}} finish{diffuse 0.6}  }
>
>
>
> //declaration gaz inside the disc
> #declare gaz=
> interior{
> media{
> method 3
> intervals 1
> samples 5
> emission 0.01
>
> density{cylindrical scale 500
> color_map{gradient_disque}
> }
>
> density{wrinkles scale 50
> color_map{
> [0.0rgb<0.1,0.1,0.1>]
> [0.5rgb<0.5,0.5,0.5>]
> [1.0rgb<1,1,1>]
> }
> }
>
> }};
>
>
> object{Disque
> texture {pigment {rgbt 0.5}}
> interior{gaz}
> hollow}
>
>
> // perspective (default) camera
> camera {location  <000.0, 500.0, -1000.0> look_at   <0.0, 0.0,  0.0>}
>
>
> //sphere{0,200 pigment{White}}
> light_source { <8000,2000,0> rgb 1  }

Post a reply to this message