Hi all. Here is a simple wallpaper made with Pov.

Feel free for experiment with the code and if you want it in more resolution
render it :P
________________________________________

#version 3.6;

#include "colors.inc"

#default {
  texture {
    pigment {rgb 1}
    finish {
      ambient 0.0
      diffuse 0.6
      specular 0.3
    }
  }
}

global_settings {
  assumed_gamma 1.0
  //max_trace_level 25
  radiosity {
    pretrace_start 0.08
    pretrace_end   0.04
    count 35
    nearest_count 5
    error_bound 1.8
    recursion_limit 3
    low_error_factor .5
    gray_threshold 0.0
    minimum_reuse 0.015
    brightness 1

    adc_bailout 0.01/2
  }
}

camera {location  <0.0, 10.0, 0.0> look_at <0.0, 0.0, 0.0>}

//seed for box creation
#declare r=seed(11811);// ... Metropolis worker ...

#declare sky_colors = array[7]{
<1,1,1>,      //0. White
<0.9,1,1>,    //1. very light Cyan
<1,0.9,1>,    //2. very light Magenta
<1,1,0.9>,    //3. very light Yellow
<1,0.9,0.9>,  //4. very light Red
<0.9,1,0.9>,  //5. very light Green
<0.9,0.9,1>   //6. very light Blue
}
#declare sky_brightness=1.5;
sky_sphere{pigment{rgb sky_colors[5]*sky_brightness}}

#declare box_x=1;//box width on X
#declare box_z=1;//box width on Z
#declare box_y=1;//box minimun height
#declare random_height=2.5;//random height
#declare n_x=15;//number of boxes on X
#declare n_z=15;//number of boxes on Z
#declare offset_x=box_x*n_x/2;
#declare offset_z=box_z*n_z/2;

#declare i=0;
#while(i<n_x)
  #declare j=0;
  #while(j<n_z)
    #declare height=rand(r)*random_height+box_y;
    box{
      0 <box_x,height,box_z>
      translate <i*box_x,0,j*box_z>
      translate <-offset_x,0,-offset_z>
      pigment{White}
    }
    #declare j=j+1;
  #end
  #declare i=i+1;
#end

Post a reply to this message

Attachments:
Download 'cubes.png' (93 KB)

Preview of image 'cubes.png'