In the Windows message area, "JayDee" <nomail@nomail> wrote:
> please help me ... i'm sorry if it has been already discussed but i don't
> know what to search for. I wanna render some shapes (black objects on the
> black background) behind which may be Light. i need result for example
> looking like eclipse of the sun .. black shape with visible shine around

Here's a fake solar eclipse, using emissive media.

//---------------------------------------------------------------------

// Persistence of Vision Ray Tracer Scene Description File
// File: MediaTestB.pov
// Vers: 3.5
// Desc: Media demo : solar eclipse
// Date:
// Auth: PM 2Ring
//
// +A0.3 +AM2 +R2
//

#version 3.5;

global_settings {assumed_gamma 1.0}

camera {location -16*z look_at 0 angle 30 }

#declare Container_T= texture {
   pigment {rgbt <1,1,1,1>}
   finish {ambient 0 diffuse 0}
}

cylinder{
   3*z, 0, 10
   hollow
   texture {Container_T}
   interior {
      media {
         intervals 15
         samples 1,1
         emission rgb <1, 1, .5> * 1.25
         density{spherical scale 3.275 turbulence 0.15}
      }
   }
}

cylinder{-1e-3*z, -z, 2.0}

background{blue .15}

//---------------------------------------------------------------------

Post a reply to this message

Attachments:
Download 'mediatestb1s.jpg' (24 KB)

Preview of image 'mediatestb1s.jpg'