|
![](/i/fill.gif) |
princeofgonville wrote:
>Can anyone give some hints on how they go about creating realistic-looking
>textures? I'd like to do something like rusty steel peeping out beneath
>cracked weathered paint - without using an image-map (am I mad?). Obviously
>I'm going to need some form of layered texture. But where does one start?
>How do you choose the right colours?
"texture_map" gives you the most power for showing different
textures "on top" of each other. Here's a rusty pipe texture
that shows the technique you can start with; it's scaled for
a 0.5 unit diameter pipe. If you come up with some good ones,
share them with us!
-Mark Slone
#local IronPigment =
pigment {
wrinkles
color_map {
[0.0 rgb <0.05, 0.10, 0.15>]
[0.7 rgb <0.10, 0.15, 0.20>]
[1.0 rgb <0.15, 0.20, 0.30>]
}
scale 5
}
#local IronTexture =
texture {
pigment { IronPigment }
normal { granite 0.1 scale 2.0}
finish { roughness 0.015 specular .5 }
}
#local RustPigment =
pigment {
granite
color_map {
[ 0.0 rgb <0.8, 0.3, 0.1> ]
[ 0.4 rgb <0.2, 0.1, 0.0> ]
[ 0.6 rgb <0.2, 0.1, 0.0> ]
[ 1.0 rgb <0.6, 0.1, 0.0> ]
}
scale .5
turbulence 1
}
#local RustTexture =
texture {
pigment { RustPigment }
normal { wrinkles scale 2 }
}
#local RustyIronTexture =
texture {
bozo
texture_map {
[ 0.0 RustTexture ]
[ 0.2 RustTexture ] // Rust
[ 0.6 IronTexture ] // Iron
[ 1.0 IronTexture ]
}
warp { turbulence 1 omega .6 lambda 4 }
scale <1,2,1>
}
Post a reply to this message
|
![](/i/fill.gif) |