|
|
"James" <hy5### [at] hanmailnet> wrote:
> Hi!
>
> I like to draw spheres of 1000 in 3D box. Is it possible?
>
> I have 3-dimensional positions of spheres. How, I don't know how to put the
> positions of spheres of 1000 on the program. As you know, it is difficult
> to write position of each sphere on the program.
>
> Thank you in advance.
>
> James
If you only want to a simple location then this does it:
/* Creates a set of spheres on a regular cube layout and spins them
/* set +kff = 180 and +kc = 1 in povray.ini */
#include "textures.inc"
#declare MyClock = clock;
#declare St = 2;
#declare Xs = 0;
#declare Qube =
union {#while ( Xs<=10)
#declare Ys = 0;
#while ( Ys<=10)
#declare Zs = 0;
#while (Zs <= 10)
sphere { <Xs,Ys,Zs>,0.25 pigment {
rgb<.1+Xs/11,0.1+Ys/11,0.1+Zs/11>} finish { Glossy } }
#declare Zs = Zs + St;
#end
#declare Ys = Ys + St;
#end
#declare Xs = Xs + St;
#end
}
object { Qube translate -5 rotate MyClock*360}
light_source { 1e3 rgb 1 }
camera { location <400,300,-600> look_at 0 angle 2 }
background { rgb 0.5 }
Post a reply to this message
|
|