Having completed the contruction of a satelite dish using this code.
The scene code looks like this:
[code]
// Create a dish width a diameter of 120cM
#declare dish_radius = 600;
#declare dish_depht = 15;

#declare BasicDish =
union {
    intersection {
        object { Paraboloid_Y scale <dish_radius, dish_depht, dish_radius> }
        object { Paraboloid_Y scale <dish_radius-1, dish_depht-1, dish_radius-1>
}
        plane  { y,dish_depht }
        texture{ clear_al }
        finish {
            ambient 0.2
            diffuse 0.8
            phong 1.0
            phong_size 10
        }
    }
}

#declare Rim =
union {
    difference {
        cylinder{<0,0,0><0,2,0>dish_radius }
        cylinder{<0,-.5,0><0,2.5,0>dish_radius-2.5 }
    } texture{ Brushed_Aluminum }
}

#declare MountingPlate =
union {
    difference {
        cylinder{<0,0,0><0,-4,0>100 }
        cylinder{<0,.5,0><0,-4.5,0>7.5 }
    } texture{ vero_green }
}

#declare SatDish =
union {
    union {
        difference {
            object{ BasicDish }
            cylinder{<0,-.5,0><0,dish_depht+1,0>2.25 }
        }
        object{ Rim translate<0,dish_depht,0> }
        object{ MountingPlate }
    } rotate<90,0,0>
}[/code]
But the question is how make i the dish look like its made out of mesh
It should look somthing like this
http://www.harry-arends.nl/werkgroep/images/schotelKL.jpg

Post a reply to this message

"gharryh" <h.a### [at] harry-arendsnl> wrote:
> But the question is how make i the dish look like its made out of mesh

Try a patterned texture with transparent holes, such as this:

[code]
#declare clear_al = texture
{ gradient z texture_map
  { [0.1 Aluminum]
    [0.1 gradient x texture_map
      { [0.1 Aluminum]
        [0.1 pigment { rgbt 1 }]
      }
    ]
  }
  scale 60
}
[/code]

You would have to remove the finish statement from the BasicDish declaration, or
else you will get a parse error.  If you like, you can redefine texture Aluminum
to include that finish:

[code]
#include "textures.inc"
#declare Aluminum = texture
{ Aluminum
  finish
  { ambient 0.2
    diffuse 0.8
    phong 1.0
    phong_size 10
  }
}
[/code]

Post a reply to this message

I got i working now but with a strange result as can be seen here:
http://www.harry-arends.nl/werkgroep/images/ParabolicDishVersion1.png

It looks that the plane is playing havoc or is this normal behaivior?

"Cousin Ricky" <rickysttATyahooDOTcom> wrote:
> "gharryh" <h.a### [at] harry-arendsnl> wrote:
> > But the question is how make i the dish look like its made out of mesh
>
> Try a patterned texture with transparent holes, such as this:
>
> [code]
> #declare clear_al = texture
> { gradient z texture_map
>   { [0.1 Aluminum]
>     [0.1 gradient x texture_map
>       { [0.1 Aluminum]
>         [0.1 pigment { rgbt 1 }]
>       }
>     ]
>   }
>   scale 60
> }
> [/code]
>
> You would have to remove the finish statement from the BasicDish declaration, or
> else you will get a parse error.  If you like, you can redefine texture Aluminum
> to include that finish:
>
> [code]
> #include "textures.inc"
> #declare Aluminum = texture
> { Aluminum
>   finish
>   { ambient 0.2
>     diffuse 0.8
>     phong 1.0
>     phong_size 10
>   }
> }
> [/code]

Post a reply to this message

> I got i working now but with a strange result as can be seen here:
> http://www.harry-arends.nl/werkgroep/images/ParabolicDishVersion1.png
>
> It looks that the plane is playing havoc or is this normal behaivior?
>

Normal behaviour.
In fact, the transparent areas allow you to see the inside of the object.
You see the pattern applied to both the plane and the sphere part.

What you can do, is to apply the texture specificaly to the sphere and 
pigment{rgbt 1} to the plane.


Alain

Post a reply to this message