On Mon, 22 Oct 2001 12:47:57 -0400, Timothy R. Cook wrote:
> So now that we've got blurring reflections licked, how do we fade
> out reflections?  Maybe media?  (Which I still haven't figured out
> how to make work the way I want it to...)

Try this.  It's not perfect, and I'm sure others will improve on it, but
it demonstrates the idea.  (3.5 only, I'm afraid, due to the no_image)
Unfortunately, this may be due to an undocumented and perhaps incorrect
behavior of no_image...

Notice that if you comment out or remove the line that says "reflective 
sphere location" the reflective sphere ceases to have faded reflections; 
this is the part that might be considered a bug.

difference {
  box {-100 100}
  sphere {x-2*z .001} //camera location
  sphere {10*z+x 5.001} // reflective sphere location
  
  hollow 
  pigment {color rgbt 1}
  interior {
    media {
      absorption .3
      density {rgb 1}
    }
  }  
  no_image
} 
 
sphere {10*z+x 5
  pigment {color red 1}
  finish {reflection .9 ambient 0 diffuse .5 specular 0}
}

light_source {<-20,20,-20> rgb 1 shadowless}
 
camera {
  location x-2*z 
  look_at 0
}

#declare I=0;
#while (I<5)     
  cylinder {I*z-y I*z+y .05 pigment {color green 1} finish {ambient 1}}
  #declare I=I+1;
#end



-- 
plane{-z,-3normal{crackle scale.2#local a=5;#while(a)warp{repeat x flip x}rotate
z*60#local a=a-1;#end translate-9*x}pigment{rgb 1}}light_source{-9red 1rotate 60
*z}light_source{-9rgb y rotate-z*60}light_source{9-z*18rgb z}text{ttf"arial.ttf"
"RP".01,0translate-<.6,.4,.02>pigment{bozo}}light_source{-z*3rgb-.2}//Ron Parker

Post a reply to this message